[LoopUnswitch] Add block frequency analysis to recognize hot/cold regions
Summary: This patch adds block frequency analysis to LoopUnswitch pass to recognize hot/cold regions. For cold regions the pass only performs trivial unswitches since they do not increase code size, and for hot regions everything works as before. This helps to minimize code growth in cold regions and be more aggressive in hot regions. Currently the default cold regions are blocks with frequencies below 20% of function entry frequency, and it can be adjusted via -loop-unswitch-cold-block-frequency flag. The entire feature is controlled via -loop-unswitch-with-block-frequency flag and it is off by default.
Reviewers: broune, silvas, dnovillo, reames
Subscribers: davidxl, llvm-commits
Differential Revision: http://reviews.llvm.org/D11605
llvm-svn: 248777
diff --git a/llvm/test/Transforms/LoopUnswitch/cold-loop.ll b/llvm/test/Transforms/LoopUnswitch/cold-loop.ll
new file mode 100644
index 0000000..1fbc080
--- /dev/null
+++ b/llvm/test/Transforms/LoopUnswitch/cold-loop.ll
@@ -0,0 +1,52 @@
+; RUN: opt < %s -loop-unswitch -loop-unswitch-with-block-frequency -S 2>&1 | FileCheck %s
+
+;; trivial condition should be unswithed regardless of coldness.
+define i32 @test1(i1 %cond1, i1 %cond2) !prof !1 {
+ br i1 %cond1, label %loop_begin, label %loop_exit, !prof !0
+
+loop_begin:
+; CHECK: br i1 true, label %continue, label %loop_exit.loopexit
+ br i1 %cond2, label %continue, label %loop_exit ; trivial condition
+
+continue:
+ call void @some_func1() noreturn nounwind
+ br label %loop_begin
+
+loop_exit:
+ ret i32 0
+}
+
+;; cold non-trivial condition should not be unswitched.
+define i32 @test2(i32* %var, i1 %cond1, i1 %cond2) !prof !1 {
+ br i1 %cond1, label %loop_begin, label %loop_exit, !prof !0
+
+loop_begin:
+ store i32 1, i32* %var
+; CHECK: br i1 %cond2, label %continue1, label %continue2
+ br i1 %cond2, label %continue1, label %continue2 ; non-trivial condition
+
+continue1:
+ call void @some_func1() noreturn nounwind
+ br label %joint
+
+continue2:
+ call void @some_func2() noreturn nounwind
+ br label %joint
+
+joint:
+;; unswitching will duplicate these calls.
+ call void @some_func3() noreturn nounwind
+ call void @some_func4() noreturn nounwind
+ br label %loop_begin
+
+loop_exit:
+ ret i32 0
+}
+
+declare void @some_func1() noreturn
+declare void @some_func2() noreturn
+declare void @some_func3() noreturn
+declare void @some_func4() noreturn
+
+!0 = !{!"branch_weights", i32 1, i32 100000000}
+!1 = !{!"function_entry_count", i64 100}