Gitiles
Code Review Sign In
gerrit-public.fairphone.software / platform / external / libjpeg-turbo / 59c1a252d56f68cd3008cdb805cbce1ded48f151 / . / simd / jdcolss2.asm
blob: 6f74cc634af1319d303ff8c56b0bf427f4c2c650 [file] [log] [blame]
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]1;
2; jdcolss2.asm - colorspace conversion (SSE2)
3;
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]4; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
5;
6; Based on
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]7; x86 SIMD extension for IJG JPEG library
8; Copyright (C) 1999-2006, MIYASAKA Masaru.
9; For conditions of distribution and use, see copyright notice in jsimdext.inc
10;
11; This file should be assembled with NASM (Netwide Assembler),
12; can *not* be assembled with Microsoft's MASM or any compatible
13; assembler (including Borland's Turbo Assembler).
14; NASM is available from http://nasm.sourceforge.net/ or
15; http://sourceforge.net/project/showfiles.php?group_id=6208
16;
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]17; [TAB8]
18
Pierre Ossman3a65ef42009-03-16 13:34:18 +0000[diff] [blame]19%include "jsimdext.inc"
20%include "jcolsamp.inc"
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]21
22; --------------------------------------------------------------------------
23
24%define SCALEBITS 16
25
26F_0_344 equ 22554 ; FIX(0.34414)
27F_0_714 equ 46802 ; FIX(0.71414)
28F_1_402 equ 91881 ; FIX(1.40200)
29F_1_772 equ 116130 ; FIX(1.77200)
30F_0_402 equ (F_1_402 - 65536) ; FIX(1.40200) - FIX(1)
31F_0_285 equ ( 65536 - F_0_714) ; FIX(1) - FIX(0.71414)
32F_0_228 equ (131072 - F_1_772) ; FIX(2) - FIX(1.77200)
33
34; --------------------------------------------------------------------------
35 SECTION SEG_CONST
36
37 alignz 16
38 global EXTN(jconst_ycc_rgb_convert_sse2)
39
40EXTN(jconst_ycc_rgb_convert_sse2):
41
42PW_F0402 times 8 dw F_0_402
43PW_MF0228 times 8 dw -F_0_228
44PW_MF0344_F0285 times 4 dw -F_0_344, F_0_285
45PW_ONE times 8 dw 1
46PD_ONEHALF times 4 dd 1 << (SCALEBITS-1)
47
48 alignz 16
49
50; --------------------------------------------------------------------------
51 SECTION SEG_TEXT
52 BITS 32
53;
54; Convert some rows of samples to the output colorspace.
55;
56; GLOBAL(void)
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]57; jsimd_ycc_rgb_convert_sse2 (JDIMENSION out_width,
58; JSAMPIMAGE input_buf, JDIMENSION input_row,
59; JSAMPARRAY output_buf, int num_rows)
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]60;
61
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]62%define out_width(b) (b)+8 ; JDIMENSION out_width
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]63%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
64%define input_row(b) (b)+16 ; JDIMENSION input_row
65%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
66%define num_rows(b) (b)+24 ; int num_rows
67
68%define original_ebp ebp+0
69%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
70%define WK_NUM 2
71%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
72
73 align 16
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]74 global EXTN(jsimd_ycc_rgb_convert_sse2)
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]75
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]76EXTN(jsimd_ycc_rgb_convert_sse2):
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]77 push ebp
78 mov eax,esp ; eax = original ebp
79 sub esp, byte 4
80 and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
81 mov [esp],eax
82 mov ebp,esp ; ebp = aligned ebp
83 lea esp, [wk(0)]
84 pushpic eax ; make a room for GOT address
85 push ebx
86; push ecx ; need not be preserved
87; push edx ; need not be preserved
88 push esi
89 push edi
90
91 get_GOT ebx ; get GOT address
92 movpic POINTER [gotptr], ebx ; save GOT address
93
Pierre Ossmaneea72152009-03-09 13:34:17 +0000[diff] [blame]94 mov ecx, JDIMENSION [out_width(eax)] ; num_cols
MIYASAKA Masarua2e6a9d2006-02-04 00:00:00 +0000[diff] [blame]95 test ecx,ecx
96 jz near .return
97
98 push ecx
99
100 mov edi, JSAMPIMAGE [input_buf(eax)]
101 mov ecx, JDIMENSION [input_row(eax)]
102 mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
103 mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
104 mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
105 lea esi, [esi+ecx*SIZEOF_JSAMPROW]
106 lea ebx, [ebx+ecx*SIZEOF_JSAMPROW]
107 lea edx, [edx+ecx*SIZEOF_JSAMPROW]
108
109 pop ecx
110
111 mov edi, JSAMPARRAY [output_buf(eax)]
112 mov eax, INT [num_rows(eax)]
113 test eax,eax
114 jle near .return
115 alignx 16,7
116.rowloop:
117 push eax
118 push edi
119 push edx
120 push ebx
121 push esi
122 push ecx ; col
123
124 mov esi, JSAMPROW [esi] ; inptr0
125 mov ebx, JSAMPROW [ebx] ; inptr1
126 mov edx, JSAMPROW [edx] ; inptr2
127 mov edi, JSAMPROW [edi] ; outptr
128 movpic eax, POINTER [gotptr] ; load GOT address (eax)
129 alignx 16,7
130.columnloop:
131
132 movdqa xmm5, XMMWORD [ebx] ; xmm5=Cb(0123456789ABCDEF)
133 movdqa xmm1, XMMWORD [edx] ; xmm1=Cr(0123456789ABCDEF)
134
135 pcmpeqw xmm4,xmm4
136 pcmpeqw xmm7,xmm7
137 psrlw xmm4,BYTE_BIT
138 psllw xmm7,7 ; xmm7={0xFF80 0xFF80 0xFF80 0xFF80 ..}
139 movdqa xmm0,xmm4 ; xmm0=xmm4={0xFF 0x00 0xFF 0x00 ..}
140
141 pand xmm4,xmm5 ; xmm4=Cb(02468ACE)=CbE
142 psrlw xmm5,BYTE_BIT ; xmm5=Cb(13579BDF)=CbO
143 pand xmm0,xmm1 ; xmm0=Cr(02468ACE)=CrE
144 psrlw xmm1,BYTE_BIT ; xmm1=Cr(13579BDF)=CrO
145
146 paddw xmm4,xmm7
147 paddw xmm5,xmm7
148 paddw xmm0,xmm7
149 paddw xmm1,xmm7
150
151 ; (Original)
152 ; R = Y + 1.40200 * Cr
153 ; G = Y - 0.34414 * Cb - 0.71414 * Cr
154 ; B = Y + 1.77200 * Cb
155 ;
156 ; (This implementation)
157 ; R = Y + 0.40200 * Cr + Cr
158 ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
159 ; B = Y - 0.22800 * Cb + Cb + Cb
160
161 movdqa xmm2,xmm4 ; xmm2=CbE
162 movdqa xmm3,xmm5 ; xmm3=CbO
163 paddw xmm4,xmm4 ; xmm4=2*CbE
164 paddw xmm5,xmm5 ; xmm5=2*CbO
165 movdqa xmm6,xmm0 ; xmm6=CrE
166 movdqa xmm7,xmm1 ; xmm7=CrO
167 paddw xmm0,xmm0 ; xmm0=2*CrE
168 paddw xmm1,xmm1 ; xmm1=2*CrO
169
170 pmulhw xmm4,[GOTOFF(eax,PW_MF0228)] ; xmm4=(2*CbE * -FIX(0.22800))
171 pmulhw xmm5,[GOTOFF(eax,PW_MF0228)] ; xmm5=(2*CbO * -FIX(0.22800))
172 pmulhw xmm0,[GOTOFF(eax,PW_F0402)] ; xmm0=(2*CrE * FIX(0.40200))
173 pmulhw xmm1,[GOTOFF(eax,PW_F0402)] ; xmm1=(2*CrO * FIX(0.40200))
174
175 paddw xmm4,[GOTOFF(eax,PW_ONE)]
176 paddw xmm5,[GOTOFF(eax,PW_ONE)]
177 psraw xmm4,1 ; xmm4=(CbE * -FIX(0.22800))
178 psraw xmm5,1 ; xmm5=(CbO * -FIX(0.22800))
179 paddw xmm0,[GOTOFF(eax,PW_ONE)]
180 paddw xmm1,[GOTOFF(eax,PW_ONE)]
181 psraw xmm0,1 ; xmm0=(CrE * FIX(0.40200))
182 psraw xmm1,1 ; xmm1=(CrO * FIX(0.40200))
183
184 paddw xmm4,xmm2
185 paddw xmm5,xmm3
186 paddw xmm4,xmm2 ; xmm4=(CbE * FIX(1.77200))=(B-Y)E
187 paddw xmm5,xmm3 ; xmm5=(CbO * FIX(1.77200))=(B-Y)O
188 paddw xmm0,xmm6 ; xmm0=(CrE * FIX(1.40200))=(R-Y)E
189 paddw xmm1,xmm7 ; xmm1=(CrO * FIX(1.40200))=(R-Y)O
190
191 movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=(B-Y)E
192 movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(B-Y)O
193
194 movdqa xmm4,xmm2
195 movdqa xmm5,xmm3
196 punpcklwd xmm2,xmm6
197 punpckhwd xmm4,xmm6
198 pmaddwd xmm2,[GOTOFF(eax,PW_MF0344_F0285)]
199 pmaddwd xmm4,[GOTOFF(eax,PW_MF0344_F0285)]
200 punpcklwd xmm3,xmm7
201 punpckhwd xmm5,xmm7
202 pmaddwd xmm3,[GOTOFF(eax,PW_MF0344_F0285)]
203 pmaddwd xmm5,[GOTOFF(eax,PW_MF0344_F0285)]
204
205 paddd xmm2,[GOTOFF(eax,PD_ONEHALF)]
206 paddd xmm4,[GOTOFF(eax,PD_ONEHALF)]
207 psrad xmm2,SCALEBITS
208 psrad xmm4,SCALEBITS
209 paddd xmm3,[GOTOFF(eax,PD_ONEHALF)]
210 paddd xmm5,[GOTOFF(eax,PD_ONEHALF)]
211 psrad xmm3,SCALEBITS
212 psrad xmm5,SCALEBITS
213
214 packssdw xmm2,xmm4 ; xmm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
215 packssdw xmm3,xmm5 ; xmm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
216 psubw xmm2,xmm6 ; xmm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
217 psubw xmm3,xmm7 ; xmm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
218
219 movdqa xmm5, XMMWORD [esi] ; xmm5=Y(0123456789ABCDEF)
220
221 pcmpeqw xmm4,xmm4
222 psrlw xmm4,BYTE_BIT ; xmm4={0xFF 0x00 0xFF 0x00 ..}
223 pand xmm4,xmm5 ; xmm4=Y(02468ACE)=YE
224 psrlw xmm5,BYTE_BIT ; xmm5=Y(13579BDF)=YO
225
226 paddw xmm0,xmm4 ; xmm0=((R-Y)E+YE)=RE=R(02468ACE)
227 paddw xmm1,xmm5 ; xmm1=((R-Y)O+YO)=RO=R(13579BDF)
228 packuswb xmm0,xmm0 ; xmm0=R(02468ACE********)
229 packuswb xmm1,xmm1 ; xmm1=R(13579BDF********)
230
231 paddw xmm2,xmm4 ; xmm2=((G-Y)E+YE)=GE=G(02468ACE)
232 paddw xmm3,xmm5 ; xmm3=((G-Y)O+YO)=GO=G(13579BDF)
233 packuswb xmm2,xmm2 ; xmm2=G(02468ACE********)
234 packuswb xmm3,xmm3 ; xmm3=G(13579BDF********)
235
236 paddw xmm4, XMMWORD [wk(0)] ; xmm4=(YE+(B-Y)E)=BE=B(02468ACE)
237 paddw xmm5, XMMWORD [wk(1)] ; xmm5=(YO+(B-Y)O)=BO=B(13579BDF)
238 packuswb xmm4,xmm4 ; xmm4=B(02468ACE********)
239 packuswb xmm5,xmm5 ; xmm5=B(13579BDF********)
240
241%if RGB_PIXELSIZE == 3 ; ---------------
242
243 ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
244 ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
245 ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
246 ; xmmG=(** ** ** ** ** ** ** ** **), xmmH=(** ** ** ** ** ** ** ** **)
247
248 punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
249 punpcklbw xmmE,xmmB ; xmmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F)
250 punpcklbw xmmD,xmmF ; xmmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F)
251
252 movdqa xmmG,xmmA
253 movdqa xmmH,xmmA
254 punpcklwd xmmA,xmmE ; xmmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07)
255 punpckhwd xmmG,xmmE ; xmmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F)
256
257 psrldq xmmH,2 ; xmmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E -- --)
258 psrldq xmmE,2 ; xmmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F -- --)
259
260 movdqa xmmC,xmmD
261 movdqa xmmB,xmmD
262 punpcklwd xmmD,xmmH ; xmmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18)
263 punpckhwd xmmC,xmmH ; xmmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F -- --)
264
265 psrldq xmmB,2 ; xmmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F -- --)
266
267 movdqa xmmF,xmmE
268 punpcklwd xmmE,xmmB ; xmmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29)
269 punpckhwd xmmF,xmmB ; xmmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F -- -- -- --)
270
271 pshufd xmmH,xmmA,0x4E; xmmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03)
272 movdqa xmmB,xmmE
273 punpckldq xmmA,xmmD ; xmmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14)
274 punpckldq xmmE,xmmH ; xmmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07)
275 punpckhdq xmmD,xmmB ; xmmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29)
276
277 pshufd xmmH,xmmG,0x4E; xmmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B)
278 movdqa xmmB,xmmF
279 punpckldq xmmG,xmmC ; xmmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C)
280 punpckldq xmmF,xmmH ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F)
281 punpckhdq xmmC,xmmB ; xmmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F -- -- -- -- -- --)
282
283 punpcklqdq xmmA,xmmE ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
284 punpcklqdq xmmD,xmmG ; xmmD=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
285 punpcklqdq xmmF,xmmC ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
286
287 cmp ecx, byte SIZEOF_XMMWORD
288 jb short .column_st32
289
290 test edi, SIZEOF_XMMWORD-1
291 jnz short .out1
292 ; --(aligned)-------------------
293 movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
294 movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
295 movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmF
296 add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
297 jmp short .out0
298.out1: ; --(unaligned)-----------------
299 pcmpeqb xmmH,xmmH ; xmmH=(all 1's)
300 maskmovdqu xmmA,xmmH ; movntdqu XMMWORD [edi], xmmA
301 add edi, byte SIZEOF_XMMWORD ; outptr
302 maskmovdqu xmmD,xmmH ; movntdqu XMMWORD [edi], xmmD
303 add edi, byte SIZEOF_XMMWORD ; outptr
304 maskmovdqu xmmF,xmmH ; movntdqu XMMWORD [edi], xmmF
305 add edi, byte SIZEOF_XMMWORD ; outptr
306.out0:
307 sub ecx, byte SIZEOF_XMMWORD
308 jz near .nextrow
309
310 add esi, byte SIZEOF_XMMWORD ; inptr0
311 add ebx, byte SIZEOF_XMMWORD ; inptr1
312 add edx, byte SIZEOF_XMMWORD ; inptr2
313 jmp near .columnloop
314 alignx 16,7
315
316.column_st32:
317 pcmpeqb xmmH,xmmH ; xmmH=(all 1's)
318 lea ecx, [ecx+ecx*2] ; imul ecx, RGB_PIXELSIZE
319 cmp ecx, byte 2*SIZEOF_XMMWORD
320 jb short .column_st16
321 maskmovdqu xmmA,xmmH ; movntdqu XMMWORD [edi], xmmA
322 add edi, byte SIZEOF_XMMWORD ; outptr
323 maskmovdqu xmmD,xmmH ; movntdqu XMMWORD [edi], xmmD
324 add edi, byte SIZEOF_XMMWORD ; outptr
325 movdqa xmmA,xmmF
326 sub ecx, byte 2*SIZEOF_XMMWORD
327 jmp short .column_st15
328.column_st16:
329 cmp ecx, byte SIZEOF_XMMWORD
330 jb short .column_st15
331 maskmovdqu xmmA,xmmH ; movntdqu XMMWORD [edi], xmmA
332 add edi, byte SIZEOF_XMMWORD ; outptr
333 movdqa xmmA,xmmD
334 sub ecx, byte SIZEOF_XMMWORD
335.column_st15:
336 mov eax,ecx
337 xor ecx, byte 0x0F
338 shl ecx, 2
339 movd xmmB,ecx
340 psrlq xmmH,4
341 pcmpeqb xmmE,xmmE
342 psrlq xmmH,xmmB
343 psrlq xmmE,xmmB
344 punpcklbw xmmE,xmmH
345 ; ----------------
346 mov ecx,edi
347 and ecx, byte SIZEOF_XMMWORD-1
348 jz short .adj0
349 add eax,ecx
350 cmp eax, byte SIZEOF_XMMWORD
351 ja short .adj0
352 and edi, byte (-SIZEOF_XMMWORD) ; align to 16-byte boundary
353 shl ecx, 3 ; pslldq xmmA,ecx & pslldq xmmE,ecx
354 movdqa xmmG,xmmA
355 movdqa xmmC,xmmE
356 pslldq xmmA, SIZEOF_XMMWORD/2
357 pslldq xmmE, SIZEOF_XMMWORD/2
358 movd xmmD,ecx
359 sub ecx, byte (SIZEOF_XMMWORD/2)*BYTE_BIT
360 jb short .adj1
361 movd xmmF,ecx
362 psllq xmmA,xmmF
363 psllq xmmE,xmmF
364 jmp short .adj0
365.adj1: neg ecx
366 movd xmmF,ecx
367 psrlq xmmA,xmmF
368 psrlq xmmE,xmmF
369 psllq xmmG,xmmD
370 psllq xmmC,xmmD
371 por xmmA,xmmG
372 por xmmE,xmmC
373.adj0: ; ----------------
374 maskmovdqu xmmA,xmmE ; movntdqu XMMWORD [edi], xmmA
375
376%else ; RGB_PIXELSIZE == 4 ; -----------
377
378%ifdef RGBX_FILLER_0XFF
379 pcmpeqb xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
380 pcmpeqb xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
381%else
382 pxor xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
383 pxor xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
384%endif
385 ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
386 ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
387 ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
388 ; xmmG=(30 32 34 36 38 3A 3C 3E **), xmmH=(31 33 35 37 39 3B 3D 3F **)
389
390 punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
391 punpcklbw xmmE,xmmG ; xmmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E)
392 punpcklbw xmmB,xmmD ; xmmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F)
393 punpcklbw xmmF,xmmH ; xmmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F)
394
395 movdqa xmmC,xmmA
396 punpcklwd xmmA,xmmE ; xmmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36)
397 punpckhwd xmmC,xmmE ; xmmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E)
398 movdqa xmmG,xmmB
399 punpcklwd xmmB,xmmF ; xmmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37)
400 punpckhwd xmmG,xmmF ; xmmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F)
401
402 movdqa xmmD,xmmA
403 punpckldq xmmA,xmmB ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
404 punpckhdq xmmD,xmmB ; xmmD=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
405 movdqa xmmH,xmmC
406 punpckldq xmmC,xmmG ; xmmC=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
407 punpckhdq xmmH,xmmG ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
408
409 cmp ecx, byte SIZEOF_XMMWORD
410 jb short .column_st32
411
412 test edi, SIZEOF_XMMWORD-1
413 jnz short .out1
414 ; --(aligned)-------------------
415 movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
416 movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
417 movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmC
418 movntdq XMMWORD [edi+3*SIZEOF_XMMWORD], xmmH
419 add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
420 jmp short .out0
421.out1: ; --(unaligned)-----------------
422 pcmpeqb xmmE,xmmE ; xmmE=(all 1's)
423 maskmovdqu xmmA,xmmE ; movntdqu XMMWORD [edi], xmmA
424 add edi, byte SIZEOF_XMMWORD ; outptr
425 maskmovdqu xmmD,xmmE ; movntdqu XMMWORD [edi], xmmD
426 add edi, byte SIZEOF_XMMWORD ; outptr
427 maskmovdqu xmmC,xmmE ; movntdqu XMMWORD [edi], xmmC
428 add edi, byte SIZEOF_XMMWORD ; outptr
429 maskmovdqu xmmH,xmmE ; movntdqu XMMWORD [edi], xmmH
430 add edi, byte SIZEOF_XMMWORD ; outptr
431.out0:
432 sub ecx, byte SIZEOF_XMMWORD
433 jz near .nextrow
434
435 add esi, byte SIZEOF_XMMWORD ; inptr0
436 add ebx, byte SIZEOF_XMMWORD ; inptr1
437 add edx, byte SIZEOF_XMMWORD ; inptr2
438 jmp near .columnloop
439 alignx 16,7
440
441.column_st32:
442 pcmpeqb xmmE,xmmE ; xmmE=(all 1's)
443 cmp ecx, byte SIZEOF_XMMWORD/2
444 jb short .column_st16
445 maskmovdqu xmmA,xmmE ; movntdqu XMMWORD [edi], xmmA
446 add edi, byte SIZEOF_XMMWORD ; outptr
447 maskmovdqu xmmD,xmmE ; movntdqu XMMWORD [edi], xmmD
448 add edi, byte SIZEOF_XMMWORD ; outptr
449 movdqa xmmA,xmmC
450 movdqa xmmD,xmmH
451 sub ecx, byte SIZEOF_XMMWORD/2
452.column_st16:
453 cmp ecx, byte SIZEOF_XMMWORD/4
454 jb short .column_st15
455 maskmovdqu xmmA,xmmE ; movntdqu XMMWORD [edi], xmmA
456 add edi, byte SIZEOF_XMMWORD ; outptr
457 movdqa xmmA,xmmD
458 sub ecx, byte SIZEOF_XMMWORD/4
459.column_st15:
460 cmp ecx, byte SIZEOF_XMMWORD/16
461 jb short .nextrow
462 mov eax,ecx
463 xor ecx, byte 0x03
464 inc ecx
465 shl ecx, 4
466 movd xmmF,ecx
467 psrlq xmmE,xmmF
468 punpcklbw xmmE,xmmE
469 ; ----------------
470 mov ecx,edi
471 and ecx, byte SIZEOF_XMMWORD-1
472 jz short .adj0
473 lea eax, [ecx+eax*4] ; RGB_PIXELSIZE
474 cmp eax, byte SIZEOF_XMMWORD
475 ja short .adj0
476 and edi, byte (-SIZEOF_XMMWORD) ; align to 16-byte boundary
477 shl ecx, 3 ; pslldq xmmA,ecx & pslldq xmmE,ecx
478 movdqa xmmB,xmmA
479 movdqa xmmG,xmmE
480 pslldq xmmA, SIZEOF_XMMWORD/2
481 pslldq xmmE, SIZEOF_XMMWORD/2
482 movd xmmC,ecx
483 sub ecx, byte (SIZEOF_XMMWORD/2)*BYTE_BIT
484 jb short .adj1
485 movd xmmH,ecx
486 psllq xmmA,xmmH
487 psllq xmmE,xmmH
488 jmp short .adj0
489.adj1: neg ecx
490 movd xmmH,ecx
491 psrlq xmmA,xmmH
492 psrlq xmmE,xmmH
493 psllq xmmB,xmmC
494 psllq xmmG,xmmC
495 por xmmA,xmmB
496 por xmmE,xmmG
497.adj0: ; ----------------
498 maskmovdqu xmmA,xmmE ; movntdqu XMMWORD [edi], xmmA
499
500%endif ; RGB_PIXELSIZE ; ---------------
501
502 alignx 16,7
503
504.nextrow:
505 pop ecx
506 pop esi
507 pop ebx
508 pop edx
509 pop edi
510 pop eax
511
512 add esi, byte SIZEOF_JSAMPROW
513 add ebx, byte SIZEOF_JSAMPROW
514 add edx, byte SIZEOF_JSAMPROW
515 add edi, byte SIZEOF_JSAMPROW ; output_buf
516 dec eax ; num_rows
517 jg near .rowloop
518
519 sfence ; flush the write buffer
520
521.return:
522 pop edi
523 pop esi
524; pop edx ; need not be preserved
525; pop ecx ; need not be preserved
526 pop ebx
527 mov esp,ebp ; esp <- aligned ebp
528 pop esp ; esp <- original ebp
529 pop ebp
530 ret
531