auto import from //depot/cupcake/@135843
diff --git a/djgpp/config.sed b/djgpp/config.sed
new file mode 100644
index 0000000..0869e8c
--- /dev/null
+++ b/djgpp/config.sed
@@ -0,0 +1,164 @@
+# DJGPP specific configuration file.
+# Sed script for additional DJGPP specific editing
+# of the configure script generated by autoconf 2.57.
+
+
+# Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software Foundation,
+# Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
+
+# Additional editing of Makefiles
+/(echo[ ]*':t/ a\
+# DJGPP specific Makefile changes.\
+ /^aliaspath * *=/s,:,";",g;t t\
+ /TEXINPUTS=/s,:,";",g;t t\
+ /PATH=/s,:,";",g;t t\
+ s,\\.deps,_deps,g;t t\
+ s,\\.new\\.,_new.,g;t t\
+ s,\\.old\\.,_old.,g;t t\
+ s,c++\\.at,cxx.at,g;t t\
+ s,c++\\.m4,cxx.m4,g;t t\
+ s,calc++,calcxx,g;t t\
+ s,scan-gram-c,c-scan-gram,g;t t\
+ s,scan-skel-c,c-scan-skel,g;t t\
+ s,Makefile\\.in\\.in,Makefile.in-in,g;t t\
+ s,Makefile\\.am\\.in,Makefile.am-in,g;t t\
+ s,(MAKEINFOFLAGS),& --no-split,\
+ /^install-info-am:/,/^$/ {\
+ /@list=/ s,\\\$(INFO_DEPS),& bison.i,\
+ /@for *file/ s,\\\$(INFO_DEPS),& bison.i,\
+ s,file-\\[0-9\\]\\[0-9\\],& \\$\\$file[0-9] \\$\\$file[0-9][0-9],\
+ }\
+ /^\\.y\\.c:/,/^$/ {\
+ /\\\$(YACCCOMPILE)/ {\
+ a\\\
+ -@test -f y.tab.c && mv -f y.tab.c y_tab.c\\\
+ -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
+ }\
+ }\
+/^libbison.a:/ i\\\
+\\$(top_srcdir)/djgpp/subpipe.c: \\$(top_srcdir)/djgpp/subpipe.h\\\
+subpipe.o: \\$(top_srcdir)/djgpp/subpipe.c \\$(top_srcdir)/djgpp/subpipe.h\\\
+ \\$(COMPILE) -c \\$<\
+/^yacc:/ i\\\
+yacc.bat:\\\
+ echo "bison\\$(EXEEXT) -y %1 %2 %3 %4 %5 %6 %7 %8 %9" >\\$@\
+/^bin_SCRIPTS =/s/$/ yacc.bat/\
+/^MOSTLYCLEANFILES = yacc/s/$/ yacc.bat/
+
+
+# Makefile.in.in is renamed to Makefile.in-in.
+/ac_config_files=/,/_ACEOF/ {
+ s|po/Makefile\.in|&:po/Makefile.in-in|
+}
+/CONFIG_FILES=/ s|po/Makefile\.in|&:po/Makefile.in-in|2
+
+# We always use _deps and _libs instead of .deps and .libs, because
+# the latter is an invalid name on 8+3 MS-DOS file system. This makes
+# the generated Makefiles good for every DJGPP installation, not only
+# the one where the package was configured (which could happen to be
+# a Windows box, where leading dots in file names are allowed).
+s,\.deps,_deps,g
+s,\.libs,_libs,g
+/^rmdir[ ]*\.tst/ i\
+am__leading_dot=_
+
+# Replace (command) > /dev/null with `command > /dev/null`, since
+# parenthesized commands always return zero status in the ported Bash,
+# even if the named command doesn't exist
+/if ([^|;`]*null/{
+ s,(,`,
+ s,),,
+ /null[ ]*2>&1/ s,2>&1,&`,
+ /null.*null/ s,null.*null,&`,
+ /null.*null/ !{
+ /null[ ]*2>&1/ !s,null,&`,
+ }
+}
+
+# DOS-style absolute file names should be supported as well
+/\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,
+
+# Prevent the spliting of subs.sed.
+# The sed script: subs.sed is split into 48 lines long files.
+# This will produce sed scripts called subs-$ac_sed_frag.sed, where
+# $ac_sed_frag is some unique number. This will not work if the splited
+# sed script contains a multiple line sed command at line #48. In this
+# case the first part of the multiple line sed command will be written
+# at the end of one particular subs-$ac_sed_frag.sed and the rest of the
+# sed command will be written at the begining of the next subs-$ac_sed_frag.sed
+# making both sed script useless.
+# This matches the configure script produced by Autoconf 2.57
+/ac_max_sed_lines=[0-9]/ s,=.*$,=`sed -n "$=" $tmp/subs.sed`,
+
+# The following two items are changes needed for configuring
+# and compiling across partitions.
+# 1) The given srcdir value is always translated from the
+# "x:" syntax into "/dev/x" syntax while we run configure.
+/^[ ]*-srcdir=\*.*$/ a\
+ ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
+/set X `ls -Lt \$srcdir/ i\
+ if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
+ srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
+ fi
+
+# Autoconf 2.52e generated configure scripts
+# write absolute paths into Makefiles and bison.in
+# making them useless for DJGPP installations for
+# which the package has not been configured for.
+/MISSING=/,/^$/ {
+ /^fi$/ a\
+am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%'`
+}
+/^install_sh=/a\
+install_sh=`echo "$install_sh" | sed 's%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%'`
+
+# This will only work if the assumption that the
+# testsuite is ran from the following path:
+# ${top_srcdir}/tests/testsuite.dir
+# holds. The explicit names are of no importance.
+# ../../. == ${top_srcdir}
+/\.)[ ]*ac_abs_builddir=/,/^esac$/ {
+ /^esac$/ a\
+ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%"`
+}
+/\.)[ ]*ac_abs_top_builddir=/,/^esac$/ {
+ /^esac$/ a\
+ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%"`
+}
+/\.)[ ]*ac_abs_srcdir=/,/^esac$/ {
+ /^esac$/ a\
+ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%"`
+}
+/\.)[ ]*ac_abs_top_srcdir=/,/^esac$/ {
+ /^esac$/ a\
+ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%"`
+}
+
+# Add DJGPP version information.
+/^#define VERSION/ s/\$VERSION/& (DJGPP port (r1))/
+
+# We need makeinfo to make the html formated docs.
+/\$am_missing_run[ ]*makeinfo/ s,\$am_missing_run,,
+
+# The path to the FORTRAN compiler and libraries
+# shall contain no absolute path reference so it
+# will be good for all djgpp installations.
+/^FLIBS="\$ac_cv_flibs"/ i\
+ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
+ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`
+
+# The following is not a valid DOS file name
+s/calc++/calcxx/g