| include(AddLLVM) # for add_lit_testsuite |
| |
| macro(pythonize_bool var) |
| if (${var}) |
| set(${var} True) |
| else() |
| set(${var} False) |
| endif() |
| endmacro() |
| |
| set(LIBCXX_LIT_VARIANT "libcxx" CACHE STRING |
| "Configuration variant to use for LIT.") |
| |
| # The tests shouldn't link to any ABI library when it has been linked into |
| # libc++ statically or via a linker script. |
| if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY OR LIBCXX_ENABLE_ABI_LINKER_SCRIPT) |
| set(LIBCXX_CXX_ABI_LIBNAME "none") |
| endif() |
| |
| # The tests shouldn't link to libunwind if we have a linker script which |
| # already does so. |
| if (LIBCXX_ENABLE_ABI_LINKER_SCRIPT) |
| set(LIBCXXABI_USE_LLVM_UNWINDER OFF) |
| endif() |
| |
| pythonize_bool(LIBCXX_ENABLE_EXCEPTIONS) |
| pythonize_bool(LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY) |
| pythonize_bool(LIBCXX_ENABLE_FILESYSTEM) |
| pythonize_bool(LIBCXX_ENABLE_RTTI) |
| pythonize_bool(LIBCXX_ENABLE_SHARED) |
| pythonize_bool(LIBCXX_BUILD_32_BITS) |
| pythonize_bool(LIBCXX_GENERATE_COVERAGE) |
| pythonize_bool(LIBCXXABI_ENABLE_SHARED) |
| pythonize_bool(LIBCXXABI_USE_LLVM_UNWINDER) |
| pythonize_bool(LIBCXX_HAS_ATOMIC_LIB) |
| pythonize_bool(LIBCXX_HAVE_CXX_ATOMICS_WITH_LIB) |
| pythonize_bool(LIBCXX_HAS_EXTERNAL_THREAD_API) |
| |
| # By default, for non-standalone builds, libcxx and libcxxabi share a library |
| # directory. |
| if (NOT LIBCXX_CXX_ABI_LIBRARY_PATH) |
| set(LIBCXX_CXX_ABI_LIBRARY_PATH "${LIBCXX_LIBRARY_DIR}" CACHE PATH |
| "The path to libc++abi library.") |
| endif() |
| |
| set(LIBCXX_TARGET_INFO "libcxx.test.target_info.LocalTI" CACHE STRING |
| "TargetInfo to use when setting up test environment.") |
| set(LIBCXX_EXECUTOR "None" CACHE STRING |
| "Executor to use when running tests.") |
| |
| set(AUTO_GEN_COMMENT "## Autogenerated by libcxx configuration.\n# Do not edit!") |
| |
| configure_file( |
| ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in |
| ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg |
| @ONLY) |
| |
| set(LIBCXX_TEST_DEPS "") |
| |
| if (LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY) |
| set(LIBCXX_TEST_DEPS cxx_experimental) |
| endif() |
| |
| if (LIBCXX_HAS_EXTERNAL_THREAD_API) |
| list(APPEND LIBCXX_TEST_DEPS cxx_external_threads) |
| endif() |
| |
| add_lit_testsuite(check-cxx |
| "Running libcxx tests" |
| ${CMAKE_CURRENT_BINARY_DIR} |
| DEPENDS cxx ${LIBCXX_TEST_DEPS}) |
| |
| add_custom_target(check-libcxx DEPENDS check-cxx) |
| |
| if (LIBCXX_GENERATE_COVERAGE) |
| include(CodeCoverage) |
| set(output_dir "${CMAKE_CURRENT_BINARY_DIR}/coverage") |
| set(capture_dirs "${LIBCXX_LIB_CMAKEFILES_DIR}/cxx.dir/;${LIBCXX_LIB_CMAKEFILES_DIR}/cxx_experimental.dir/;${CMAKE_CURRENT_BINARY_DIR}") |
| set(extract_dirs "${LIBCXX_SOURCE_DIR}/include;${LIBCXX_SOURCE_DIR}/src") |
| setup_lcov_test_target_coverage("cxx" "${output_dir}" "${capture_dirs}" "${extract_dirs}") |
| endif() |