Add a project structure for the Wear Support Module.
This CL adds an Android Studio project as well as make
files and some initial sources for the upcoming Android
Wear Support module in the Android Support Library.
Test: make framework/support/wearable tests
Bug: 33035990
Change-Id: Id7e38da305cab28ef4a746ddbfd7fb76130b2ec8
diff --git a/wearable/build.gradle b/wearable/build.gradle
new file mode 100644
index 0000000..666770f
--- /dev/null
+++ b/wearable/build.gradle
@@ -0,0 +1,126 @@
+apply plugin: 'com.android.library'
+
+archivesBaseName = 'wearable'
+
+dependencies {
+ compile project(':support-annotations')
+ compile project(':support-core-ui')
+ androidTestCompile ("com.android.support.test:runner:${project.rootProject.ext.testRunnerVersion}") {
+ exclude module: 'support-annotations'
+ }
+ androidTestCompile ("com.android.support.test.espresso:espresso-core:${project.rootProject.ext.espressoVersion}") {
+ exclude module: 'support-annotations'
+ }
+ testCompile 'junit:junit:4.12'
+ testCompile "org.mockito:mockito-core:1.9.5"
+ testCompile ("com.android.support.test:runner:${project.rootProject.ext.testRunnerVersion}") {
+ exclude module: 'support-annotations'
+ }
+ androidTestCompile "org.mockito:mockito-core:1.9.5"
+ androidTestCompile "com.google.dexmaker:dexmaker:1.2"
+ androidTestCompile "com.google.dexmaker:dexmaker-mockito:1.2"
+}
+
+android {
+ compileSdkVersion project.ext.currentSdk
+
+ defaultConfig {
+ minSdkVersion 20
+ testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
+ }
+
+ sourceSets {
+ main.manifest.srcFile 'AndroidManifest.xml'
+ main.java.srcDir 'src'
+ main.res.srcDirs 'res', 'res-public'
+
+ androidTest.setRoot('tests')
+ androidTest.java.srcDir 'tests/src'
+ androidTest.res.srcDir 'tests/res'
+ androidTest.manifest.srcFile 'tests/AndroidManifest.xml'
+ }
+
+ compileOptions {
+ sourceCompatibility JavaVersion.VERSION_1_7
+ targetCompatibility JavaVersion.VERSION_1_7
+ }
+
+ packagingOptions {
+ exclude 'LICENSE.txt'
+ }
+
+ testOptions {
+ unitTests.returnDefaultValues = true
+ }
+
+ buildTypes.all {
+ consumerProguardFiles 'proguard-rules.pro'
+ }
+}
+
+android.libraryVariants.all { variant ->
+ def name = variant.buildType.name
+
+ if (name.equals(com.android.builder.core.BuilderConstants.DEBUG)) {
+ return; // Skip debug builds.
+ }
+ def suffix = name.capitalize()
+
+ def jarTask = project.tasks.create(name: "jar${suffix}", type: Jar){
+ dependsOn variant.javaCompile
+ from variant.javaCompile.destinationDir
+ from 'LICENSE.txt'
+ }
+ def javadocTask = project.tasks.create(name: "javadoc${suffix}", type: Javadoc) {
+ source android.sourceSets.main.java
+ classpath = files(variant.javaCompile.classpath.files) + files(
+ "${android.sdkDirectory}/platforms/${android.compileSdkVersion}/android.jar")
+ }
+
+ def javadocJarTask = project.tasks.create(name: "javadocJar${suffix}", type: Jar) {
+ classifier = 'javadoc'
+ from 'build/docs/javadoc'
+ }
+
+ def sourcesJarTask = project.tasks.create(name: "sourceJar${suffix}", type: Jar) {
+ classifier = 'sources'
+ from android.sourceSets.main.java.srcDirs
+ }
+
+ artifacts.add('archives', javadocJarTask);
+ artifacts.add('archives', sourcesJarTask);
+}
+
+uploadArchives {
+ repositories {
+ mavenDeployer {
+ repository(url: uri(rootProject.ext.supportRepoOut)) {
+ }
+
+ pom.project {
+ name 'Android Wear Support UI'
+ description "Android Wear Support UI"
+ url 'http://developer.android.com/tools/extras/support-library.html'
+ inceptionYear '2016'
+
+ licenses {
+ license {
+ name 'The Apache Software License, Version 2.0'
+ url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+ distribution 'repo'
+ }
+ }
+
+ scm {
+ url "http://source.android.com"
+ connection "scm:git:https://android.googlesource.com/platform/frameworks/support"
+ }
+ developers {
+ developer {
+ name 'The Android Open Source Project'
+ }
+ }
+ }
+ }
+ }
+}