Kun Zhang | 4bc2d6d | 2015-04-17 10:49:11 -0700 | [diff] [blame] | 1 | buildscript { |
| 2 | repositories { |
| 3 | mavenCentral() |
| 4 | mavenLocal() |
| 5 | } |
| 6 | dependencies { |
| 7 | classpath 'com.google.gradle:osdetector-gradle-plugin:1.2.1' |
| 8 | } |
| 9 | } |
Eric Anderson | b938ba5 | 2015-02-28 09:59:25 -0800 | [diff] [blame] | 10 | |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 11 | subprojects { |
Eric Anderson | c3e8dae | 2015-01-30 14:58:07 -0800 | [diff] [blame] | 12 | apply plugin: "checkstyle" |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 13 | apply plugin: "java" |
| 14 | apply plugin: "maven" |
nmittler | 52f4220 | 2015-01-21 14:30:14 -0800 | [diff] [blame] | 15 | apply plugin: "idea" |
Kun Zhang | 4bc2d6d | 2015-04-17 10:49:11 -0700 | [diff] [blame] | 16 | apply plugin: "osdetector" |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 17 | apply plugin: "signing" |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 18 | |
nmittler | f831458 | 2015-01-27 10:25:39 -0800 | [diff] [blame] | 19 | group = "io.grpc" |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 20 | version = "0.1.0-SNAPSHOT" |
| 21 | |
| 22 | sourceCompatibility = 1.6 |
| 23 | targetCompatibility = 1.6 |
| 24 | |
| 25 | repositories { |
| 26 | mavenCentral() |
| 27 | mavenLocal() |
| 28 | } |
| 29 | |
Eric Anderson | 76d0955 | 2015-03-12 15:25:11 -0700 | [diff] [blame] | 30 | [compileJava, compileTestJava].each() { |
| 31 | it.options.compilerArgs += ["-Xlint:unchecked", "-Xlint:deprecation", "-Xlint:-options"] |
| 32 | it.options.encoding = "UTF-8" |
nmittler | 02c953e | 2015-01-26 14:03:11 -0800 | [diff] [blame] | 33 | } |
| 34 | |
Eric Anderson | 14444a9 | 2015-03-11 16:44:38 -0700 | [diff] [blame] | 35 | javadoc.options.encoding = "UTF-8" |
| 36 | |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 37 | ext { |
| 38 | libraries = [ |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 39 | guava: 'com.google.guava:guava:18.0', |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 40 | // used to collect benchmark results |
| 41 | hdrhistogram: 'org.hdrhistogram:HdrHistogram:2.1.4', |
Jeff Pinner | b1cc7cc | 2015-02-25 10:17:23 -0800 | [diff] [blame] | 42 | hpack: 'com.twitter:hpack:0.10.1', |
nmittler | b897a89 | 2015-02-23 12:03:59 -0800 | [diff] [blame] | 43 | javaee_api: 'javax:javaee-api:7.0', |
| 44 | jsonp: 'org.glassfish:javax.json:1.0.4', |
| 45 | jsr305: 'com.google.code.findbugs:jsr305:3.0.0', |
Louis Ryan | 767a12c | 2015-03-02 15:05:09 -0800 | [diff] [blame] | 46 | oauth_client: 'com.google.auth:google-auth-library-oauth2-http:0.1.0', |
nmittler | b897a89 | 2015-02-23 12:03:59 -0800 | [diff] [blame] | 47 | okhttp: 'com.squareup.okhttp:okhttp:2.2.0', |
Eric Anderson | a6f5fff | 2015-02-26 07:53:17 -0800 | [diff] [blame] | 48 | protobuf: 'com.google.protobuf:protobuf-java:3.0.0-alpha-2', |
| 49 | protobuf_nano: 'com.google.protobuf.nano:protobuf-javanano:3.0.0-alpha-2', |
Kun Zhang | 41940f7 | 2015-04-28 18:14:34 -0700 | [diff] [blame] | 50 | protobuf_plugin: 'com.google.protobuf:protobuf-gradle-plugin:0.3.1', |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 51 | |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 52 | // TODO: Unreleased dependencies. |
| 53 | // These must already be installed in the local maven repository. |
nmittler | 2a42509 | 2015-03-11 12:15:30 -0700 | [diff] [blame] | 54 | netty: 'io.netty:netty-codec-http2:4.1.0.Beta5-SNAPSHOT', |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 55 | |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 56 | // Test dependencies. |
| 57 | junit: 'junit:junit:4.11', |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 58 | mockito: 'org.mockito:mockito-core:1.10.19' |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 59 | ] |
| 60 | |
| 61 | // Determine the correct version of Jetty ALPN boot to use based |
| 62 | // on the Java version. |
| 63 | def alpnboot_version = '8.1.2.v20141202' |
| 64 | if (JavaVersion.current().ordinal() < JavaVersion.VERSION_1_8.ordinal()) { |
| 65 | alpnboot_version = '7.1.2.v20141202' |
| 66 | } |
| 67 | |
| 68 | alpnboot_package_name = 'org.mortbay.jetty.alpn:alpn-boot:' + alpnboot_version |
Eric Anderson | b938ba5 | 2015-02-28 09:59:25 -0800 | [diff] [blame] | 69 | |
Kun Zhang | 4bc2d6d | 2015-04-17 10:49:11 -0700 | [diff] [blame] | 70 | def exeSuffix = osdetector.os == 'windows' ? ".exe" : "" |
Kun Zhang | 90706dc | 2015-04-09 13:11:31 -0700 | [diff] [blame] | 71 | protocPluginBaseName = 'protoc-gen-grpc-java' |
Kun Zhang | 221c534 | 2015-04-29 18:16:15 -0700 | [diff] [blame] | 72 | javaPluginPath = "$rootDir/compiler/build/binaries/java_pluginExecutable/$protocPluginBaseName$exeSuffix" |
Jakob Buchgraber | 7ddcdfd | 2015-02-13 16:21:53 -0800 | [diff] [blame] | 73 | } |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 74 | |
| 75 | dependencies { |
| 76 | testCompile libraries.junit, |
| 77 | libraries.mockito |
| 78 | } |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 79 | |
| 80 | signing { |
| 81 | required false |
| 82 | sign configurations.archives |
| 83 | } |
| 84 | |
nmittler | 732cfc0 | 2015-03-03 07:59:13 -0800 | [diff] [blame] | 85 | // Disable JavaDoc doclint on Java 8. It's annoying. |
| 86 | if (JavaVersion.current().isJava8Compatible()) { |
| 87 | allprojects { |
| 88 | tasks.withType(Javadoc) { |
| 89 | options.addStringOption('Xdoclint:none', '-quiet') |
| 90 | } |
| 91 | } |
| 92 | } |
| 93 | |
Eric Anderson | c3e8dae | 2015-01-30 14:58:07 -0800 | [diff] [blame] | 94 | checkstyle { |
| 95 | configFile = file("$rootDir/checkstyle.xml") |
Xudong Ma | 9aae6f6 | 2015-04-06 21:04:56 +0800 | [diff] [blame] | 96 | toolVersion = "6.5" |
Eric Anderson | 26141b4 | 2015-03-21 10:59:17 -0700 | [diff] [blame] | 97 | ignoreFailures = true |
| 98 | if (rootProject.hasProperty("checkstyle.ignoreFailures")) { |
| 99 | ignoreFailures = rootProject.properties["checkstyle.ignoreFailures"].toBoolean() |
| 100 | } |
Eric Anderson | c3e8dae | 2015-01-30 14:58:07 -0800 | [diff] [blame] | 101 | } |
| 102 | |
| 103 | checkstyleMain { |
| 104 | source = fileTree(dir: "src", include: "**/*.java", |
| 105 | excludes: ["${buildDir}/generated-sources", "**/TestServiceGrpc.java"]) |
| 106 | } |
| 107 | |
| 108 | checkstyleTest { |
| 109 | source = fileTree(dir: "test", include: "**/*.java", |
| 110 | exclude: "${buildDir}/generated-sources") |
| 111 | } |
| 112 | |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 113 | task javadocJar(type: Jar) { |
| 114 | classifier = 'javadoc' |
| 115 | from javadoc |
| 116 | } |
| 117 | |
| 118 | task sourcesJar(type: Jar) { |
| 119 | classifier = 'sources' |
| 120 | from sourceSets.main.allSource |
| 121 | } |
| 122 | |
| 123 | artifacts { |
| 124 | archives javadocJar, sourcesJar |
| 125 | } |
| 126 | |
| 127 | uploadArchives.repositories.mavenDeployer { |
| 128 | beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) } |
zhangkun83 | da3c3f8 | 2015-03-11 18:03:31 -0700 | [diff] [blame] | 129 | String stagingUrl |
| 130 | if (System.getProperty('repositoryId')) { |
| 131 | stagingUrl = 'https://oss.sonatype.org/service/local/staging/deployByRepositoryId/' + System.getProperty('repositoryId') |
| 132 | } else { |
| 133 | stagingUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/' |
| 134 | } |
| 135 | repository(url: stagingUrl) { |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 136 | if (rootProject.hasProperty("ossrhUsername") |
| 137 | && rootProject.hasProperty("ossrhPassword")) { |
| 138 | authentication(userName: ossrhUsername, password: ossrhPassword) |
| 139 | } |
| 140 | } |
| 141 | |
| 142 | snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") { |
| 143 | if (rootProject.hasProperty("ossrhUsername") |
| 144 | && rootProject.hasProperty("ossrhPassword")) { |
| 145 | authentication(userName: ossrhUsername, password: ossrhPassword) |
| 146 | } |
| 147 | } |
| 148 | } |
| 149 | |
| 150 | [ |
| 151 | install.repositories.mavenInstaller, |
| 152 | uploadArchives.repositories.mavenDeployer, |
| 153 | ]*.pom*.whenConfigured { pom -> |
| 154 | pom.project { |
Eric Anderson | 7e8a02c | 2015-03-12 17:03:01 -0700 | [diff] [blame] | 155 | name "$project.group:$project.name" |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 156 | description project.description |
| 157 | url 'https://github.com/grpc/grpc-java' |
| 158 | |
| 159 | scm { |
| 160 | connection 'scm:svn:https://github.com/grpc/grpc-java.git' |
| 161 | developerConnection 'scm:svn:git@github.com:grpc/grpc-java.git' |
| 162 | url 'https://github.com/grpc/grpc-java' |
| 163 | } |
| 164 | |
| 165 | licenses { |
| 166 | license { |
| 167 | name 'BSD 3-Clause' |
| 168 | url 'http://opensource.org/licenses/BSD-3-Clause' |
| 169 | } |
| 170 | } |
Eric Anderson | 7e8a02c | 2015-03-12 17:03:01 -0700 | [diff] [blame] | 171 | |
| 172 | developers { |
| 173 | developer { |
| 174 | id "grpc.io" |
| 175 | name "gRPC Contributors" |
| 176 | email "grpc-io@googlegroups.com" |
| 177 | url "http://grpc.io/" |
| 178 | // https://issues.gradle.org/browse/GRADLE-2719 |
| 179 | organization = "Google, Inc." |
| 180 | organizationUrl "https://www.google.com" |
| 181 | } |
| 182 | } |
Eric Anderson | 192144e | 2015-03-02 13:31:14 -0800 | [diff] [blame] | 183 | } |
| 184 | } |
Kun Zhang | 3ddd1d5 | 2015-04-22 10:02:19 -0700 | [diff] [blame] | 185 | // At a test failure, log the stack trace to the console so that we don't |
| 186 | // have to open the HTML in a browser. |
| 187 | test { |
| 188 | testLogging { |
| 189 | exceptionFormat = 'full' |
| 190 | } |
| 191 | } |
nathanmittler | 164b734 | 2014-12-15 09:58:05 -0800 | [diff] [blame] | 192 | } |