Primiano Tucci | 4f9b6d7 | 2017-12-05 20:59:16 +0000 | [diff] [blame] | 1 | # Copyright (C) 2017 The Android Open Source Project |
| 2 | # |
| 3 | # Licensed under the Apache License, Version 2.0 (the "License"); |
| 4 | # you may not use this file except in compliance with the License. |
| 5 | # You may obtain a copy of the License at |
| 6 | # |
| 7 | # http://www.apache.org/licenses/LICENSE-2.0 |
| 8 | # |
| 9 | # Unless required by applicable law or agreed to in writing, software |
| 10 | # distributed under the License is distributed on an "AS IS" BASIS, |
| 11 | # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| 12 | # See the License for the specific language governing permissions and |
| 13 | # limitations under the License. |
| 14 | |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 15 | import("perfetto.gni") |
Primiano Tucci | 916f4e5 | 2020-10-16 20:40:33 +0200 | [diff] [blame] | 16 | import("perfetto_component.gni") |
Primiano Tucci | 4f9b6d7 | 2017-12-05 20:59:16 +0000 | [diff] [blame] | 17 | |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 18 | # This gni file defines rules for proto generation. There are various types of |
| 19 | # proto targets that can be defined in our codebase: |
| 20 | # "lite" targets: these use the standard libprotobuf library. They are used |
| 21 | # mainly for tests and readback. |
| 22 | # "zero" targets: these use the protozero library and its protoc plugin. They |
| 23 | # are used pretty much everywhere. |
| 24 | # "descriptor" targets: they are used to generate a proto-encoded reflection |
| 25 | # descriptor that describes the schema of the proto using protobuf itself. |
| 26 | # All these targets can be generated using the perfetto_proto_library rule. It |
| 27 | # wraps the instantiation of several proto targets using a convenience template. |
| 28 | # |
| 29 | # For instance: |
| 30 | # perfetto_proto_library("xxx_@TYPE@") { |
Andrew Shulaev | a7e60fe | 2020-06-09 10:33:06 +0100 | [diff] [blame] | 31 | # proto_generators = [ "lite", "zero" ] # lite+zero+cpp is the default value. |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 32 | # sources = [ "one.proto", "two.proto" ] |
| 33 | # deps = [ "dep:@TYPE@" ] |
| 34 | # } |
| 35 | # |
| 36 | # Is the equivalent of: |
| 37 | # proto_library("xxx_lite") { sources = [...], deps = [ "dep:lite"] } |
| 38 | # protozero_library("xxx_zero") { sources = [...], deps = [ "dep:zero"] } |
| 39 | |
| 40 | # Load the protobuf's proto_library() definition. |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 41 | if (!defined(perfetto_protobuf_target_prefix)) { |
Primiano Tucci | 7e05fc1 | 2019-08-27 17:29:47 +0200 | [diff] [blame] | 42 | if (perfetto_root_path == "//") { |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 43 | perfetto_protobuf_target_prefix = "//buildtools" |
| 44 | } else { |
| 45 | perfetto_protobuf_target_prefix = "//third_party/protobuf" |
| 46 | } |
Primiano Tucci | 4f9b6d7 | 2017-12-05 20:59:16 +0000 | [diff] [blame] | 47 | } |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 48 | if (!defined(perfetto_protobuf_gni)) { |
Primiano Tucci | 7e05fc1 | 2019-08-27 17:29:47 +0200 | [diff] [blame] | 49 | if (perfetto_root_path == "//") { |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 50 | perfetto_protobuf_gni = "//gn/standalone/proto_library.gni" |
| 51 | } else { |
| 52 | perfetto_protobuf_gni = "//third_party/protobuf/proto_library.gni" |
| 53 | } |
| 54 | } |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 55 | if (!defined(perfetto_protobuf_src_dir)) { |
| 56 | if (perfetto_root_path == "//") { |
| 57 | perfetto_protobuf_src_dir = "//buildtools/protobuf/src" |
| 58 | } else { |
| 59 | perfetto_protobuf_src_dir = "//third_party/protobuf/src" |
| 60 | } |
| 61 | } |
Primiano Tucci | 4c5efa4 | 2018-10-23 13:15:13 +0100 | [diff] [blame] | 62 | import(perfetto_protobuf_gni) |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 63 | |
| 64 | # Equivalent to proto_library (generation of .h/.cc from .proto files) but |
| 65 | # enables also generation using the protozero plugin. |
| 66 | # The generated files will have the .pbzero.{cc,h} suffix, as opposed to the |
| 67 | # .pb.{cc,h} of the official proto library. |
| 68 | # DO NOT use this target directly, use perfetto_proto_library() below. |
| 69 | template("protozero_library") { |
| 70 | proto_library(target_name) { |
| 71 | perfetto_root_path = invoker.perfetto_root_path |
| 72 | |
| 73 | generate_cc = false |
| 74 | generate_python = false |
| 75 | generator_plugin_label = |
| 76 | perfetto_root_path + "src/protozero/protoc_plugin:protozero_plugin" |
| 77 | generator_plugin_suffix = ".pbzero" |
| 78 | if (build_with_chromium) { |
| 79 | component_build_force_source_set = true |
| 80 | } |
| 81 | |
| 82 | if (defined(invoker.deps)) { |
| 83 | deps = invoker.deps |
| 84 | } else { |
| 85 | deps = [] |
| 86 | } |
| 87 | |
Andrew Shulaev | 292a92c | 2020-11-12 14:32:04 +0000 | [diff] [blame] | 88 | # omit_protozero_dep is intended to be used when protozero_library |
| 89 | # is used in Chrome (for generation of code for proto extensions) |
| 90 | # to avoid ODR violations in case of component builds. The embedder |
| 91 | # (Chrome) is then responsible for adding the appropriate transitive |
| 92 | # dependency on Protozero. |
| 93 | # |
| 94 | # TODO(b/173041866): use fine-grained components instead when available |
| 95 | if (!(defined(invoker.omit_protozero_dep) && invoker.omit_protozero_dep)) { |
| 96 | deps += [ perfetto_root_path + "src/protozero" ] |
| 97 | } |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 98 | |
| 99 | forward_variables_from(invoker, |
| 100 | [ |
| 101 | "defines", |
| 102 | "generator_plugin_options", |
| 103 | "include_dirs", |
| 104 | "proto_in_dir", |
| 105 | "proto_out_dir", |
| 106 | "sources", |
| 107 | "testonly", |
| 108 | "visibility", |
| 109 | "generate_descriptor", |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 110 | "propagate_imports_configs", |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 111 | "import_dirs", |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 112 | ]) |
| 113 | } |
| 114 | } |
| 115 | |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 116 | # This template generates .gen.cc/h files from .proto files. The generated |
| 117 | # sources are actual C++ classes that can be moved and copied around, very |
| 118 | # similar to the libprotobuf generated ones API-wise, but use protozero under |
| 119 | # the hoods, without any zero-copy benefit though. |
| 120 | # They are mainly used for the perfetto IPC layer and tests. |
| 121 | template("protozero_cpp_library") { |
| 122 | proto_library(target_name) { |
| 123 | perfetto_root_path = invoker.perfetto_root_path |
| 124 | |
| 125 | generate_cc = false |
| 126 | generate_python = false |
| 127 | generator_plugin_label = |
| 128 | perfetto_root_path + "src/protozero/protoc_plugin:cppgen_plugin" |
| 129 | generator_plugin_suffix = ".gen" |
| 130 | if (build_with_chromium) { |
| 131 | component_build_force_source_set = true |
| 132 | } |
| 133 | |
| 134 | deps = [ |
| 135 | "$perfetto_root_path/gn:default_deps", |
| 136 | "$perfetto_root_path/include/perfetto/base", |
Primiano Tucci | e8020f9 | 2019-11-26 13:24:01 +0000 | [diff] [blame] | 137 | "$perfetto_root_path/src/protozero", |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 138 | ] |
| 139 | |
| 140 | if (defined(invoker.deps)) { |
| 141 | deps += invoker.deps |
| 142 | } |
| 143 | |
| 144 | forward_variables_from(invoker, |
| 145 | [ |
| 146 | "defines", |
| 147 | "generator_plugin_options", |
| 148 | "include_dirs", |
| 149 | "proto_in_dir", |
| 150 | "proto_out_dir", |
| 151 | "sources", |
| 152 | "testonly", |
| 153 | "visibility", |
| 154 | "generate_descriptor", |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 155 | "propagate_imports_configs", |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 156 | "import_dirs", |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 157 | ]) |
| 158 | } |
| 159 | } |
| 160 | |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 161 | # Generates .ipc.{h,cc} stubs for IPC services defined in .proto files. |
| 162 | template("ipc_library") { |
| 163 | proto_library(target_name) { |
| 164 | perfetto_root_path = invoker.perfetto_root_path |
| 165 | generate_cc = false |
| 166 | generate_python = false |
| 167 | generator_plugin_label = |
| 168 | "$perfetto_root_path/src/ipc/protoc_plugin:ipc_plugin" |
| 169 | generator_plugin_suffix = ".ipc" |
Primiano Tucci | 916f4e5 | 2020-10-16 20:40:33 +0200 | [diff] [blame] | 170 | deps = [ "$perfetto_root_path/gn:default_deps" ] |
| 171 | if (perfetto_component_type == "static_library") { |
| 172 | deps += [ "$perfetto_root_path/src/ipc:perfetto_ipc" ] |
| 173 | } else { |
| 174 | deps += [ "$perfetto_root_path/src/ipc:common" ] |
| 175 | } |
Primiano Tucci | 5f3008e | 2021-05-19 21:34:45 +0100 | [diff] [blame] | 176 | if (is_win) { |
| 177 | # TODO(primiano): investigate this. In Windows standalone builds, some |
| 178 | # executable targets end up in a state where no code pulls a dep on the |
| 179 | # ipc:client (in turn that seems a subtle consequence of not having |
| 180 | # traced_probes on Windows). This dep here is effectively needed because |
| 181 | # the client-side code in the generated .ipc.cc effectively depends on the |
| 182 | # client-side IPC library. Perhaps we just should do this unconditionally |
| 183 | # on all platforms? |
| 184 | deps += [ "$perfetto_root_path/src/ipc:client" ] |
| 185 | } |
| 186 | |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 187 | if (defined(invoker.deps)) { |
| 188 | deps += invoker.deps |
| 189 | } |
| 190 | forward_variables_from(invoker, |
| 191 | [ |
| 192 | "defines", |
| 193 | "extra_configs", |
| 194 | "include_dirs", |
| 195 | "proto_in_dir", |
| 196 | "proto_out_dir", |
Primiano Tucci | e8020f9 | 2019-11-26 13:24:01 +0000 | [diff] [blame] | 197 | "generator_plugin_options", |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 198 | "sources", |
| 199 | "testonly", |
| 200 | "visibility", |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 201 | "propagate_imports_configs", |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 202 | "import_dirs", |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 203 | ]) |
| 204 | } |
| 205 | } |
| 206 | |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 207 | # The template used everywhere in the codebase. |
| 208 | template("perfetto_proto_library") { |
| 209 | if (defined(invoker.proto_generators)) { |
| 210 | proto_generators = invoker.proto_generators |
| 211 | } else { |
| 212 | proto_generators = [ |
| 213 | "zero", |
| 214 | "lite", |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 215 | "cpp", |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 216 | "source_set", |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 217 | ] |
| 218 | } |
| 219 | |
| 220 | # proto imports and C++ #includes are relative to this path. |
| 221 | if (defined(invoker.proto_path)) { |
| 222 | proto_path = invoker.proto_path |
| 223 | } else { |
Primiano Tucci | 355b8c8 | 2019-08-29 08:37:51 +0200 | [diff] [blame] | 224 | proto_path = perfetto_root_path |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 225 | } |
| 226 | |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 227 | if (defined(invoker.import_dirs)) { |
| 228 | import_dirs_ = invoker.import_dirs |
| 229 | } else { |
| 230 | import_dirs_ = [] |
| 231 | } |
| 232 | |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 233 | vars_to_forward = [ |
| 234 | "sources", |
| 235 | "visibility", |
| 236 | "testonly", |
Andrew Shulaev | e6c4a5c | 2021-01-29 11:07:39 +0000 | [diff] [blame] | 237 | "exclude_imports", |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 238 | ] |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 239 | expansion_token = "@TYPE@" |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 240 | |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 241 | # gn:public_config propagates the gen dir as include directory. We |
| 242 | # disable the proto_library's public_config to avoid duplicate include |
| 243 | # directory command line flags (crbug.com/1043279, crbug.com/gn/142). |
| 244 | propagate_imports_configs_ = false |
| 245 | |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 246 | foreach(gen_type, proto_generators) { |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 247 | target_name_ = string_replace(target_name, expansion_token, gen_type) |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 248 | |
| 249 | # Translate deps from xxx:@TYPE@ to xxx:lite/zero. |
| 250 | deps_ = [] |
| 251 | if (defined(invoker.deps)) { |
| 252 | foreach(dep, invoker.deps) { |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 253 | deps_ += [ string_replace(dep, expansion_token, gen_type) ] |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 254 | } |
| 255 | } |
| 256 | |
| 257 | if (gen_type == "zero") { |
| 258 | protozero_library(target_name_) { |
| 259 | proto_in_dir = proto_path |
| 260 | proto_out_dir = proto_path |
| 261 | generator_plugin_options = "wrapper_namespace=pbzero" |
| 262 | deps = deps_ |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 263 | propagate_imports_configs = propagate_imports_configs_ |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 264 | import_dirs = import_dirs_ |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 265 | forward_variables_from(invoker, vars_to_forward) |
| 266 | } |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 267 | } else if (gen_type == "cpp") { |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 268 | protozero_cpp_library(target_name_) { |
| 269 | proto_in_dir = proto_path |
| 270 | proto_out_dir = proto_path |
Primiano Tucci | e8020f9 | 2019-11-26 13:24:01 +0000 | [diff] [blame] | 271 | generator_plugin_options = "wrapper_namespace=gen" |
| 272 | deps = deps_ |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 273 | propagate_imports_configs = propagate_imports_configs_ |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 274 | import_dirs = import_dirs_ |
Primiano Tucci | 57dd66b | 2019-10-15 23:09:04 +0100 | [diff] [blame] | 275 | forward_variables_from(invoker, vars_to_forward) |
| 276 | } |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 277 | } else if (gen_type == "ipc") { |
Primiano Tucci | e8020f9 | 2019-11-26 13:24:01 +0000 | [diff] [blame] | 278 | cpp_target_name_ = string_replace(target_name, expansion_token, "cpp") |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 279 | ipc_library(target_name_) { |
| 280 | proto_in_dir = proto_path |
| 281 | proto_out_dir = proto_path |
Primiano Tucci | e8020f9 | 2019-11-26 13:24:01 +0000 | [diff] [blame] | 282 | generator_plugin_options = "wrapper_namespace=gen" |
| 283 | deps = deps_ + [ ":$cpp_target_name_" ] |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 284 | propagate_imports_configs = propagate_imports_configs_ |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 285 | import_dirs = import_dirs_ |
Primiano Tucci | 3aa027d | 2019-11-22 21:43:43 +0000 | [diff] [blame] | 286 | forward_variables_from(invoker, vars_to_forward) |
| 287 | } |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 288 | } else if (gen_type == "lite") { |
| 289 | proto_library(target_name_) { |
| 290 | proto_in_dir = proto_path |
| 291 | proto_out_dir = proto_path |
| 292 | generate_python = false |
| 293 | deps = deps_ |
Primiano Tucci | 7b6a788 | 2020-01-20 22:34:31 +0000 | [diff] [blame] | 294 | cc_generator_options = "lite=true:" |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 295 | propagate_imports_configs = propagate_imports_configs_ |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 296 | import_dirs = import_dirs_ |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 297 | forward_variables_from(invoker, vars_to_forward) |
| 298 | } |
| 299 | } else if (gen_type == "descriptor") { |
| 300 | proto_library(target_name_) { |
| 301 | proto_in_dir = proto_path |
| 302 | proto_out_dir = proto_path |
| 303 | generate_python = false |
| 304 | generate_cc = false |
Lalit Maganti | 45d8eb8 | 2020-09-12 16:32:18 +0100 | [diff] [blame] | 305 | generate_descriptor = |
| 306 | rebase_path(invoker.generate_descriptor, proto_path) |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 307 | deps = deps_ |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 308 | import_dirs = import_dirs_ |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 309 | forward_variables_from(invoker, vars_to_forward) |
| 310 | } |
Eric Seckler | d7fd6c2 | 2020-01-22 18:46:35 +0000 | [diff] [blame] | 311 | |
| 312 | # Not needed for descriptor proto_library target. |
| 313 | not_needed([ "propagate_imports_configs_" ]) |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 314 | } else if (gen_type == "source_set") { |
| 315 | action(target_name_) { |
| 316 | out_path = "$target_gen_dir/" + target_name_ |
| 317 | rebased_out_path = |
| 318 | rebase_path(target_gen_dir, root_build_dir) + "/" + target_name_ |
| 319 | |
| 320 | script = "$perfetto_root_path/tools/touch_file.py" |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 321 | args = [ |
| 322 | "--output", |
| 323 | rebased_out_path, |
| 324 | ] |
| 325 | outputs = [ out_path ] |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 326 | deps = deps_ |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 327 | |
| 328 | metadata = { |
| 329 | proto_library_sources = invoker.sources |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 330 | import_dirs = import_dirs_ |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 331 | } |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 332 | forward_variables_from(invoker, vars_to_forward) |
Lalit Maganti | 117272f | 2020-09-11 14:01:18 +0100 | [diff] [blame] | 333 | } |
Lalit Maganti | 3b09a3f | 2020-09-14 13:28:44 +0100 | [diff] [blame] | 334 | |
| 335 | # Not needed for source_set proto_library target. |
Lalit Maganti | eeae1e0 | 2020-09-14 17:03:35 +0100 | [diff] [blame] | 336 | not_needed([ |
| 337 | "propagate_imports_configs_", |
| 338 | "proto_path", |
| 339 | ]) |
Primiano Tucci | 2cf8b53 | 2019-08-29 01:14:01 +0200 | [diff] [blame] | 340 | } else { |
| 341 | assert(false, "Invalid 'proto_generators' value.") |
| 342 | } |
| 343 | } |
| 344 | } |