Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 1 | /* |
| 2 | * ld script to make ARM Linux kernel |
| 3 | * taken from the i386 version by Russell King |
| 4 | * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz> |
| 5 | */ |
| 6 | |
| 7 | #include <asm-generic/vmlinux.lds.h> |
Ard Biesheuvel | 98fb754 | 2015-12-01 13:20:40 +0100 | [diff] [blame] | 8 | #include <asm/cache.h> |
Suzuki K. Poulose | 87d1587 | 2015-10-19 14:19:27 +0100 | [diff] [blame] | 9 | #include <asm/kernel-pgtable.h> |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 10 | #include <asm/thread_info.h> |
| 11 | #include <asm/memory.h> |
| 12 | #include <asm/page.h> |
Laura Abbott | da14170 | 2015-01-21 17:36:06 -0800 | [diff] [blame] | 13 | #include <asm/pgtable.h> |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 14 | |
Mark Rutland | a2c1d73 | 2014-06-24 16:51:36 +0100 | [diff] [blame] | 15 | #include "image.h" |
| 16 | |
Will Deacon | 07c802b | 2014-11-25 15:26:13 +0000 | [diff] [blame] | 17 | /* .exit.text needed in case of alternative patching */ |
| 18 | #define ARM_EXIT_KEEP(x) x |
| 19 | #define ARM_EXIT_DISCARD(x) |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 20 | |
| 21 | OUTPUT_ARCH(aarch64) |
Geoff Levand | af885f4 | 2014-05-16 18:26:01 +0100 | [diff] [blame] | 22 | ENTRY(_text) |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 23 | |
| 24 | jiffies = jiffies_64; |
| 25 | |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 26 | #define HYPERVISOR_TEXT \ |
| 27 | /* \ |
Ard Biesheuvel | 06f75a1 | 2015-03-19 16:42:26 +0000 | [diff] [blame] | 28 | * Align to 4 KB so that \ |
| 29 | * a) the HYP vector table is at its minimum \ |
| 30 | * alignment of 2048 bytes \ |
| 31 | * b) the HYP init code will not cross a page \ |
| 32 | * boundary if its size does not exceed \ |
| 33 | * 4 KB (see related ASSERT() below) \ |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 34 | */ \ |
Ard Biesheuvel | 06f75a1 | 2015-03-19 16:42:26 +0000 | [diff] [blame] | 35 | . = ALIGN(SZ_4K); \ |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 36 | VMLINUX_SYMBOL(__hyp_idmap_text_start) = .; \ |
| 37 | *(.hyp.idmap.text) \ |
| 38 | VMLINUX_SYMBOL(__hyp_idmap_text_end) = .; \ |
| 39 | VMLINUX_SYMBOL(__hyp_text_start) = .; \ |
| 40 | *(.hyp.text) \ |
| 41 | VMLINUX_SYMBOL(__hyp_text_end) = .; |
| 42 | |
Ard Biesheuvel | 5dfe9d7 | 2015-06-01 13:40:33 +0200 | [diff] [blame] | 43 | #define IDMAP_TEXT \ |
| 44 | . = ALIGN(SZ_4K); \ |
| 45 | VMLINUX_SYMBOL(__idmap_text_start) = .; \ |
| 46 | *(.idmap.text) \ |
| 47 | VMLINUX_SYMBOL(__idmap_text_end) = .; |
| 48 | |
James Morse | 82869ac | 2016-04-27 17:47:12 +0100 | [diff] [blame] | 49 | #ifdef CONFIG_HIBERNATION |
| 50 | #define HIBERNATE_TEXT \ |
| 51 | . = ALIGN(SZ_4K); \ |
| 52 | VMLINUX_SYMBOL(__hibernate_exit_text_start) = .;\ |
| 53 | *(.hibernate_exit.text) \ |
| 54 | VMLINUX_SYMBOL(__hibernate_exit_text_end) = .; |
| 55 | #else |
| 56 | #define HIBERNATE_TEXT |
| 57 | #endif |
| 58 | |
Will Deacon | a329b06 | 2017-11-14 14:07:40 +0000 | [diff] [blame] | 59 | #ifdef CONFIG_UNMAP_KERNEL_AT_EL0 |
| 60 | #define TRAMP_TEXT \ |
| 61 | . = ALIGN(PAGE_SIZE); \ |
| 62 | VMLINUX_SYMBOL(__entry_tramp_text_start) = .; \ |
Sami Tolvanen | 0d6fbe4 | 2018-02-13 14:00:14 -0800 | [diff] [blame] | 63 | KEEP(*(.entry.tramp.text)) \ |
Will Deacon | a329b06 | 2017-11-14 14:07:40 +0000 | [diff] [blame] | 64 | . = ALIGN(PAGE_SIZE); \ |
| 65 | VMLINUX_SYMBOL(__entry_tramp_text_end) = .; |
| 66 | #else |
| 67 | #define TRAMP_TEXT |
| 68 | #endif |
| 69 | |
Ard Biesheuvel | a352ea3 | 2014-10-10 18:42:55 +0200 | [diff] [blame] | 70 | /* |
| 71 | * The size of the PE/COFF section that covers the kernel image, which |
| 72 | * runs from stext to _edata, must be a round multiple of the PE/COFF |
| 73 | * FileAlignment, which we set to its minimum value of 0x200. 'stext' |
| 74 | * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned |
| 75 | * boundary should be sufficient. |
| 76 | */ |
| 77 | PECOFF_FILE_ALIGNMENT = 0x200; |
| 78 | |
| 79 | #ifdef CONFIG_EFI |
| 80 | #define PECOFF_EDATA_PADDING \ |
| 81 | .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); } |
| 82 | #else |
| 83 | #define PECOFF_EDATA_PADDING |
| 84 | #endif |
| 85 | |
Mark Rutland | cb08381 | 2015-10-26 21:42:33 +0000 | [diff] [blame] | 86 | #if defined(CONFIG_DEBUG_ALIGN_RODATA) |
Ard Biesheuvel | 9774005 | 2016-03-30 17:43:09 +0200 | [diff] [blame] | 87 | /* |
| 88 | * 4 KB granule: 1 level 2 entry |
| 89 | * 16 KB granule: 128 level 3 entries, with contiguous bit |
| 90 | * 64 KB granule: 32 level 3 entries, with contiguous bit |
| 91 | */ |
| 92 | #define SEGMENT_ALIGN SZ_2M |
Laura Abbott | da14170 | 2015-01-21 17:36:06 -0800 | [diff] [blame] | 93 | #else |
Ard Biesheuvel | 9774005 | 2016-03-30 17:43:09 +0200 | [diff] [blame] | 94 | /* |
| 95 | * 4 KB granule: 16 level 3 entries, with contiguous bit |
| 96 | * 16 KB granule: 4 level 3 entries, without contiguous bit |
| 97 | * 64 KB granule: 1 level 3 entry |
| 98 | */ |
| 99 | #define SEGMENT_ALIGN SZ_64K |
Laura Abbott | da14170 | 2015-01-21 17:36:06 -0800 | [diff] [blame] | 100 | #endif |
| 101 | |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 102 | SECTIONS |
| 103 | { |
| 104 | /* |
| 105 | * XXX: The linker does not define how output sections are |
| 106 | * assigned to input sections when there are multiple statements |
| 107 | * matching the same input section name. There is no documented |
| 108 | * order of matching. |
| 109 | */ |
| 110 | /DISCARD/ : { |
| 111 | ARM_EXIT_DISCARD(EXIT_TEXT) |
| 112 | ARM_EXIT_DISCARD(EXIT_DATA) |
| 113 | EXIT_CALL |
| 114 | *(.discard) |
| 115 | *(.discard.*) |
Ard Biesheuvel | 1e48ef7 | 2016-01-26 09:13:44 +0100 | [diff] [blame] | 116 | *(.interp .dynamic) |
Ard Biesheuvel | 08cc55b | 2016-07-24 14:00:13 +0200 | [diff] [blame] | 117 | *(.dynsym .dynstr .hash) |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 118 | } |
| 119 | |
Ard Biesheuvel | ab893fb | 2016-02-16 13:52:36 +0100 | [diff] [blame] | 120 | . = KIMAGE_VADDR + TEXT_OFFSET; |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 121 | |
| 122 | .head.text : { |
| 123 | _text = .; |
| 124 | HEAD_TEXT |
| 125 | } |
| 126 | .text : { /* Real text segment */ |
| 127 | _stext = .; /* Text and read-only data */ |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 128 | __exception_text_start = .; |
| 129 | *(.exception.text) |
| 130 | __exception_text_end = .; |
| 131 | IRQENTRY_TEXT |
Alexander Potapenko | be7635e | 2016-03-25 14:22:05 -0700 | [diff] [blame] | 132 | SOFTIRQENTRY_TEXT |
Pratyush Anand | 888b3c8 | 2016-07-08 12:35:50 -0400 | [diff] [blame] | 133 | ENTRY_TEXT |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 134 | TEXT_TEXT |
| 135 | SCHED_TEXT |
Chris Metcalf | 6727ad9 | 2016-10-07 17:02:55 -0700 | [diff] [blame] | 136 | CPUIDLE_TEXT |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 137 | LOCK_TEXT |
Sandeepa Prabhu | 2dd0e8d | 2016-07-08 12:35:48 -0400 | [diff] [blame] | 138 | KPROBES_TEXT |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 139 | HYPERVISOR_TEXT |
Ard Biesheuvel | 5dfe9d7 | 2015-06-01 13:40:33 +0200 | [diff] [blame] | 140 | IDMAP_TEXT |
James Morse | 82869ac | 2016-04-27 17:47:12 +0100 | [diff] [blame] | 141 | HIBERNATE_TEXT |
Will Deacon | a329b06 | 2017-11-14 14:07:40 +0000 | [diff] [blame] | 142 | TRAMP_TEXT |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 143 | *(.fixup) |
| 144 | *(.gnu.warning) |
| 145 | . = ALIGN(16); |
| 146 | *(.got) /* Global offset table */ |
| 147 | } |
| 148 | |
Ard Biesheuvel | 9774005 | 2016-03-30 17:43:09 +0200 | [diff] [blame] | 149 | . = ALIGN(SEGMENT_ALIGN); |
Ard Biesheuvel | 9fdc14c5 | 2016-06-23 15:53:17 +0200 | [diff] [blame] | 150 | _etext = .; /* End of text section */ |
| 151 | |
| 152 | RO_DATA(PAGE_SIZE) /* everything from this point to */ |
| 153 | EXCEPTION_TABLE(8) /* __init_begin will be marked RO NX */ |
Mark Salter | c80b7ee | 2013-08-23 16:16:42 +0100 | [diff] [blame] | 154 | NOTES |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 155 | |
Ard Biesheuvel | 9774005 | 2016-03-30 17:43:09 +0200 | [diff] [blame] | 156 | . = ALIGN(SEGMENT_ALIGN); |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 157 | __init_begin = .; |
| 158 | |
| 159 | INIT_TEXT_SECTION(8) |
| 160 | .exit.text : { |
| 161 | ARM_EXIT_KEEP(EXIT_TEXT) |
| 162 | } |
Laura Abbott | da14170 | 2015-01-21 17:36:06 -0800 | [diff] [blame] | 163 | |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 164 | .init.data : { |
| 165 | INIT_DATA |
| 166 | INIT_SETUP(16) |
| 167 | INIT_CALLS |
| 168 | CON_INITCALL |
| 169 | SECURITY_INITCALL |
| 170 | INIT_RAM_FS |
Ard Biesheuvel | 1ce99bf | 2016-02-17 12:35:58 +0000 | [diff] [blame] | 171 | *(.init.rodata.* .init.bss) /* from the EFI stub */ |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 172 | } |
| 173 | .exit.data : { |
| 174 | ARM_EXIT_KEEP(EXIT_DATA) |
| 175 | } |
| 176 | |
Ard Biesheuvel | 98fb754 | 2015-12-01 13:20:40 +0100 | [diff] [blame] | 177 | PERCPU_SECTION(L1_CACHE_BYTES) |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 178 | |
Andre Przywara | e039ee4 | 2014-11-14 15:54:08 +0000 | [diff] [blame] | 179 | . = ALIGN(4); |
| 180 | .altinstructions : { |
| 181 | __alt_instructions = .; |
Sami Tolvanen | e611641 | 2017-10-10 10:56:17 -0700 | [diff] [blame] | 182 | KEEP(*(.altinstructions)) |
Andre Przywara | e039ee4 | 2014-11-14 15:54:08 +0000 | [diff] [blame] | 183 | __alt_instructions_end = .; |
| 184 | } |
| 185 | .altinstr_replacement : { |
Sami Tolvanen | e611641 | 2017-10-10 10:56:17 -0700 | [diff] [blame] | 186 | KEEP(*(.altinstr_replacement)) |
Andre Przywara | e039ee4 | 2014-11-14 15:54:08 +0000 | [diff] [blame] | 187 | } |
Ard Biesheuvel | 1e48ef7 | 2016-01-26 09:13:44 +0100 | [diff] [blame] | 188 | .rela : ALIGN(8) { |
Ard Biesheuvel | 1e48ef7 | 2016-01-26 09:13:44 +0100 | [diff] [blame] | 189 | *(.rela .rela*) |
Ard Biesheuvel | 1e48ef7 | 2016-01-26 09:13:44 +0100 | [diff] [blame] | 190 | } |
Andre Przywara | e039ee4 | 2014-11-14 15:54:08 +0000 | [diff] [blame] | 191 | |
Ard Biesheuvel | d6732fc | 2016-07-28 16:15:14 +0200 | [diff] [blame] | 192 | __rela_offset = ABSOLUTE(ADDR(.rela) - KIMAGE_VADDR); |
Ard Biesheuvel | 0cd3def | 2016-04-18 17:09:43 +0200 | [diff] [blame] | 193 | __rela_size = SIZEOF(.rela); |
Ard Biesheuvel | 0cd3def | 2016-04-18 17:09:43 +0200 | [diff] [blame] | 194 | |
Ard Biesheuvel | 9774005 | 2016-03-30 17:43:09 +0200 | [diff] [blame] | 195 | . = ALIGN(SEGMENT_ALIGN); |
Mark Rutland | 9aa4ec1 | 2015-12-09 12:44:38 +0000 | [diff] [blame] | 196 | __init_end = .; |
| 197 | |
Mark Salter | 3c62062 | 2013-11-04 16:38:47 +0000 | [diff] [blame] | 198 | _data = .; |
Mark Salter | 3c62062 | 2013-11-04 16:38:47 +0000 | [diff] [blame] | 199 | _sdata = .; |
Ard Biesheuvel | 98fb754 | 2015-12-01 13:20:40 +0100 | [diff] [blame] | 200 | RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE) |
James Morse | b611303 | 2016-08-24 18:27:29 +0100 | [diff] [blame] | 201 | |
| 202 | /* |
| 203 | * Data written with the MMU off but read with the MMU on requires |
| 204 | * cache lines to be invalidated, discarding up to a Cache Writeback |
| 205 | * Granule (CWG) of data from the cache. Keep the section that |
| 206 | * requires this type of maintenance to be in its own Cache Writeback |
| 207 | * Granule (CWG) area so the cache maintenance operations don't |
| 208 | * interfere with adjacent data. |
| 209 | */ |
| 210 | .mmuoff.data.write : ALIGN(SZ_2K) { |
| 211 | __mmuoff_data_start = .; |
| 212 | *(.mmuoff.data.write) |
| 213 | } |
| 214 | . = ALIGN(SZ_2K); |
| 215 | .mmuoff.data.read : { |
| 216 | *(.mmuoff.data.read) |
| 217 | __mmuoff_data_end = .; |
| 218 | } |
| 219 | |
Ard Biesheuvel | a352ea3 | 2014-10-10 18:42:55 +0200 | [diff] [blame] | 220 | PECOFF_EDATA_PADDING |
Mark Salter | 3c62062 | 2013-11-04 16:38:47 +0000 | [diff] [blame] | 221 | _edata = .; |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 222 | |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 223 | BSS_SECTION(0, 0, 0) |
Mark Rutland | bd00cd5 | 2014-06-24 16:51:35 +0100 | [diff] [blame] | 224 | |
| 225 | . = ALIGN(PAGE_SIZE); |
| 226 | idmap_pg_dir = .; |
| 227 | . += IDMAP_DIR_SIZE; |
| 228 | swapper_pg_dir = .; |
| 229 | . += SWAPPER_DIR_SIZE; |
| 230 | |
Catalin Marinas | 005bf1a | 2016-07-01 16:53:00 +0100 | [diff] [blame] | 231 | #ifdef CONFIG_ARM64_SW_TTBR0_PAN |
| 232 | reserved_ttbr0 = .; |
| 233 | . += RESERVED_TTBR0_SIZE; |
| 234 | #endif |
| 235 | |
Will Deacon | a329b06 | 2017-11-14 14:07:40 +0000 | [diff] [blame] | 236 | #ifdef CONFIG_UNMAP_KERNEL_AT_EL0 |
| 237 | tramp_pg_dir = .; |
| 238 | . += PAGE_SIZE; |
| 239 | #endif |
| 240 | |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 241 | _end = .; |
| 242 | |
| 243 | STABS_DEBUG |
Mark Rutland | a2c1d73 | 2014-06-24 16:51:36 +0100 | [diff] [blame] | 244 | |
| 245 | HEAD_SYMBOLS |
Catalin Marinas | 8c2c3df | 2012-04-20 14:45:54 +0100 | [diff] [blame] | 246 | } |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 247 | |
| 248 | /* |
Ard Biesheuvel | 5dfe9d7 | 2015-06-01 13:40:33 +0200 | [diff] [blame] | 249 | * The HYP init code and ID map text can't be longer than a page each, |
Ard Biesheuvel | 06f75a1 | 2015-03-19 16:42:26 +0000 | [diff] [blame] | 250 | * and should not cross a page boundary. |
Marc Zyngier | 2240bbb | 2012-12-07 18:40:43 +0000 | [diff] [blame] | 251 | */ |
Ard Biesheuvel | 06f75a1 | 2015-03-19 16:42:26 +0000 | [diff] [blame] | 252 | ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K, |
| 253 | "HYP init code too big or misaligned") |
Ard Biesheuvel | 5dfe9d7 | 2015-06-01 13:40:33 +0200 | [diff] [blame] | 254 | ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K, |
| 255 | "ID map text too big or misaligned") |
James Morse | 82869ac | 2016-04-27 17:47:12 +0100 | [diff] [blame] | 256 | #ifdef CONFIG_HIBERNATION |
| 257 | ASSERT(__hibernate_exit_text_end - (__hibernate_exit_text_start & ~(SZ_4K - 1)) |
| 258 | <= SZ_4K, "Hibernate exit text too big or misaligned") |
| 259 | #endif |
Will Deacon | 06fe41f | 2017-12-06 11:24:02 +0000 | [diff] [blame] | 260 | #ifdef CONFIG_UNMAP_KERNEL_AT_EL0 |
| 261 | ASSERT((__entry_tramp_text_end - __entry_tramp_text_start) == PAGE_SIZE, |
| 262 | "Entry trampoline text too big") |
| 263 | #endif |
Mark Rutland | da57a36 | 2014-06-24 16:51:37 +0100 | [diff] [blame] | 264 | /* |
| 265 | * If padding is applied before .head.text, virt<->phys conversions will fail. |
| 266 | */ |
Ard Biesheuvel | ab893fb | 2016-02-16 13:52:36 +0100 | [diff] [blame] | 267 | ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned") |