Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 1 | /* |
| 2 | * Helper macros to support writing architecture specific |
| 3 | * linker scripts. |
| 4 | * |
| 5 | * A minimal linker scripts has following content: |
| 6 | * [This is a sample, architectures may have special requiriements] |
| 7 | * |
| 8 | * OUTPUT_FORMAT(...) |
| 9 | * OUTPUT_ARCH(...) |
| 10 | * ENTRY(...) |
| 11 | * SECTIONS |
| 12 | * { |
| 13 | * . = START; |
| 14 | * __init_begin = .; |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 15 | * HEAD_TEXT_SECTION |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 16 | * INIT_TEXT_SECTION(PAGE_SIZE) |
| 17 | * INIT_DATA_SECTION(...) |
| 18 | * PERCPU(PAGE_SIZE) |
| 19 | * __init_end = .; |
| 20 | * |
| 21 | * _stext = .; |
| 22 | * TEXT_SECTION = 0 |
| 23 | * _etext = .; |
| 24 | * |
| 25 | * _sdata = .; |
| 26 | * RO_DATA_SECTION(PAGE_SIZE) |
| 27 | * RW_DATA_SECTION(...) |
| 28 | * _edata = .; |
| 29 | * |
| 30 | * EXCEPTION_TABLE(...) |
| 31 | * NOTES |
| 32 | * |
Tim Abbott | 04e448d | 2009-07-12 18:23:33 -0400 | [diff] [blame] | 33 | * BSS_SECTION(0, 0, 0) |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 34 | * _end = .; |
| 35 | * |
| 36 | * /DISCARD/ : { |
| 37 | * EXIT_TEXT |
| 38 | * EXIT_DATA |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 39 | * EXIT_CALL |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 40 | * } |
| 41 | * STABS_DEBUG |
| 42 | * DWARF_DEBUG |
| 43 | * } |
| 44 | * |
| 45 | * [__init_begin, __init_end] is the init section that may be freed after init |
| 46 | * [_stext, _etext] is the text section |
| 47 | * [_sdata, _edata] is the data section |
| 48 | * |
| 49 | * Some of the included output section have their own set of constants. |
| 50 | * Examples are: [__initramfs_start, __initramfs_end] for initramfs and |
| 51 | * [__nosave_begin, __nosave_end] for the nosave data |
| 52 | */ |
Tim Abbott | c80d471 | 2009-04-25 22:10:56 -0400 | [diff] [blame] | 53 | |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 54 | #ifndef LOAD_OFFSET |
| 55 | #define LOAD_OFFSET 0 |
| 56 | #endif |
| 57 | |
| 58 | #ifndef VMLINUX_SYMBOL |
| 59 | #define VMLINUX_SYMBOL(_sym_) _sym_ |
| 60 | #endif |
| 61 | |
Sam Ravnborg | 6d30e3a | 2005-07-14 20:15:44 +0000 | [diff] [blame] | 62 | /* Align . to a 8 byte boundary equals to maximum function alignment. */ |
| 63 | #define ALIGN_FUNCTION() . = ALIGN(8) |
| 64 | |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 65 | /* The actual configuration determine if the init/exit sections |
| 66 | * are handled as text/data or they can be discarded (which |
| 67 | * often happens at runtime) |
| 68 | */ |
| 69 | #ifdef CONFIG_HOTPLUG |
| 70 | #define DEV_KEEP(sec) *(.dev##sec) |
| 71 | #define DEV_DISCARD(sec) |
| 72 | #else |
| 73 | #define DEV_KEEP(sec) |
| 74 | #define DEV_DISCARD(sec) *(.dev##sec) |
| 75 | #endif |
| 76 | |
| 77 | #ifdef CONFIG_HOTPLUG_CPU |
| 78 | #define CPU_KEEP(sec) *(.cpu##sec) |
| 79 | #define CPU_DISCARD(sec) |
| 80 | #else |
| 81 | #define CPU_KEEP(sec) |
| 82 | #define CPU_DISCARD(sec) *(.cpu##sec) |
| 83 | #endif |
| 84 | |
Adrian Bunk | 1a3fb6d | 2008-01-24 22:20:18 +0100 | [diff] [blame] | 85 | #if defined(CONFIG_MEMORY_HOTPLUG) |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 86 | #define MEM_KEEP(sec) *(.mem##sec) |
| 87 | #define MEM_DISCARD(sec) |
| 88 | #else |
| 89 | #define MEM_KEEP(sec) |
| 90 | #define MEM_DISCARD(sec) *(.mem##sec) |
| 91 | #endif |
| 92 | |
Steven Rostedt | 8da3821 | 2008-08-14 15:45:07 -0400 | [diff] [blame] | 93 | #ifdef CONFIG_FTRACE_MCOUNT_RECORD |
| 94 | #define MCOUNT_REC() VMLINUX_SYMBOL(__start_mcount_loc) = .; \ |
| 95 | *(__mcount_loc) \ |
| 96 | VMLINUX_SYMBOL(__stop_mcount_loc) = .; |
| 97 | #else |
| 98 | #define MCOUNT_REC() |
| 99 | #endif |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 100 | |
Steven Rostedt | 2ed84ee | 2008-11-12 15:24:24 -0500 | [diff] [blame] | 101 | #ifdef CONFIG_TRACE_BRANCH_PROFILING |
Steven Rostedt | 45b7974 | 2008-11-21 00:40:40 -0500 | [diff] [blame] | 102 | #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \ |
| 103 | *(_ftrace_annotated_branch) \ |
| 104 | VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .; |
Steven Rostedt | 1f0d69a | 2008-11-12 00:14:39 -0500 | [diff] [blame] | 105 | #else |
| 106 | #define LIKELY_PROFILE() |
| 107 | #endif |
| 108 | |
Steven Rostedt | 2bcd521 | 2008-11-21 01:30:54 -0500 | [diff] [blame] | 109 | #ifdef CONFIG_PROFILE_ALL_BRANCHES |
| 110 | #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \ |
| 111 | *(_ftrace_branch) \ |
| 112 | VMLINUX_SYMBOL(__stop_branch_profile) = .; |
| 113 | #else |
| 114 | #define BRANCH_PROFILE() |
| 115 | #endif |
| 116 | |
Tom Zanussi | 5f77a88 | 2009-04-08 03:14:01 -0500 | [diff] [blame] | 117 | #ifdef CONFIG_EVENT_TRACING |
Steven Rostedt | b77e38a | 2009-02-24 10:21:36 -0500 | [diff] [blame] | 118 | #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \ |
| 119 | *(_ftrace_events) \ |
| 120 | VMLINUX_SYMBOL(__stop_ftrace_events) = .; |
| 121 | #else |
| 122 | #define FTRACE_EVENTS() |
| 123 | #endif |
| 124 | |
Lai Jiangshan | 1ba28e0 | 2009-03-06 17:21:48 +0100 | [diff] [blame] | 125 | #ifdef CONFIG_TRACING |
| 126 | #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \ |
| 127 | *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \ |
| 128 | VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .; |
| 129 | #else |
| 130 | #define TRACE_PRINTKS() |
| 131 | #endif |
| 132 | |
Frederic Weisbecker | bed1ffc | 2009-03-13 15:42:11 +0100 | [diff] [blame] | 133 | #ifdef CONFIG_FTRACE_SYSCALLS |
| 134 | #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \ |
| 135 | *(__syscalls_metadata) \ |
| 136 | VMLINUX_SYMBOL(__stop_syscalls_metadata) = .; |
| 137 | #else |
| 138 | #define TRACE_SYSCALLS() |
| 139 | #endif |
| 140 | |
Sam Ravnborg | ca96725 | 2007-05-17 13:38:44 +0200 | [diff] [blame] | 141 | /* .data section */ |
| 142 | #define DATA_DATA \ |
Sam Ravnborg | 0e0d314 | 2007-05-17 20:14:48 +0200 | [diff] [blame] | 143 | *(.data) \ |
Sam Ravnborg | 312b148 | 2008-01-28 20:21:15 +0100 | [diff] [blame] | 144 | *(.ref.data) \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 145 | DEV_KEEP(init.data) \ |
| 146 | DEV_KEEP(exit.data) \ |
| 147 | CPU_KEEP(init.data) \ |
| 148 | CPU_KEEP(exit.data) \ |
| 149 | MEM_KEEP(init.data) \ |
| 150 | MEM_KEEP(exit.data) \ |
Mathieu Desnoyers | 8256e47 | 2007-10-18 23:41:06 -0700 | [diff] [blame] | 151 | . = ALIGN(8); \ |
| 152 | VMLINUX_SYMBOL(__start___markers) = .; \ |
| 153 | *(__markers) \ |
Mathieu Desnoyers | 97e1c18 | 2008-07-18 12:16:16 -0400 | [diff] [blame] | 154 | VMLINUX_SYMBOL(__stop___markers) = .; \ |
Mathieu Desnoyers | 7e066fb | 2008-11-14 17:47:47 -0500 | [diff] [blame] | 155 | . = ALIGN(32); \ |
Mathieu Desnoyers | 97e1c18 | 2008-07-18 12:16:16 -0400 | [diff] [blame] | 156 | VMLINUX_SYMBOL(__start___tracepoints) = .; \ |
| 157 | *(__tracepoints) \ |
Steven Rostedt | 1f0d69a | 2008-11-12 00:14:39 -0500 | [diff] [blame] | 158 | VMLINUX_SYMBOL(__stop___tracepoints) = .; \ |
Jason Baron | e9d376f | 2009-02-05 11:51:38 -0500 | [diff] [blame] | 159 | /* implement dynamic printk debug */ \ |
| 160 | . = ALIGN(8); \ |
| 161 | VMLINUX_SYMBOL(__start___verbose) = .; \ |
| 162 | *(__verbose) \ |
| 163 | VMLINUX_SYMBOL(__stop___verbose) = .; \ |
Steven Rostedt | 2bcd521 | 2008-11-21 01:30:54 -0500 | [diff] [blame] | 164 | LIKELY_PROFILE() \ |
Steven Rostedt | b77e38a | 2009-02-24 10:21:36 -0500 | [diff] [blame] | 165 | BRANCH_PROFILE() \ |
Ingo Molnar | 8a20d84 | 2009-03-09 10:09:06 +0100 | [diff] [blame] | 166 | TRACE_PRINTKS() \ |
Frederic Weisbecker | bed1ffc | 2009-03-13 15:42:11 +0100 | [diff] [blame] | 167 | FTRACE_EVENTS() \ |
| 168 | TRACE_SYSCALLS() |
Sam Ravnborg | ca96725 | 2007-05-17 13:38:44 +0200 | [diff] [blame] | 169 | |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 170 | /* |
| 171 | * Data section helpers |
| 172 | */ |
| 173 | #define NOSAVE_DATA \ |
| 174 | . = ALIGN(PAGE_SIZE); \ |
| 175 | VMLINUX_SYMBOL(__nosave_begin) = .; \ |
| 176 | *(.data.nosave) \ |
| 177 | . = ALIGN(PAGE_SIZE); \ |
| 178 | VMLINUX_SYMBOL(__nosave_end) = .; |
| 179 | |
| 180 | #define PAGE_ALIGNED_DATA(page_align) \ |
| 181 | . = ALIGN(page_align); \ |
| 182 | *(.data.page_aligned) |
| 183 | |
| 184 | #define READ_MOSTLY_DATA(align) \ |
| 185 | . = ALIGN(align); \ |
| 186 | *(.data.read_mostly) |
| 187 | |
| 188 | #define CACHELINE_ALIGNED_DATA(align) \ |
| 189 | . = ALIGN(align); \ |
| 190 | *(.data.cacheline_aligned) |
| 191 | |
Tim Abbott | 39a449d | 2009-06-23 18:53:15 -0400 | [diff] [blame] | 192 | #define INIT_TASK_DATA(align) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 193 | . = ALIGN(align); \ |
| 194 | *(.data.init_task) |
| 195 | |
| 196 | /* |
| 197 | * Read only Data |
| 198 | */ |
| 199 | #define RO_DATA_SECTION(align) \ |
Sam Ravnborg | 4096b46 | 2007-05-29 21:29:00 +0200 | [diff] [blame] | 200 | . = ALIGN((align)); \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 201 | .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \ |
Vivek Goyal | 6569580 | 2006-12-07 02:14:03 +0100 | [diff] [blame] | 202 | VMLINUX_SYMBOL(__start_rodata) = .; \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 203 | *(.rodata) *(.rodata.*) \ |
| 204 | *(__vermagic) /* Kernel version magic */ \ |
Mathieu Desnoyers | 8256e47 | 2007-10-18 23:41:06 -0700 | [diff] [blame] | 205 | *(__markers_strings) /* Markers: strings */ \ |
Mathieu Desnoyers | 97e1c18 | 2008-07-18 12:16:16 -0400 | [diff] [blame] | 206 | *(__tracepoints_strings)/* Tracepoints: strings */ \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 207 | } \ |
| 208 | \ |
| 209 | .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \ |
| 210 | *(.rodata1) \ |
| 211 | } \ |
| 212 | \ |
Jan Beulich | 6360b1f | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 213 | BUG_TABLE \ |
| 214 | \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 215 | /* PCI quirks */ \ |
| 216 | .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \ |
| 217 | VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \ |
| 218 | *(.pci_fixup_early) \ |
| 219 | VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \ |
| 220 | VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \ |
| 221 | *(.pci_fixup_header) \ |
| 222 | VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \ |
| 223 | VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \ |
| 224 | *(.pci_fixup_final) \ |
| 225 | VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \ |
| 226 | VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \ |
| 227 | *(.pci_fixup_enable) \ |
| 228 | VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \ |
Alan Cox | 1597cac | 2006-12-04 15:14:45 -0800 | [diff] [blame] | 229 | VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \ |
| 230 | *(.pci_fixup_resume) \ |
| 231 | VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \ |
Rafael J. Wysocki | e1a2a51 | 2008-05-15 21:51:31 +0200 | [diff] [blame] | 232 | VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \ |
| 233 | *(.pci_fixup_resume_early) \ |
| 234 | VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \ |
| 235 | VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \ |
| 236 | *(.pci_fixup_suspend) \ |
| 237 | VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 238 | } \ |
| 239 | \ |
David Woodhouse | 5658c76 | 2008-05-23 13:52:42 +0100 | [diff] [blame] | 240 | /* Built-in firmware blobs */ \ |
| 241 | .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \ |
| 242 | VMLINUX_SYMBOL(__start_builtin_fw) = .; \ |
| 243 | *(.builtin_fw) \ |
| 244 | VMLINUX_SYMBOL(__end_builtin_fw) = .; \ |
| 245 | } \ |
| 246 | \ |
Matt Porter | 394b701 | 2005-11-07 01:00:15 -0800 | [diff] [blame] | 247 | /* RapidIO route ops */ \ |
| 248 | .rio_route : AT(ADDR(.rio_route) - LOAD_OFFSET) { \ |
| 249 | VMLINUX_SYMBOL(__start_rio_route_ops) = .; \ |
| 250 | *(.rio_route_ops) \ |
| 251 | VMLINUX_SYMBOL(__end_rio_route_ops) = .; \ |
| 252 | } \ |
| 253 | \ |
Jan Beulich | 63687a5 | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 254 | TRACEDATA \ |
| 255 | \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 256 | /* Kernel symbol table: Normal symbols */ \ |
| 257 | __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \ |
| 258 | VMLINUX_SYMBOL(__start___ksymtab) = .; \ |
| 259 | *(__ksymtab) \ |
| 260 | VMLINUX_SYMBOL(__stop___ksymtab) = .; \ |
| 261 | } \ |
| 262 | \ |
| 263 | /* Kernel symbol table: GPL-only symbols */ \ |
| 264 | __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \ |
| 265 | VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \ |
| 266 | *(__ksymtab_gpl) \ |
| 267 | VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \ |
| 268 | } \ |
| 269 | \ |
Arjan van de Ven | f71d20e | 2006-06-28 04:26:45 -0700 | [diff] [blame] | 270 | /* Kernel symbol table: Normal unused symbols */ \ |
| 271 | __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \ |
| 272 | VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \ |
| 273 | *(__ksymtab_unused) \ |
| 274 | VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \ |
| 275 | } \ |
| 276 | \ |
| 277 | /* Kernel symbol table: GPL-only unused symbols */ \ |
| 278 | __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \ |
| 279 | VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \ |
| 280 | *(__ksymtab_unused_gpl) \ |
| 281 | VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \ |
| 282 | } \ |
| 283 | \ |
Greg Kroah-Hartman | 9f28bb7 | 2006-03-20 13:17:13 -0800 | [diff] [blame] | 284 | /* Kernel symbol table: GPL-future-only symbols */ \ |
| 285 | __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \ |
| 286 | VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \ |
| 287 | *(__ksymtab_gpl_future) \ |
| 288 | VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \ |
| 289 | } \ |
| 290 | \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 291 | /* Kernel symbol table: Normal symbols */ \ |
| 292 | __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \ |
| 293 | VMLINUX_SYMBOL(__start___kcrctab) = .; \ |
| 294 | *(__kcrctab) \ |
| 295 | VMLINUX_SYMBOL(__stop___kcrctab) = .; \ |
| 296 | } \ |
| 297 | \ |
| 298 | /* Kernel symbol table: GPL-only symbols */ \ |
| 299 | __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \ |
| 300 | VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \ |
| 301 | *(__kcrctab_gpl) \ |
| 302 | VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \ |
| 303 | } \ |
| 304 | \ |
Arjan van de Ven | f71d20e | 2006-06-28 04:26:45 -0700 | [diff] [blame] | 305 | /* Kernel symbol table: Normal unused symbols */ \ |
| 306 | __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \ |
| 307 | VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \ |
| 308 | *(__kcrctab_unused) \ |
| 309 | VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \ |
| 310 | } \ |
| 311 | \ |
| 312 | /* Kernel symbol table: GPL-only unused symbols */ \ |
| 313 | __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \ |
| 314 | VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \ |
| 315 | *(__kcrctab_unused_gpl) \ |
| 316 | VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \ |
| 317 | } \ |
| 318 | \ |
Greg Kroah-Hartman | 9f28bb7 | 2006-03-20 13:17:13 -0800 | [diff] [blame] | 319 | /* Kernel symbol table: GPL-future-only symbols */ \ |
| 320 | __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \ |
| 321 | VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \ |
| 322 | *(__kcrctab_gpl_future) \ |
| 323 | VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \ |
| 324 | } \ |
| 325 | \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 326 | /* Kernel symbol table: strings */ \ |
| 327 | __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \ |
| 328 | *(__ksymtab_strings) \ |
| 329 | } \ |
| 330 | \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 331 | /* __*init sections */ \ |
| 332 | __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \ |
Sam Ravnborg | 312b148 | 2008-01-28 20:21:15 +0100 | [diff] [blame] | 333 | *(.ref.rodata) \ |
Steven Rostedt | 8da3821 | 2008-08-14 15:45:07 -0400 | [diff] [blame] | 334 | MCOUNT_REC() \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 335 | DEV_KEEP(init.rodata) \ |
| 336 | DEV_KEEP(exit.rodata) \ |
| 337 | CPU_KEEP(init.rodata) \ |
| 338 | CPU_KEEP(exit.rodata) \ |
| 339 | MEM_KEEP(init.rodata) \ |
| 340 | MEM_KEEP(exit.rodata) \ |
| 341 | } \ |
| 342 | \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 343 | /* Built-in module parameters. */ \ |
| 344 | __param : AT(ADDR(__param) - LOAD_OFFSET) { \ |
| 345 | VMLINUX_SYMBOL(__start___param) = .; \ |
| 346 | *(__param) \ |
| 347 | VMLINUX_SYMBOL(__stop___param) = .; \ |
Arjan van de Ven | edeed30 | 2008-01-30 13:34:08 +0100 | [diff] [blame] | 348 | . = ALIGN((align)); \ |
Vivek Goyal | 6569580 | 2006-12-07 02:14:03 +0100 | [diff] [blame] | 349 | VMLINUX_SYMBOL(__end_rodata) = .; \ |
Marcelo Tosatti | 7583ddf | 2006-09-27 01:51:02 -0700 | [diff] [blame] | 350 | } \ |
Sam Ravnborg | 4096b46 | 2007-05-29 21:29:00 +0200 | [diff] [blame] | 351 | . = ALIGN((align)); |
| 352 | |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 353 | /* RODATA & RO_DATA provided for backward compatibility. |
Sam Ravnborg | 4096b46 | 2007-05-29 21:29:00 +0200 | [diff] [blame] | 354 | * All archs are supposed to use RO_DATA() */ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 355 | #define RODATA RO_DATA_SECTION(4096) |
| 356 | #define RO_DATA(align) RO_DATA_SECTION(align) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 357 | |
| 358 | #define SECURITY_INIT \ |
Eric W. Biederman | 60bad7f | 2005-06-25 14:57:46 -0700 | [diff] [blame] | 359 | .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 360 | VMLINUX_SYMBOL(__security_initcall_start) = .; \ |
| 361 | *(.security_initcall.init) \ |
| 362 | VMLINUX_SYMBOL(__security_initcall_end) = .; \ |
| 363 | } |
| 364 | |
Sam Ravnborg | 7664709 | 2007-05-13 00:31:33 +0200 | [diff] [blame] | 365 | /* .text section. Map to function alignment to avoid address changes |
| 366 | * during second ld run in second ld pass when generating System.map */ |
| 367 | #define TEXT_TEXT \ |
| 368 | ALIGN_FUNCTION(); \ |
Jan Beulich | fb5e2b3 | 2008-06-18 12:36:01 +0100 | [diff] [blame] | 369 | *(.text.hot) \ |
Sam Ravnborg | 0e0d314 | 2007-05-17 20:14:48 +0200 | [diff] [blame] | 370 | *(.text) \ |
Sam Ravnborg | 312b148 | 2008-01-28 20:21:15 +0100 | [diff] [blame] | 371 | *(.ref.text) \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 372 | DEV_KEEP(init.text) \ |
| 373 | DEV_KEEP(exit.text) \ |
| 374 | CPU_KEEP(init.text) \ |
| 375 | CPU_KEEP(exit.text) \ |
| 376 | MEM_KEEP(init.text) \ |
Jan Beulich | fb5e2b3 | 2008-06-18 12:36:01 +0100 | [diff] [blame] | 377 | MEM_KEEP(exit.text) \ |
| 378 | *(.text.unlikely) |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 379 | |
Sam Ravnborg | 7664709 | 2007-05-13 00:31:33 +0200 | [diff] [blame] | 380 | |
Sam Ravnborg | 6d30e3a | 2005-07-14 20:15:44 +0000 | [diff] [blame] | 381 | /* sched.text is aling to function alignment to secure we have same |
| 382 | * address even at second ld pass when generating System.map */ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 383 | #define SCHED_TEXT \ |
Sam Ravnborg | 6d30e3a | 2005-07-14 20:15:44 +0000 | [diff] [blame] | 384 | ALIGN_FUNCTION(); \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 385 | VMLINUX_SYMBOL(__sched_text_start) = .; \ |
| 386 | *(.sched.text) \ |
| 387 | VMLINUX_SYMBOL(__sched_text_end) = .; |
| 388 | |
Sam Ravnborg | 6d30e3a | 2005-07-14 20:15:44 +0000 | [diff] [blame] | 389 | /* spinlock.text is aling to function alignment to secure we have same |
| 390 | * address even at second ld pass when generating System.map */ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 391 | #define LOCK_TEXT \ |
Sam Ravnborg | 6d30e3a | 2005-07-14 20:15:44 +0000 | [diff] [blame] | 392 | ALIGN_FUNCTION(); \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 393 | VMLINUX_SYMBOL(__lock_text_start) = .; \ |
| 394 | *(.spinlock.text) \ |
| 395 | VMLINUX_SYMBOL(__lock_text_end) = .; |
Prasanna S Panchamukhi | d0aaff9 | 2005-09-06 15:19:26 -0700 | [diff] [blame] | 396 | |
| 397 | #define KPROBES_TEXT \ |
| 398 | ALIGN_FUNCTION(); \ |
| 399 | VMLINUX_SYMBOL(__kprobes_text_start) = .; \ |
| 400 | *(.kprobes.text) \ |
| 401 | VMLINUX_SYMBOL(__kprobes_text_end) = .; |
Paolo 'Blaisorblade' Giarrusso | a7d0c21 | 2005-09-10 19:44:54 +0200 | [diff] [blame] | 402 | |
Frederic Weisbecker | a0343e8 | 2008-12-09 23:53:16 +0100 | [diff] [blame] | 403 | #ifdef CONFIG_FUNCTION_GRAPH_TRACER |
| 404 | #define IRQENTRY_TEXT \ |
| 405 | ALIGN_FUNCTION(); \ |
| 406 | VMLINUX_SYMBOL(__irqentry_text_start) = .; \ |
| 407 | *(.irqentry.text) \ |
| 408 | VMLINUX_SYMBOL(__irqentry_text_end) = .; |
| 409 | #else |
| 410 | #define IRQENTRY_TEXT |
| 411 | #endif |
| 412 | |
Sam Ravnborg | 37c514e | 2008-02-19 21:00:18 +0100 | [diff] [blame] | 413 | /* Section used for early init (in .S files) */ |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 414 | #define HEAD_TEXT *(.head.text) |
Sam Ravnborg | 37c514e | 2008-02-19 21:00:18 +0100 | [diff] [blame] | 415 | |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 416 | #define HEAD_TEXT_SECTION \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 417 | .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \ |
| 418 | HEAD_TEXT \ |
| 419 | } |
| 420 | |
| 421 | /* |
| 422 | * Exception table |
| 423 | */ |
| 424 | #define EXCEPTION_TABLE(align) \ |
| 425 | . = ALIGN(align); \ |
| 426 | __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \ |
| 427 | VMLINUX_SYMBOL(__start___ex_table) = .; \ |
| 428 | *(__ex_table) \ |
| 429 | VMLINUX_SYMBOL(__stop___ex_table) = .; \ |
| 430 | } |
| 431 | |
| 432 | /* |
| 433 | * Init task |
| 434 | */ |
Tim Abbott | 39a449d | 2009-06-23 18:53:15 -0400 | [diff] [blame] | 435 | #define INIT_TASK_DATA_SECTION(align) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 436 | . = ALIGN(align); \ |
| 437 | .data.init_task : { \ |
Tim Abbott | 39a449d | 2009-06-23 18:53:15 -0400 | [diff] [blame] | 438 | INIT_TASK_DATA(align) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 439 | } |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 440 | |
Peter Oberparleiter | b99b87f | 2009-06-17 16:28:03 -0700 | [diff] [blame] | 441 | #ifdef CONFIG_CONSTRUCTORS |
Heiko Carstens | 2a2325e | 2009-06-30 11:41:13 -0700 | [diff] [blame] | 442 | #define KERNEL_CTORS() . = ALIGN(8); \ |
| 443 | VMLINUX_SYMBOL(__ctors_start) = .; \ |
Peter Oberparleiter | b99b87f | 2009-06-17 16:28:03 -0700 | [diff] [blame] | 444 | *(.ctors) \ |
| 445 | VMLINUX_SYMBOL(__ctors_end) = .; |
| 446 | #else |
| 447 | #define KERNEL_CTORS() |
| 448 | #endif |
| 449 | |
Sam Ravnborg | 01ba2bd | 2008-01-20 14:15:03 +0100 | [diff] [blame] | 450 | /* init and exit section handling */ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 451 | #define INIT_DATA \ |
| 452 | *(.init.data) \ |
| 453 | DEV_DISCARD(init.data) \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 454 | CPU_DISCARD(init.data) \ |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 455 | MEM_DISCARD(init.data) \ |
Peter Oberparleiter | b99b87f | 2009-06-17 16:28:03 -0700 | [diff] [blame] | 456 | KERNEL_CTORS() \ |
Jan Beulich | fd6c3a8 | 2009-03-12 10:58:33 +0000 | [diff] [blame] | 457 | *(.init.rodata) \ |
| 458 | DEV_DISCARD(init.rodata) \ |
| 459 | CPU_DISCARD(init.rodata) \ |
Jason Baron | e9d376f | 2009-02-05 11:51:38 -0500 | [diff] [blame] | 460 | MEM_DISCARD(init.rodata) |
Sam Ravnborg | 01ba2bd | 2008-01-20 14:15:03 +0100 | [diff] [blame] | 461 | |
Sam Ravnborg | eb8f689 | 2008-01-20 20:07:28 +0100 | [diff] [blame] | 462 | #define INIT_TEXT \ |
| 463 | *(.init.text) \ |
| 464 | DEV_DISCARD(init.text) \ |
| 465 | CPU_DISCARD(init.text) \ |
| 466 | MEM_DISCARD(init.text) |
| 467 | |
| 468 | #define EXIT_DATA \ |
| 469 | *(.exit.data) \ |
| 470 | DEV_DISCARD(exit.data) \ |
| 471 | DEV_DISCARD(exit.rodata) \ |
| 472 | CPU_DISCARD(exit.data) \ |
| 473 | CPU_DISCARD(exit.rodata) \ |
| 474 | MEM_DISCARD(exit.data) \ |
| 475 | MEM_DISCARD(exit.rodata) |
| 476 | |
| 477 | #define EXIT_TEXT \ |
| 478 | *(.exit.text) \ |
| 479 | DEV_DISCARD(exit.text) \ |
| 480 | CPU_DISCARD(exit.text) \ |
| 481 | MEM_DISCARD(exit.text) |
Sam Ravnborg | 01ba2bd | 2008-01-20 14:15:03 +0100 | [diff] [blame] | 482 | |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 483 | #define EXIT_CALL \ |
| 484 | *(.exitcall.exit) |
| 485 | |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 486 | /* |
| 487 | * bss (Block Started by Symbol) - uninitialized data |
| 488 | * zeroed during startup |
| 489 | */ |
Tim Abbott | 04e448d | 2009-07-12 18:23:33 -0400 | [diff] [blame] | 490 | #define SBSS(sbss_align) \ |
| 491 | . = ALIGN(sbss_align); \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 492 | .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \ |
| 493 | *(.sbss) \ |
| 494 | *(.scommon) \ |
| 495 | } |
| 496 | |
| 497 | #define BSS(bss_align) \ |
| 498 | . = ALIGN(bss_align); \ |
| 499 | .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 500 | *(.bss.page_aligned) \ |
| 501 | *(.dynbss) \ |
| 502 | *(.bss) \ |
| 503 | *(COMMON) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 504 | } |
| 505 | |
| 506 | /* |
| 507 | * DWARF debug sections. |
| 508 | * Symbols in the DWARF debugging sections are relative to |
| 509 | * the beginning of the section so we begin them at 0. |
| 510 | */ |
Paolo 'Blaisorblade' Giarrusso | a7d0c21 | 2005-09-10 19:44:54 +0200 | [diff] [blame] | 511 | #define DWARF_DEBUG \ |
| 512 | /* DWARF 1 */ \ |
| 513 | .debug 0 : { *(.debug) } \ |
| 514 | .line 0 : { *(.line) } \ |
| 515 | /* GNU DWARF 1 extensions */ \ |
| 516 | .debug_srcinfo 0 : { *(.debug_srcinfo) } \ |
| 517 | .debug_sfnames 0 : { *(.debug_sfnames) } \ |
| 518 | /* DWARF 1.1 and DWARF 2 */ \ |
| 519 | .debug_aranges 0 : { *(.debug_aranges) } \ |
| 520 | .debug_pubnames 0 : { *(.debug_pubnames) } \ |
| 521 | /* DWARF 2 */ \ |
| 522 | .debug_info 0 : { *(.debug_info \ |
| 523 | .gnu.linkonce.wi.*) } \ |
| 524 | .debug_abbrev 0 : { *(.debug_abbrev) } \ |
| 525 | .debug_line 0 : { *(.debug_line) } \ |
| 526 | .debug_frame 0 : { *(.debug_frame) } \ |
| 527 | .debug_str 0 : { *(.debug_str) } \ |
| 528 | .debug_loc 0 : { *(.debug_loc) } \ |
| 529 | .debug_macinfo 0 : { *(.debug_macinfo) } \ |
| 530 | /* SGI/MIPS DWARF 2 extensions */ \ |
| 531 | .debug_weaknames 0 : { *(.debug_weaknames) } \ |
| 532 | .debug_funcnames 0 : { *(.debug_funcnames) } \ |
| 533 | .debug_typenames 0 : { *(.debug_typenames) } \ |
| 534 | .debug_varnames 0 : { *(.debug_varnames) } \ |
| 535 | |
| 536 | /* Stabs debugging sections. */ |
| 537 | #define STABS_DEBUG \ |
| 538 | .stab 0 : { *(.stab) } \ |
| 539 | .stabstr 0 : { *(.stabstr) } \ |
| 540 | .stab.excl 0 : { *(.stab.excl) } \ |
| 541 | .stab.exclstr 0 : { *(.stab.exclstr) } \ |
| 542 | .stab.index 0 : { *(.stab.index) } \ |
| 543 | .stab.indexstr 0 : { *(.stab.indexstr) } \ |
| 544 | .comment 0 : { *(.comment) } |
Jeremy Fitzhardinge | 9c9b8b3 | 2006-09-25 23:32:26 -0700 | [diff] [blame] | 545 | |
Jan Beulich | 6360b1f | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 546 | #ifdef CONFIG_GENERIC_BUG |
Jeremy Fitzhardinge | 7664c5a | 2006-12-08 02:36:19 -0800 | [diff] [blame] | 547 | #define BUG_TABLE \ |
| 548 | . = ALIGN(8); \ |
| 549 | __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \ |
Yoshinori Sato | c6de002 | 2008-07-31 00:07:29 -0700 | [diff] [blame] | 550 | VMLINUX_SYMBOL(__start___bug_table) = .; \ |
Jeremy Fitzhardinge | 7664c5a | 2006-12-08 02:36:19 -0800 | [diff] [blame] | 551 | *(__bug_table) \ |
Yoshinori Sato | c6de002 | 2008-07-31 00:07:29 -0700 | [diff] [blame] | 552 | VMLINUX_SYMBOL(__stop___bug_table) = .; \ |
Jeremy Fitzhardinge | 7664c5a | 2006-12-08 02:36:19 -0800 | [diff] [blame] | 553 | } |
Jan Beulich | 6360b1f | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 554 | #else |
| 555 | #define BUG_TABLE |
| 556 | #endif |
Jeremy Fitzhardinge | 7664c5a | 2006-12-08 02:36:19 -0800 | [diff] [blame] | 557 | |
Jan Beulich | 63687a5 | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 558 | #ifdef CONFIG_PM_TRACE |
| 559 | #define TRACEDATA \ |
| 560 | . = ALIGN(4); \ |
| 561 | .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \ |
Yoshinori Sato | c6de002 | 2008-07-31 00:07:29 -0700 | [diff] [blame] | 562 | VMLINUX_SYMBOL(__tracedata_start) = .; \ |
Jan Beulich | 63687a5 | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 563 | *(.tracedata) \ |
Yoshinori Sato | c6de002 | 2008-07-31 00:07:29 -0700 | [diff] [blame] | 564 | VMLINUX_SYMBOL(__tracedata_end) = .; \ |
Jan Beulich | 63687a5 | 2008-05-12 15:44:41 +0200 | [diff] [blame] | 565 | } |
| 566 | #else |
| 567 | #define TRACEDATA |
| 568 | #endif |
| 569 | |
Jeremy Fitzhardinge | 9c9b8b3 | 2006-09-25 23:32:26 -0700 | [diff] [blame] | 570 | #define NOTES \ |
Roland McGrath | cbe8712 | 2007-07-19 01:48:36 -0700 | [diff] [blame] | 571 | .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \ |
| 572 | VMLINUX_SYMBOL(__start_notes) = .; \ |
| 573 | *(.note.*) \ |
| 574 | VMLINUX_SYMBOL(__stop_notes) = .; \ |
| 575 | } |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 576 | |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 577 | #define INIT_SETUP(initsetup_align) \ |
| 578 | . = ALIGN(initsetup_align); \ |
| 579 | VMLINUX_SYMBOL(__setup_start) = .; \ |
| 580 | *(.init.setup) \ |
| 581 | VMLINUX_SYMBOL(__setup_end) = .; |
| 582 | |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 583 | #define INITCALLS \ |
Eduard - Gabriel Munteanu | c2147a5 | 2008-07-25 19:45:11 -0700 | [diff] [blame] | 584 | *(.initcallearly.init) \ |
Yoshinori Sato | c6de002 | 2008-07-31 00:07:29 -0700 | [diff] [blame] | 585 | VMLINUX_SYMBOL(__early_initcall_end) = .; \ |
Linus Torvalds | b3438f8 | 2006-11-20 11:47:18 -0800 | [diff] [blame] | 586 | *(.initcall0.init) \ |
| 587 | *(.initcall0s.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 588 | *(.initcall1.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 589 | *(.initcall1s.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 590 | *(.initcall2.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 591 | *(.initcall2s.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 592 | *(.initcall3.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 593 | *(.initcall3s.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 594 | *(.initcall4.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 595 | *(.initcall4s.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 596 | *(.initcall5.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 597 | *(.initcall5s.init) \ |
Linus Torvalds | 8d610dd | 2006-12-11 12:12:04 -0800 | [diff] [blame] | 598 | *(.initcallrootfs.init) \ |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 599 | *(.initcall6.init) \ |
Andrew Morton | 735a7ff | 2006-10-27 11:42:37 -0700 | [diff] [blame] | 600 | *(.initcall6s.init) \ |
| 601 | *(.initcall7.init) \ |
| 602 | *(.initcall7s.init) |
Andrew Morton | 61ce1ef | 2006-10-27 11:41:44 -0700 | [diff] [blame] | 603 | |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 604 | #define INIT_CALLS \ |
| 605 | VMLINUX_SYMBOL(__initcall_start) = .; \ |
| 606 | INITCALLS \ |
| 607 | VMLINUX_SYMBOL(__initcall_end) = .; |
| 608 | |
| 609 | #define CON_INITCALL \ |
| 610 | VMLINUX_SYMBOL(__con_initcall_start) = .; \ |
| 611 | *(.con_initcall.init) \ |
| 612 | VMLINUX_SYMBOL(__con_initcall_end) = .; |
| 613 | |
| 614 | #define SECURITY_INITCALL \ |
| 615 | VMLINUX_SYMBOL(__security_initcall_start) = .; \ |
| 616 | *(.security_initcall.init) \ |
| 617 | VMLINUX_SYMBOL(__security_initcall_end) = .; |
| 618 | |
| 619 | #ifdef CONFIG_BLK_DEV_INITRD |
| 620 | #define INIT_RAM_FS \ |
| 621 | . = ALIGN(PAGE_SIZE); \ |
| 622 | VMLINUX_SYMBOL(__initramfs_start) = .; \ |
| 623 | *(.init.ramfs) \ |
| 624 | VMLINUX_SYMBOL(__initramfs_end) = .; |
| 625 | #else |
David Howells | eadfe21 | 2009-06-22 15:32:31 +0100 | [diff] [blame] | 626 | #define INIT_RAM_FS |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 627 | #endif |
| 628 | |
Tejun Heo | 3e5d8f9 | 2009-01-13 20:41:35 +0900 | [diff] [blame] | 629 | /** |
Tejun Heo | 6b7c38d | 2009-01-19 12:21:28 +0900 | [diff] [blame] | 630 | * PERCPU_VADDR - define output section for percpu area |
Tejun Heo | 3e5d8f9 | 2009-01-13 20:41:35 +0900 | [diff] [blame] | 631 | * @vaddr: explicit base address (optional) |
| 632 | * @phdr: destination PHDR (optional) |
| 633 | * |
| 634 | * Macro which expands to output section for percpu area. If @vaddr |
| 635 | * is not blank, it specifies explicit base address and all percpu |
| 636 | * symbols will be offset from the given address. If blank, @vaddr |
| 637 | * always equals @laddr + LOAD_OFFSET. |
| 638 | * |
| 639 | * @phdr defines the output PHDR to use if not blank. Be warned that |
| 640 | * output PHDR is sticky. If @phdr is specified, the next output |
| 641 | * section in the linker script will go there too. @phdr should have |
| 642 | * a leading colon. |
| 643 | * |
Tejun Heo | 3ac6cff | 2009-01-30 16:32:22 +0900 | [diff] [blame] | 644 | * Note that this macros defines __per_cpu_load as an absolute symbol. |
| 645 | * If there is no need to put the percpu section at a predetermined |
| 646 | * address, use PERCPU(). |
Tejun Heo | 3e5d8f9 | 2009-01-13 20:41:35 +0900 | [diff] [blame] | 647 | */ |
| 648 | #define PERCPU_VADDR(vaddr, phdr) \ |
Ingo Molnar | dba3d36 | 2009-01-29 17:10:12 +0100 | [diff] [blame] | 649 | VMLINUX_SYMBOL(__per_cpu_load) = .; \ |
| 650 | .data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \ |
Tejun Heo | 6b7c38d | 2009-01-19 12:21:28 +0900 | [diff] [blame] | 651 | - LOAD_OFFSET) { \ |
| 652 | VMLINUX_SYMBOL(__per_cpu_start) = .; \ |
Brian Gerst | 0bd74fa | 2009-01-19 12:21:27 +0900 | [diff] [blame] | 653 | *(.data.percpu.first) \ |
Eric Dumazet | 63cc8c7 | 2008-05-12 15:44:40 +0200 | [diff] [blame] | 654 | *(.data.percpu.page_aligned) \ |
Fenghua Yu | 5fb7dc3 | 2007-07-19 01:48:12 -0700 | [diff] [blame] | 655 | *(.data.percpu) \ |
| 656 | *(.data.percpu.shared_aligned) \ |
Tejun Heo | 6b7c38d | 2009-01-19 12:21:28 +0900 | [diff] [blame] | 657 | VMLINUX_SYMBOL(__per_cpu_end) = .; \ |
| 658 | } phdr \ |
Ingo Molnar | dba3d36 | 2009-01-29 17:10:12 +0100 | [diff] [blame] | 659 | . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu); |
Tejun Heo | 3e5d8f9 | 2009-01-13 20:41:35 +0900 | [diff] [blame] | 660 | |
| 661 | /** |
| 662 | * PERCPU - define output section for percpu area, simple version |
| 663 | * @align: required alignment |
| 664 | * |
| 665 | * Align to @align and outputs output section for percpu area. This |
| 666 | * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and |
| 667 | * __per_cpu_start will be identical. |
Tejun Heo | 3ac6cff | 2009-01-30 16:32:22 +0900 | [diff] [blame] | 668 | * |
| 669 | * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except |
| 670 | * that __per_cpu_load is defined as a relative symbol against |
| 671 | * .data.percpu which is required for relocatable x86_32 |
| 672 | * configuration. |
Tejun Heo | 3e5d8f9 | 2009-01-13 20:41:35 +0900 | [diff] [blame] | 673 | */ |
| 674 | #define PERCPU(align) \ |
| 675 | . = ALIGN(align); \ |
Tejun Heo | 3ac6cff | 2009-01-30 16:32:22 +0900 | [diff] [blame] | 676 | .data.percpu : AT(ADDR(.data.percpu) - LOAD_OFFSET) { \ |
| 677 | VMLINUX_SYMBOL(__per_cpu_load) = .; \ |
| 678 | VMLINUX_SYMBOL(__per_cpu_start) = .; \ |
| 679 | *(.data.percpu.first) \ |
| 680 | *(.data.percpu.page_aligned) \ |
| 681 | *(.data.percpu) \ |
| 682 | *(.data.percpu.shared_aligned) \ |
| 683 | VMLINUX_SYMBOL(__per_cpu_end) = .; \ |
| 684 | } |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 685 | |
| 686 | |
| 687 | /* |
| 688 | * Definition of the high level *_SECTION macros |
| 689 | * They will fit only a subset of the architectures |
| 690 | */ |
| 691 | |
| 692 | |
| 693 | /* |
| 694 | * Writeable data. |
| 695 | * All sections are combined in a single .data section. |
| 696 | * The sections following CONSTRUCTORS are arranged so their |
| 697 | * typical alignment matches. |
| 698 | * A cacheline is typical/always less than a PAGE_SIZE so |
| 699 | * the sections that has this restriction (or similar) |
| 700 | * is located before the ones requiring PAGE_SIZE alignment. |
| 701 | * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which |
| 702 | * matches the requirment of PAGE_ALIGNED_DATA. |
| 703 | * |
Sam Ravnborg | 7923f90 | 2009-06-14 22:10:41 +0200 | [diff] [blame] | 704 | * use 0 as page_align if page_aligned data is not used */ |
Paul Mundt | 73f1d93 | 2009-06-24 01:04:36 +0900 | [diff] [blame] | 705 | #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 706 | . = ALIGN(PAGE_SIZE); \ |
| 707 | .data : AT(ADDR(.data) - LOAD_OFFSET) { \ |
Tim Abbott | 39a449d | 2009-06-23 18:53:15 -0400 | [diff] [blame] | 708 | INIT_TASK_DATA(inittask) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 709 | CACHELINE_ALIGNED_DATA(cacheline) \ |
| 710 | READ_MOSTLY_DATA(cacheline) \ |
| 711 | DATA_DATA \ |
| 712 | CONSTRUCTORS \ |
Paul Mundt | 73f1d93 | 2009-06-24 01:04:36 +0900 | [diff] [blame] | 713 | NOSAVE_DATA \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 714 | PAGE_ALIGNED_DATA(pagealigned) \ |
| 715 | } |
| 716 | |
| 717 | #define INIT_TEXT_SECTION(inittext_align) \ |
| 718 | . = ALIGN(inittext_align); \ |
| 719 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \ |
| 720 | VMLINUX_SYMBOL(_sinittext) = .; \ |
| 721 | INIT_TEXT \ |
| 722 | VMLINUX_SYMBOL(_einittext) = .; \ |
| 723 | } |
| 724 | |
| 725 | #define INIT_DATA_SECTION(initsetup_align) \ |
| 726 | .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \ |
| 727 | INIT_DATA \ |
| 728 | INIT_SETUP(initsetup_align) \ |
| 729 | INIT_CALLS \ |
| 730 | CON_INITCALL \ |
| 731 | SECURITY_INITCALL \ |
| 732 | INIT_RAM_FS \ |
| 733 | } |
| 734 | |
Tim Abbott | 04e448d | 2009-07-12 18:23:33 -0400 | [diff] [blame] | 735 | #define BSS_SECTION(sbss_align, bss_align, stop_align) \ |
| 736 | . = ALIGN(sbss_align); \ |
| 737 | VMLINUX_SYMBOL(__bss_start) = .; \ |
| 738 | SBSS(sbss_align) \ |
Sam Ravnborg | ef53dae | 2009-06-07 20:46:37 +0200 | [diff] [blame] | 739 | BSS(bss_align) \ |
Tim Abbott | 04e448d | 2009-07-12 18:23:33 -0400 | [diff] [blame] | 740 | . = ALIGN(stop_align); \ |
| 741 | VMLINUX_SYMBOL(__bss_stop) = .; |