It's not necessary to do rounding for alloca operations when the requested
alignment is equal to the stack alignment.
git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@40004 91177308-0d34-0410-b5e6-96231b3b80d8
diff --git a/test/lib/llvm.exp b/test/lib/llvm.exp
new file mode 100644
index 0000000..a64692d
--- /dev/null
+++ b/test/lib/llvm.exp
@@ -0,0 +1,234 @@
+# This procedure executes one line of a test case's execution script.
+proc execOneLine { test PRS outcome lineno line } {
+ set status 0
+ set resultmsg ""
+ set retval [ catch { eval exec -keepnewline -- $line } errmsg ]
+ if { $retval != 0 } {
+ set code [lindex $::errorCode 0]
+ set lineno [expr $lineno + 1]
+ if { $PRS != ""} {
+ set PRS " for $PRS"
+ }
+ set errmsg " at line $lineno\nwhile running: $line\n$errmsg"
+ switch "$code" {
+ CHILDSTATUS {
+ set status [lindex $::errorCode 2]
+ if { $status != 0 } {
+ set resultmsg "$test$PRS\nFailed with exit($status)$errmsg"
+ }
+ }
+ CHILDKILLED {
+ set signal [lindex $::errorCode 2]
+ set resultmsg "$test$PRS\nFailed with signal($signal)$errmsg"
+ }
+ CHILDSUSP {
+ set signal [lindex $::errorCode 2]
+ set resultmsg "$test$PRS\nFailed with suspend($signal)$errmsg"
+ }
+ POSIX {
+ set posixNum [lindex $::errorCode 1]
+ set posixMsg [lindex $::errorCode 2]
+ set resultmsg "$test$PRS\nFailed with posix($posixNum,$posixMsg)$errmsg"
+ }
+ NONE {
+ }
+ default {
+ }
+ }
+ }
+ return $resultmsg
+}
+
+# This procedure performs variable substitutions on the RUN: lines of a test
+# cases.
+proc substitute { line test tmpFile } {
+ global srcroot objroot srcdir objdir subdir target_triplet prcontext
+ global llvmgcc llvmgxx llvmgcc_version llvmgccmajvers
+ global gccpath gxxpath compile_c compile_cxx link shlibext llvmlibsdir
+ set path [file join $srcdir $subdir]
+ set tmp [file join Output $tmpFile]
+
+ # Substitute all Tcl variables.
+ set new_line [subst $line ]
+
+ #replace %prcontext with prcontext.tcl (Must replace before %p)
+ regsub -all {%prcontext} $new_line $prcontext new_line
+ #replace %llvmgcc with actual path to llvmgcc
+ regsub -all {%llvmgcc} $new_line "$llvmgcc -emit-llvm" new_line
+ #replace %llvmgxx with actual path to llvmg++
+ regsub -all {%llvmgxx} $new_line "$llvmgxx -emit-llvm" new_line
+ #replace %compile_c with C compilation command
+ regsub -all {%compile_c} $new_line "$compile_c" new_line
+ #replace %compile_cxx with C++ compilation command
+ regsub -all {%compile_cxx} $new_line "$compile_cxx" new_line
+ #replace %link with C++ link command
+ regsub -all {%link} $new_line "$link" new_line
+ #replace %shlibext with shared library extension
+ regsub -all {%shlibext} $new_line "$shlibext" new_line
+ #replace %llvmlibsdir with configure library directory
+ regsub -all {%llvmlibsdir} $new_line "$llvmlibsdir" new_line
+ #replace %p with path to source,
+ regsub -all {%p} $new_line [file join $srcdir $subdir] new_line
+ #replace %s with filename
+ regsub -all {%s} $new_line $test new_line
+ #replace %t with temp filenames
+ regsub -all {%t} $new_line [file join Output $tmpFile] new_line
+ #replace %% with %
+ regsub -all {%%} $new_line % new_line
+ return $new_line
+}
+
+# This procedure runs the set of tests for the test_source_files array.
+proc RunLLVMTests { test_source_files } {
+ global srcroot objroot srcdir objdir subdir target_triplet llvmgcc_version
+ set timeout 60
+
+ set path [file join $objdir $subdir]
+
+ #Make Output Directory if it does not exist already
+ if { [file exists path] } {
+ cd $path
+ } else {
+ file mkdir $path
+ cd $path
+ }
+
+ file mkdir Output
+
+ foreach test $test_source_files {
+ #Should figure out best way to set the timeout
+ #set timeout 40
+
+ set filename [file tail $test]
+ set outcome PASS
+ set tmpFile "$filename.tmp"
+
+ #set hasRunline bool to check if testcase has a runline
+ set numLines 0
+
+ # Open the test file and start reading lines
+ set testFileId [ open $test r]
+ set runline ""
+ set PRNUMS ""
+ foreach line [split [read $testFileId] \n] {
+
+ # if its the END. line then stop parsing (optimization for big files)
+ if {[regexp {END.[ *]$} $line match endofscript]} {
+ break
+
+ # if the line is continued, concatenate and continue the loop
+ } elseif {[regexp {RUN: *(.+)(\\)$} $line match oneline suffix]} {
+ set runline "$runline$oneline "
+
+ # if its a terminating RUN: line then do substitution on the whole line
+ # and then save the line.
+ } elseif {[regexp {RUN: *([^&]+)(&&)?} $line match oneline suffix]} {
+ set runline "$runline$oneline"
+ set runline [ substitute $runline $test $tmpFile ]
+ set lines($numLines) $runline
+ set numLines [expr $numLines + 1]
+ set runline ""
+
+ # if its an PR line, save the problem report number
+ } elseif {[regexp {PR([0-9]+)} $line match prnum]} {
+ if {$PRNUMS == ""} {
+ set PRNUMS "PR$prnum"
+ } else {
+ set PRNUMS "$PRNUMS,$prnum"
+ }
+ # if its an XFAIL line, see if we should be XFAILing or not.
+ } elseif {[regexp {XFAIL:[ *](.+)} $line match targets]} {
+ set targets
+
+ #split up target if more then 1 specified
+ foreach target [split $targets ,] {
+ if { [regexp {\*} $target match] } {
+ set outcome XFAIL
+ } elseif { [regexp $target $target_triplet match] } {
+ set outcome XFAIL
+ } elseif { [regexp {llvmgcc(([0-9]+)|([0-9]+[.][0-9]+))} $target match submatch submatch2] } {
+ if { [regexp ^($submatch)$|^(($submatch)(\.)) $llvmgcc_version match] } {
+ set outcome XFAIL
+ }
+ }
+ }
+ }
+ }
+
+ # Done reading the script
+ close $testFileId
+
+
+ if { $numLines == 0 } {
+ fail "$test: \nDoes not have a RUN line\n"
+ } else {
+ set failed 0
+ for { set i 0 } { $i < $numLines } { set i [ expr $i + 1 ] } {
+ regsub ^.*RUN:(.*) $lines($i) \1 theLine
+ set resultmsg [execOneLine $test $PRNUMS $outcome $i $theLine ]
+ if { $resultmsg != "" } {
+ if { $outcome == "XFAIL" } {
+ xfail "$resultmsg"
+ } else {
+ fail "$resultmsg"
+ }
+ set failed 1
+ break
+ }
+ }
+ if { $failed } {
+ continue
+ } else {
+ if { $PRNUMS != "" } {
+ set PRNUMS " for $PRNUMS"
+ }
+ if { $outcome == "XFAIL" } {
+ xpass "$test$PRNUMS"
+ } else {
+ pass "$test$PRNUMS"
+ }
+ }
+ }
+ }
+}
+
+# This procedure provides an interface to check the LLVMGCC_LANGS makefile
+# variable to see if llvm-gcc supports compilation of a particular language.
+proc llvm_gcc_supports { lang } {
+ global llvmgcc llvmgcc_langs
+ # validate the language choices and determine the name of the compiler
+ # component responsible for determining if the compiler has been built.
+ switch "$lang" {
+ ada { set file gnat1 }
+ c { set file cc1 }
+ c++ { set file cc1plus }
+ objc { set file cc1 }
+ objc++ { set file cc1 }
+ fortran { set file fcc1 }
+ default { return 0 }
+ }
+ foreach supported_lang [split "$llvmgcc_langs" ,] {
+ if { "$lang" == "$supported_lang" } {
+ # FIXME: Knowing it is configured is not enough. We should do two more
+ # checks here. First, we need to run llvm-gcc -print-prog-name=$file to
+ # get the path to the compiler. If we don't get a path, the language isn't
+ # properly configured or built. If we do get a path, we should check to
+ # make sure that it is executable and perhaps even try executing it.
+ return 1;
+ }
+ }
+ return 0;
+}
+
+# This procedure provides an interface to check the TARGETS_TO_BUILD makefile
+# variable to see if a particular target has been configured to build. This
+# helps avoid running tests for targets that aren't available.
+proc llvm_supports_target { tgtName } {
+ global TARGETS_TO_BUILD
+ foreach target [split $TARGETS_TO_BUILD] {
+ if { [regexp $tgtName $target match] } {
+ return 1
+ }
+ }
+ return 0
+}
diff --git a/test/lib/llvm2cpp.exp b/test/lib/llvm2cpp.exp
new file mode 100644
index 0000000..b4141ac
--- /dev/null
+++ b/test/lib/llvm2cpp.exp
@@ -0,0 +1,113 @@
+# This file defines a tcl proc to assist with testing the llvm2cpp. There are
+# no llvm2cpp specific test cases. Instead, it utilizes all the existing test
+# cases and makes sure llvm2cpp can run them. The basic idea is that we find
+# all the LLVM Assembly (*.ll) files, run llvm2cpp on them to generate a C++
+# program, compile those programs, run them and see if what they produce matches
+# the original input to llvm2cpp.
+
+proc llvm2cpp-test { files } {
+ global subdir llvmtoolsdir llvmlibsdir objdir srcdir objroot srcroot
+ set timeout 30
+ set path [file join $objdir $subdir]
+ set llvm2cpp [file join $llvmtoolsdir llvm2cpp ]
+ set llvmas [file join $llvmtoolsdir llvm-as ]
+ set llvmdis [file join $llvmtoolsdir llvm-dis ]
+ set llvmupgrade [ file join $llvmtoolsdir llvm-upgrade ]
+
+ #Make Output Directory if it does not exist already
+ if { [file exists path] } {
+ cd $path
+ } else {
+ file mkdir $path
+ cd $path
+ }
+
+ file mkdir Output
+
+ foreach test $files {
+
+ set filename [file tail $test]
+ set generated [file join Output $filename.cpp]
+ set executable [file join Output $filename.exe]
+ set output [file join Output $filename.gen]
+ set assembly [file join Output $filename.asm]
+ set testname [file rootname $filename]
+ set bytecode [file join Output $filename.bc]
+
+ # Note that the stderr for llvm-as, etc. must be redirected to /dev/null
+ # because otherwise exec will see the msgs and return 1 even though they
+ # are only warnings. If real errors are generated on stderr then llvm-as
+ # will return a non-zero retval anyway so we're good.
+
+ # Scan the test file to see if there's an XFAIL file. If so, don't run it
+ set retval [ catch {
+ exec -keepnewline grep XFAIL $test 2>/dev/null } msg ]
+ if { $retval == 0 } {
+ continue;
+ }
+
+ # Scan the test file to see if there's a line with "lvm-upgrade" in it.
+ # If so, run llvm-upgrade first or else llvm-as will fail on it.
+ set retval [ catch {
+ exec -keepnewline grep llvm-upgrade $test 2>/dev/null } msg ]
+
+ if { $retval == 0 } {
+ # In this case we must run llvm-upgrade before llvm-as
+ set pipeline llvm-upgrade|llvm-as|llvm-dis
+ set retval [ catch {
+ exec -keepnewline $llvmupgrade < $test -o - | $llvmas | $llvmdis -f -o $assembly 2>/dev/null } msg ]
+ } else {
+ # llvm-upgrade not necessary, just llvm-as/llvm-dis
+ set pipeline llvm-as|llvm-dis
+ set retval [ catch {
+ exec -keepnewline $llvmas < $test -o - | $llvmdis -f -o $assembly 2>/dev/null } msg ]
+ }
+
+ if { $retval != 0 } {
+ fail "$test: $pipeline returned $retval\n$msg"
+ continue
+ }
+
+ # Build bytecode for llvm2cpp input
+ set retval [ catch {
+ exec -keepnewline $llvmas < $assembly > $bytecode 2>/dev/null } msg ]
+
+ if { $retval != 0 } {
+ fail "$test: llvm-as returned $retval\n$msg"
+ continue
+ }
+
+ set retval [ catch {
+ exec -keepnewline $llvm2cpp -f -o $generated < $bytecode 2>/dev/null } msg]
+
+ if { $retval != 0 } {
+ fail "$test: llvm2cpp returned $retval\n$msg"
+ continue
+ }
+
+ set retval [ catch {
+ exec -keepnewline gcc -g -D__STDC_LIMIT_MACROS -o $executable $generated -I$srcroot/include -I$objroot/include -L$llvmlibsdir -lLLVMCore -lLLVMSupport -lLLVMbzip2 -lLLVMSystem -lstdc++ } msg ]
+ if { $retval != 0 } {
+ fail "$test: gcc returned $retval\n$msg"
+ continue
+ }
+
+ set retval [ catch { exec -keepnewline $executable > $output } msg ]
+ if { $retval != 0 } {
+ set execname [file tail $executable]
+ fail "$test: $execname returned $retval:\n$msg"
+ continue
+ }
+
+ set retval [ catch {
+ exec -keepnewline diff $assembly $output } msg ]
+
+ if { $retval != 0 } {
+ fail "$test: diff returned $retval:\n$msg"
+ continue
+ }
+ pass "$test"
+ }
+}
+
+