Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 1 | @echo off |
| 2 | goto Run |
| 3 | :Usage |
| 4 | echo.%~nx0 [flags and arguments] [quoted MSBuild options] |
| 5 | echo. |
| 6 | echo.Build CPython from the command line. Requires the appropriate |
| 7 | echo.version(s) of Microsoft Visual Studio to be installed (see readme.txt). |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 8 | echo. |
| 9 | echo.After the flags recognized by this script, up to 9 arguments to be passed |
| 10 | echo.directly to MSBuild may be passed. If the argument contains an '=', the |
| 11 | echo.entire argument must be quoted (e.g. `%~nx0 "/p:PlatformToolset=v100"`). |
| 12 | echo.Alternatively you can put extra flags for MSBuild in a file named |
| 13 | echo.`msbuild.rsp` in the `PCbuild` directory, one flag per line. This file |
| 14 | echo.will be picked automatically by MSBuild. Flags put in this file does not |
| 15 | echo.need to be quoted. You can still use environment variables inside the |
| 16 | echo.response file. |
| 17 | echo. |
| 18 | echo.Available flags: |
| 19 | echo. -h Display this help message |
| 20 | echo. -V Display version information for the current build |
| 21 | echo. -r Target Rebuild instead of Build |
| 22 | echo. -d Set the configuration to Debug |
Zachary Ware | d01db1c | 2017-09-06 17:29:37 -0700 | [diff] [blame] | 23 | echo. -E Don't fetch or build external libraries. Extension modules that |
| 24 | echo. depend on external libraries will not attempt to build if this flag |
| 25 | echo. is present; -e is also accepted to explicitly enable fetching and |
| 26 | echo. building externals. |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 27 | echo. -m Enable parallel build (enabled by default) |
| 28 | echo. -M Disable parallel build |
| 29 | echo. -v Increased output messages |
| 30 | echo. -k Attempt to kill any running Pythons before building (usually done |
| 31 | echo. automatically by the pythoncore project) |
| 32 | echo. --pgo Build with Profile-Guided Optimization. This flag |
| 33 | echo. overrides -c and -d |
| 34 | echo. --test-marker Enable the test marker within the build. |
| 35 | echo. |
| 36 | echo.Available flags to avoid building certain modules. |
| 37 | echo.These flags have no effect if '-e' is not given: |
| 38 | echo. --no-ssl Do not attempt to build _ssl |
| 39 | echo. --no-tkinter Do not attempt to build Tkinter |
| 40 | echo. |
| 41 | echo.Available arguments: |
| 42 | echo. -c Release ^| Debug ^| PGInstrument ^| PGUpdate |
| 43 | echo. Set the configuration (default: Release) |
| 44 | echo. -p x64 ^| Win32 |
| 45 | echo. Set the platform (default: Win32) |
| 46 | echo. -t Build ^| Rebuild ^| Clean ^| CleanAll |
| 47 | echo. Set the target manually |
| 48 | echo. --pgo-job The job to use for PGO training; implies --pgo |
| 49 | echo. (default: "-m test --pgo") |
| 50 | exit /b 127 |
| 51 | |
| 52 | :Run |
| 53 | setlocal |
| 54 | set platf=Win32 |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 55 | set conf=Release |
| 56 | set target=Build |
| 57 | set dir=%~dp0 |
| 58 | set parallel=/m |
| 59 | set verbose=/nologo /v:m |
| 60 | set kill= |
| 61 | set do_pgo= |
| 62 | set pgo_job=-m test --pgo |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 63 | |
| 64 | :CheckOpts |
| 65 | if "%~1"=="-h" goto Usage |
| 66 | if "%~1"=="-c" (set conf=%2) & shift & shift & goto CheckOpts |
| 67 | if "%~1"=="-p" (set platf=%2) & shift & shift & goto CheckOpts |
| 68 | if "%~1"=="-r" (set target=Rebuild) & shift & goto CheckOpts |
| 69 | if "%~1"=="-t" (set target=%2) & shift & shift & goto CheckOpts |
| 70 | if "%~1"=="-d" (set conf=Debug) & shift & goto CheckOpts |
| 71 | if "%~1"=="-m" (set parallel=/m) & shift & goto CheckOpts |
| 72 | if "%~1"=="-M" (set parallel=) & shift & goto CheckOpts |
| 73 | if "%~1"=="-v" (set verbose=/v:n) & shift & goto CheckOpts |
| 74 | if "%~1"=="-k" (set kill=true) & shift & goto CheckOpts |
| 75 | if "%~1"=="--pgo" (set do_pgo=true) & shift & goto CheckOpts |
| 76 | if "%~1"=="--pgo-job" (set do_pgo=true) & (set pgo_job=%~2) & shift & shift & goto CheckOpts |
| 77 | if "%~1"=="--test-marker" (set UseTestMarker=true) & shift & goto CheckOpts |
| 78 | if "%~1"=="-V" shift & goto Version |
| 79 | rem These use the actual property names used by MSBuild. We could just let |
| 80 | rem them in through the environment, but we specify them on the command line |
| 81 | rem anyway for visibility so set defaults after this |
| 82 | if "%~1"=="-e" (set IncludeExternals=true) & shift & goto CheckOpts |
Zachary Ware | d01db1c | 2017-09-06 17:29:37 -0700 | [diff] [blame] | 83 | if "%~1"=="-E" (set IncludeExternals=false) & shift & goto CheckOpts |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 84 | if "%~1"=="--no-ssl" (set IncludeSSL=false) & shift & goto CheckOpts |
| 85 | if "%~1"=="--no-tkinter" (set IncludeTkinter=false) & shift & goto CheckOpts |
| 86 | |
Steve Dower | 05f01d8 | 2017-09-07 11:49:23 -0700 | [diff] [blame] | 87 | if "%IncludeExternals%"=="" set IncludeExternals=true |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 88 | if "%IncludeSSL%"=="" set IncludeSSL=true |
| 89 | if "%IncludeTkinter%"=="" set IncludeTkinter=true |
| 90 | |
| 91 | if "%IncludeExternals%"=="true" call "%dir%get_externals.bat" |
| 92 | |
Steve Dower | 40a23e8 | 2017-06-19 10:34:25 -0700 | [diff] [blame] | 93 | if "%do_pgo%" EQU "true" if "%platf%" EQU "x64" ( |
| 94 | if "%PROCESSOR_ARCHITEW6432%" NEQ "AMD64" if "%PROCESSOR_ARCHITECTURE%" NEQ "AMD64" ( |
| 95 | echo.ERROR: Cannot cross-compile with PGO |
| 96 | echo. 32bit operating system detected. Ensure your PROCESSOR_ARCHITECTURE |
| 97 | echo. and PROCESSOR_ARCHITEW6432 environment variables are correct. |
| 98 | exit /b 1 |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 99 | ) |
| 100 | ) |
| 101 | |
| 102 | if not exist "%GIT%" where git > "%TEMP%\git.loc" 2> nul && set /P GIT= < "%TEMP%\git.loc" & del "%TEMP%\git.loc" |
| 103 | if exist "%GIT%" set GITProperty=/p:GIT="%GIT%" |
| 104 | if not exist "%GIT%" echo Cannot find Git on PATH & set GITProperty= |
| 105 | |
| 106 | rem Setup the environment |
Steve Dower | 40a23e8 | 2017-06-19 10:34:25 -0700 | [diff] [blame] | 107 | call "%dir%find_msbuild.bat" %MSBUILD% |
| 108 | if ERRORLEVEL 1 (echo Cannot locate MSBuild.exe on PATH or as MSBUILD variable & exit /b 2) |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 109 | |
| 110 | if "%kill%"=="true" call :Kill |
| 111 | |
| 112 | if "%do_pgo%"=="true" ( |
| 113 | set conf=PGInstrument |
| 114 | call :Build %1 %2 %3 %4 %5 %6 %7 %8 %9 |
| 115 | del /s "%dir%\*.pgc" |
| 116 | del /s "%dir%\..\Lib\*.pyc" |
| 117 | echo on |
| 118 | call "%dir%\..\python.bat" %pgo_job% |
| 119 | @echo off |
| 120 | call :Kill |
| 121 | set conf=PGUpdate |
| 122 | set target=Build |
| 123 | ) |
| 124 | goto Build |
| 125 | :Kill |
| 126 | echo on |
Steve Dower | 40a23e8 | 2017-06-19 10:34:25 -0700 | [diff] [blame] | 127 | %MSBUILD% "%dir%\pythoncore.vcxproj" /t:KillPython %verbose%^ |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 128 | /p:Configuration=%conf% /p:Platform=%platf%^ |
| 129 | /p:KillPython=true |
| 130 | |
| 131 | @echo off |
| 132 | goto :eof |
| 133 | |
| 134 | :Build |
| 135 | rem Call on MSBuild to do the work, echo the command. |
| 136 | rem Passing %1-9 is not the preferred option, but argument parsing in |
| 137 | rem batch is, shall we say, "lackluster" |
| 138 | echo on |
Steve Dower | 40a23e8 | 2017-06-19 10:34:25 -0700 | [diff] [blame] | 139 | %MSBUILD% "%dir%pcbuild.proj" /t:%target% %parallel% %verbose%^ |
Zachary Ware | 6b6e687 | 2017-06-10 14:58:42 -0500 | [diff] [blame] | 140 | /p:Configuration=%conf% /p:Platform=%platf%^ |
| 141 | /p:IncludeExternals=%IncludeExternals%^ |
| 142 | /p:IncludeSSL=%IncludeSSL% /p:IncludeTkinter=%IncludeTkinter%^ |
| 143 | /p:UseTestMarker=%UseTestMarker% %GITProperty%^ |
| 144 | %1 %2 %3 %4 %5 %6 %7 %8 %9 |
| 145 | |
| 146 | @echo off |
| 147 | goto :eof |
| 148 | |
| 149 | :Version |
| 150 | rem Display the current build version information |
Steve Dower | 40a23e8 | 2017-06-19 10:34:25 -0700 | [diff] [blame] | 151 | %MSBUILD% "%dir%python.props" /t:ShowVersionInfo /v:m /nologo %1 %2 %3 %4 %5 %6 %7 %8 %9 |