pw_checksum/BUILD.gn

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

# gn-format disable
import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")
config("default_config") {
  include_dirs = [ "public" ]
}

pw_source_set("pw_checksum") {
  public_configs = [ ":default_config" ]
  public = [
    "public/pw_checksum/ccitt_crc16.h",
    "public/pw_checksum/crc32.h",
  ]
  sources = [
    "ccitt_crc16.cc",
    "crc32.cc",
  ]
  public_deps = [ dir_pw_span ]
}

pw_test_group("tests") {
  tests = [
    ":ccitt_crc16_test",
    ":crc32_test",
  ]
}

pw_test("ccitt_crc16_test") {
  deps = [ ":pw_checksum" ]
  sources = [
    "ccitt_crc16_test.cc",
    "ccitt_crc16_test_c.c",
  ]
}

pw_test("crc32_test") {
  deps = [ ":pw_checksum" ]
  sources = [
    "crc32_test.cc",
    "crc32_test_c.c",
  ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}