| /* |
| * __put_user functions. |
| * |
| * (C) Copyright 2005 Linus Torvalds |
| * |
| * These functions have a non-standard call interface |
| * to make them more efficient, especially as they |
| * return an error value in addition to the "real" |
| * return value. |
| */ |
| #include <linux/linkage.h> |
| #include <asm/dwarf2.h> |
| #include <asm/thread_info.h> |
| |
| |
| /* |
| * __put_user_X |
| * |
| * Inputs: %eax[:%edx] contains the data |
| * %ecx contains the address |
| * |
| * Outputs: %eax is error code (0 or -EFAULT) |
| * |
| * These functions should not modify any other registers, |
| * as they get called from within inline assembly. |
| */ |
| |
| #define ENTER CFI_STARTPROC ; \ |
| GET_THREAD_INFO(%ebx) |
| #define EXIT ret ; \ |
| CFI_ENDPROC |
| |
| .text |
| ENTRY(__put_user_1) |
| ENTER |
| cmp TI_addr_limit(%ebx),%ecx |
| jae bad_put_user |
| 1: movb %al,(%ecx) |
| xor %eax,%eax |
| EXIT |
| ENDPROC(__put_user_1) |
| |
| ENTRY(__put_user_2) |
| ENTER |
| mov TI_addr_limit(%ebx),%ebx |
| sub $1,%ebx |
| cmp %ebx,%ecx |
| jae bad_put_user |
| 2: movw %ax,(%ecx) |
| xor %eax,%eax |
| EXIT |
| ENDPROC(__put_user_2) |
| |
| ENTRY(__put_user_4) |
| ENTER |
| mov TI_addr_limit(%ebx),%ebx |
| sub $3,%ebx |
| cmp %ebx,%ecx |
| jae bad_put_user |
| 3: movl %eax,(%ecx) |
| xor %eax,%eax |
| EXIT |
| ENDPROC(__put_user_4) |
| |
| ENTRY(__put_user_8) |
| ENTER |
| mov TI_addr_limit(%ebx),%ebx |
| sub $7,%ebx |
| cmp %ebx,%ecx |
| jae bad_put_user |
| 4: movl %eax,(%ecx) |
| 5: movl %edx,4(%ecx) |
| xor %eax,%eax |
| EXIT |
| ENDPROC(__put_user_8) |
| |
| bad_put_user: |
| CFI_STARTPROC |
| movl $-14,%eax |
| EXIT |
| END(bad_put_user) |
| |
| .section __ex_table,"a" |
| .long 1b,bad_put_user |
| .long 2b,bad_put_user |
| .long 3b,bad_put_user |
| .long 4b,bad_put_user |
| .long 5b,bad_put_user |
| .previous |