| Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 1 | /* |
| 2 | * Divide a 64-bit unsigned number by a 32-bit unsigned number. |
| 3 | * This routine assumes that the top 32 bits of the dividend are |
| 4 | * non-zero to start with. |
| 5 | * On entry, r3 points to the dividend, which get overwritten with |
| 6 | * the 64-bit quotient, and r4 contains the divisor. |
| 7 | * On exit, r3 contains the remainder. |
| 8 | * |
| 9 | * Copyright (C) 2002 Paul Mackerras, IBM Corp. |
| 10 | * |
| 11 | * This program is free software; you can redistribute it and/or |
| 12 | * modify it under the terms of the GNU General Public License |
| 13 | * as published by the Free Software Foundation; either version |
| 14 | * 2 of the License, or (at your option) any later version. |
| 15 | */ |
| 16 | #include <asm/ppc_asm.h> |
| 17 | #include <asm/processor.h> |
| 18 | |
| 19 | _GLOBAL(__div64_32) |
| 20 | lwz r5,0(r3) # get the dividend into r5/r6 |
| 21 | lwz r6,4(r3) |
| 22 | cmplw r5,r4 |
| 23 | li r7,0 |
| 24 | li r8,0 |
| 25 | blt 1f |
| 26 | divwu r7,r5,r4 # if dividend.hi >= divisor, |
| 27 | mullw r0,r7,r4 # quotient.hi = dividend.hi / divisor |
| 28 | subf. r5,r0,r5 # dividend.hi %= divisor |
| 29 | beq 3f |
| 30 | 1: mr r11,r5 # here dividend.hi != 0 |
| 31 | andis. r0,r5,0xc000 |
| 32 | bne 2f |
| 33 | cntlzw r0,r5 # we are shifting the dividend right |
| 34 | li r10,-1 # to make it < 2^32, and shifting |
| 35 | srw r10,r10,r0 # the divisor right the same amount, |
| 36 | add r9,r4,r10 # rounding up (so the estimate cannot |
| 37 | andc r11,r6,r10 # ever be too large, only too small) |
| 38 | andc r9,r9,r10 |
| 39 | or r11,r5,r11 |
| 40 | rotlw r9,r9,r0 |
| 41 | rotlw r11,r11,r0 |
| 42 | divwu r11,r11,r9 # then we divide the shifted quantities |
| 43 | 2: mullw r10,r11,r4 # to get an estimate of the quotient, |
| 44 | mulhwu r9,r11,r4 # multiply the estimate by the divisor, |
| 45 | subfc r6,r10,r6 # take the product from the divisor, |
| 46 | add r8,r8,r11 # and add the estimate to the accumulated |
| 47 | subfe. r5,r9,r5 # quotient |
| 48 | bne 1b |
| 49 | 3: cmplw r6,r4 |
| 50 | blt 4f |
| 51 | divwu r0,r6,r4 # perform the remaining 32-bit division |
| 52 | mullw r10,r0,r4 # and get the remainder |
| 53 | add r8,r8,r0 |
| 54 | subf r6,r10,r6 |
| 55 | 4: stw r7,0(r3) # return the quotient in *r3 |
| 56 | stw r8,4(r3) |
| 57 | mr r3,r6 # return the remainder in r3 |
| 58 | blr |