Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 1 | /* |
| 2 | * This file is subject to the terms and conditions of the GNU General Public |
| 3 | * License. See the file "COPYING" in the main directory of this archive |
| 4 | * for more details. |
| 5 | * |
| 6 | * Unified implementation of memcpy, memmove and the __copy_user backend. |
| 7 | * |
| 8 | * Copyright (C) 1998, 99, 2000, 01, 2002 Ralf Baechle (ralf@gnu.org) |
| 9 | * Copyright (C) 1999, 2000, 01, 2002 Silicon Graphics, Inc. |
| 10 | * Copyright (C) 2002 Broadcom, Inc. |
| 11 | * memcpy/copy_user author: Mark Vandevoorde |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 12 | * Copyright (C) 2007 Maciej W. Rozycki |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 13 | * Copyright (C) 2014 Imagination Technologies Ltd. |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 14 | * |
| 15 | * Mnemonic names for arguments to memcpy/__copy_user |
| 16 | */ |
Ralf Baechle | e5adb87 | 2005-10-20 22:55:26 +0100 | [diff] [blame] | 17 | |
| 18 | /* |
| 19 | * Hack to resolve longstanding prefetch issue |
| 20 | * |
| 21 | * Prefetching may be fatal on some systems if we're prefetching beyond the |
| 22 | * end of memory on some systems. It's also a seriously bad idea on non |
| 23 | * dma-coherent systems. |
| 24 | */ |
Ralf Baechle | 634286f | 2009-01-28 17:48:40 +0000 | [diff] [blame] | 25 | #ifdef CONFIG_DMA_NONCOHERENT |
Ralf Baechle | e5adb87 | 2005-10-20 22:55:26 +0100 | [diff] [blame] | 26 | #undef CONFIG_CPU_HAS_PREFETCH |
| 27 | #endif |
| 28 | #ifdef CONFIG_MIPS_MALTA |
| 29 | #undef CONFIG_CPU_HAS_PREFETCH |
| 30 | #endif |
| 31 | |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 32 | #include <asm/asm.h> |
Sam Ravnborg | 048eb58 | 2005-09-09 22:32:31 +0200 | [diff] [blame] | 33 | #include <asm/asm-offsets.h> |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 34 | #include <asm/regdef.h> |
| 35 | |
| 36 | #define dst a0 |
| 37 | #define src a1 |
| 38 | #define len a2 |
| 39 | |
| 40 | /* |
| 41 | * Spec |
| 42 | * |
| 43 | * memcpy copies len bytes from src to dst and sets v0 to dst. |
| 44 | * It assumes that |
| 45 | * - src and dst don't overlap |
| 46 | * - src is readable |
| 47 | * - dst is writable |
| 48 | * memcpy uses the standard calling convention |
| 49 | * |
| 50 | * __copy_user copies up to len bytes from src to dst and sets a2 (len) to |
| 51 | * the number of uncopied bytes due to an exception caused by a read or write. |
| 52 | * __copy_user assumes that src and dst don't overlap, and that the call is |
| 53 | * implementing one of the following: |
| 54 | * copy_to_user |
| 55 | * - src is readable (no exceptions when reading src) |
| 56 | * copy_from_user |
| 57 | * - dst is writable (no exceptions when writing dst) |
| 58 | * __copy_user uses a non-standard calling convention; see |
| 59 | * include/asm-mips/uaccess.h |
| 60 | * |
| 61 | * When an exception happens on a load, the handler must |
| 62 | # ensure that all of the destination buffer is overwritten to prevent |
| 63 | * leaking information to user mode programs. |
| 64 | */ |
| 65 | |
| 66 | /* |
| 67 | * Implementation |
| 68 | */ |
| 69 | |
| 70 | /* |
| 71 | * The exception handler for loads requires that: |
| 72 | * 1- AT contain the address of the byte just past the end of the source |
| 73 | * of the copy, |
| 74 | * 2- src_entry <= src < AT, and |
| 75 | * 3- (dst - src) == (dst_entry - src_entry), |
| 76 | * The _entry suffix denotes values when __copy_user was called. |
| 77 | * |
| 78 | * (1) is set up up by uaccess.h and maintained by not writing AT in copy_user |
| 79 | * (2) is met by incrementing src by the number of bytes copied |
| 80 | * (3) is met by not doing loads between a pair of increments of dst and src |
| 81 | * |
| 82 | * The exception handlers for stores adjust len (if necessary) and return. |
| 83 | * These handlers do not need to overwrite any data. |
| 84 | * |
| 85 | * For __rmemcpy and memmove an exception is always a kernel bug, therefore |
| 86 | * they're not protected. |
| 87 | */ |
| 88 | |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 89 | /* Instruction type */ |
| 90 | #define LD_INSN 1 |
| 91 | #define ST_INSN 2 |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 92 | /* Pretech type */ |
| 93 | #define SRC_PREFETCH 1 |
| 94 | #define DST_PREFETCH 2 |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 95 | |
| 96 | /* |
| 97 | * Wrapper to add an entry in the exception table |
| 98 | * in case the insn causes a memory exception. |
| 99 | * Arguments: |
| 100 | * insn : Load/store instruction |
| 101 | * type : Instruction type |
| 102 | * reg : Register |
| 103 | * addr : Address |
| 104 | * handler : Exception handler |
| 105 | */ |
| 106 | #define EXC(insn, type, reg, addr, handler) \ |
| 107 | 9: insn reg, addr; \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 108 | .section __ex_table,"a"; \ |
| 109 | PTR 9b, handler; \ |
| 110 | .previous |
| 111 | |
| 112 | /* |
| 113 | * Only on the 64-bit kernel we can made use of 64-bit registers. |
| 114 | */ |
Ralf Baechle | 875d43e | 2005-09-03 15:56:16 -0700 | [diff] [blame] | 115 | #ifdef CONFIG_64BIT |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 116 | #define USE_DOUBLE |
| 117 | #endif |
| 118 | |
| 119 | #ifdef USE_DOUBLE |
| 120 | |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 121 | #define LOADK ld /* No exception */ |
| 122 | #define LOAD(reg, addr, handler) EXC(ld, LD_INSN, reg, addr, handler) |
| 123 | #define LOADL(reg, addr, handler) EXC(ldl, LD_INSN, reg, addr, handler) |
| 124 | #define LOADR(reg, addr, handler) EXC(ldr, LD_INSN, reg, addr, handler) |
| 125 | #define STOREL(reg, addr, handler) EXC(sdl, ST_INSN, reg, addr, handler) |
| 126 | #define STORER(reg, addr, handler) EXC(sdr, ST_INSN, reg, addr, handler) |
| 127 | #define STORE(reg, addr, handler) EXC(sd, ST_INSN, reg, addr, handler) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 128 | #define ADD daddu |
| 129 | #define SUB dsubu |
| 130 | #define SRL dsrl |
| 131 | #define SRA dsra |
| 132 | #define SLL dsll |
| 133 | #define SLLV dsllv |
| 134 | #define SRLV dsrlv |
| 135 | #define NBYTES 8 |
| 136 | #define LOG_NBYTES 3 |
| 137 | |
Ralf Baechle | 42a3b4f | 2005-09-03 15:56:17 -0700 | [diff] [blame] | 138 | /* |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 139 | * As we are sharing code base with the mips32 tree (which use the o32 ABI |
| 140 | * register definitions). We need to redefine the register definitions from |
| 141 | * the n64 ABI register naming to the o32 ABI register naming. |
| 142 | */ |
| 143 | #undef t0 |
| 144 | #undef t1 |
| 145 | #undef t2 |
| 146 | #undef t3 |
| 147 | #define t0 $8 |
| 148 | #define t1 $9 |
| 149 | #define t2 $10 |
| 150 | #define t3 $11 |
| 151 | #define t4 $12 |
| 152 | #define t5 $13 |
| 153 | #define t6 $14 |
| 154 | #define t7 $15 |
Ralf Baechle | 42a3b4f | 2005-09-03 15:56:17 -0700 | [diff] [blame] | 155 | |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 156 | #else |
| 157 | |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 158 | #define LOADK lw /* No exception */ |
| 159 | #define LOAD(reg, addr, handler) EXC(lw, LD_INSN, reg, addr, handler) |
| 160 | #define LOADL(reg, addr, handler) EXC(lwl, LD_INSN, reg, addr, handler) |
| 161 | #define LOADR(reg, addr, handler) EXC(lwr, LD_INSN, reg, addr, handler) |
| 162 | #define STOREL(reg, addr, handler) EXC(swl, ST_INSN, reg, addr, handler) |
| 163 | #define STORER(reg, addr, handler) EXC(swr, ST_INSN, reg, addr, handler) |
| 164 | #define STORE(reg, addr, handler) EXC(sw, ST_INSN, reg, addr, handler) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 165 | #define ADD addu |
| 166 | #define SUB subu |
| 167 | #define SRL srl |
| 168 | #define SLL sll |
| 169 | #define SRA sra |
| 170 | #define SLLV sllv |
| 171 | #define SRLV srlv |
| 172 | #define NBYTES 4 |
| 173 | #define LOG_NBYTES 2 |
| 174 | |
| 175 | #endif /* USE_DOUBLE */ |
| 176 | |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 177 | #define LOADB(reg, addr, handler) EXC(lb, LD_INSN, reg, addr, handler) |
| 178 | #define STOREB(reg, addr, handler) EXC(sb, ST_INSN, reg, addr, handler) |
| 179 | |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 180 | #define _PREF(hint, addr, type) PREF(hint, addr) |
| 181 | |
| 182 | #define PREFS(hint, addr) _PREF(hint, addr, SRC_PREFETCH) |
| 183 | #define PREFD(hint, addr) _PREF(hint, addr, DST_PREFETCH) |
| 184 | |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 185 | #ifdef CONFIG_CPU_LITTLE_ENDIAN |
| 186 | #define LDFIRST LOADR |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 187 | #define LDREST LOADL |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 188 | #define STFIRST STORER |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 189 | #define STREST STOREL |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 190 | #define SHIFT_DISCARD SLLV |
| 191 | #else |
| 192 | #define LDFIRST LOADL |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 193 | #define LDREST LOADR |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 194 | #define STFIRST STOREL |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 195 | #define STREST STORER |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 196 | #define SHIFT_DISCARD SRLV |
| 197 | #endif |
| 198 | |
| 199 | #define FIRST(unit) ((unit)*NBYTES) |
| 200 | #define REST(unit) (FIRST(unit)+NBYTES-1) |
| 201 | #define UNIT(unit) FIRST(unit) |
| 202 | |
| 203 | #define ADDRMASK (NBYTES-1) |
| 204 | |
| 205 | .text |
| 206 | .set noreorder |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 207 | #ifndef CONFIG_CPU_DADDI_WORKAROUNDS |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 208 | .set noat |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 209 | #else |
| 210 | .set at=v1 |
| 211 | #endif |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 212 | |
| 213 | /* |
David Daney | bb0757e | 2012-06-06 23:00:31 +0100 | [diff] [blame] | 214 | * t6 is used as a flag to note inatomic mode. |
| 215 | */ |
| 216 | LEAF(__copy_user_inatomic) |
| 217 | b __copy_user_common |
| 218 | li t6, 1 |
| 219 | END(__copy_user_inatomic) |
| 220 | |
| 221 | /* |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 222 | * A combined memcpy/__copy_user |
| 223 | * __copy_user sets len to 0 for success; else to an upper bound of |
| 224 | * the number of uncopied bytes. |
| 225 | * memcpy sets v0 to dst. |
| 226 | */ |
| 227 | .align 5 |
| 228 | LEAF(memcpy) /* a0=dst a1=src a2=len */ |
| 229 | move v0, dst /* return value */ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 230 | .L__memcpy: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 231 | FEXPORT(__copy_user) |
David Daney | bb0757e | 2012-06-06 23:00:31 +0100 | [diff] [blame] | 232 | li t6, 0 /* not inatomic */ |
| 233 | __copy_user_common: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 234 | /* |
| 235 | * Note: dst & src may be unaligned, len may be 0 |
| 236 | * Temps |
| 237 | */ |
| 238 | #define rem t8 |
| 239 | |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 240 | R10KCBARRIER(0(ra)) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 241 | /* |
| 242 | * The "issue break"s below are very approximate. |
| 243 | * Issue delays for dcache fills will perturb the schedule, as will |
| 244 | * load queue full replay traps, etc. |
| 245 | * |
| 246 | * If len < NBYTES use byte operations. |
| 247 | */ |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 248 | PREFS( 0, 0(src) ) |
| 249 | PREFD( 1, 0(dst) ) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 250 | sltu t2, len, NBYTES |
| 251 | and t1, dst, ADDRMASK |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 252 | PREFS( 0, 1*32(src) ) |
| 253 | PREFD( 1, 1*32(dst) ) |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 254 | bnez t2, .Lcopy_bytes_checklen |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 255 | and t0, src, ADDRMASK |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 256 | PREFS( 0, 2*32(src) ) |
| 257 | PREFD( 1, 2*32(dst) ) |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 258 | bnez t1, .Ldst_unaligned |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 259 | nop |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 260 | bnez t0, .Lsrc_unaligned_dst_aligned |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 261 | /* |
| 262 | * use delay slot for fall-through |
| 263 | * src and dst are aligned; need to compute rem |
| 264 | */ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 265 | .Lboth_aligned: |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 266 | SRL t0, len, LOG_NBYTES+3 # +3 for 8 units/iter |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 267 | beqz t0, .Lcleanup_both_aligned # len < 8*NBYTES |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 268 | and rem, len, (8*NBYTES-1) # rem = len % (8*NBYTES) |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 269 | PREFS( 0, 3*32(src) ) |
| 270 | PREFD( 1, 3*32(dst) ) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 271 | .align 4 |
| 272 | 1: |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 273 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 274 | LOAD(t0, UNIT(0)(src), .Ll_exc) |
| 275 | LOAD(t1, UNIT(1)(src), .Ll_exc_copy) |
| 276 | LOAD(t2, UNIT(2)(src), .Ll_exc_copy) |
| 277 | LOAD(t3, UNIT(3)(src), .Ll_exc_copy) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 278 | SUB len, len, 8*NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 279 | LOAD(t4, UNIT(4)(src), .Ll_exc_copy) |
| 280 | LOAD(t7, UNIT(5)(src), .Ll_exc_copy) |
| 281 | STORE(t0, UNIT(0)(dst), .Ls_exc_p8u) |
| 282 | STORE(t1, UNIT(1)(dst), .Ls_exc_p7u) |
| 283 | LOAD(t0, UNIT(6)(src), .Ll_exc_copy) |
| 284 | LOAD(t1, UNIT(7)(src), .Ll_exc_copy) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 285 | ADD src, src, 8*NBYTES |
| 286 | ADD dst, dst, 8*NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 287 | STORE(t2, UNIT(-6)(dst), .Ls_exc_p6u) |
| 288 | STORE(t3, UNIT(-5)(dst), .Ls_exc_p5u) |
| 289 | STORE(t4, UNIT(-4)(dst), .Ls_exc_p4u) |
| 290 | STORE(t7, UNIT(-3)(dst), .Ls_exc_p3u) |
| 291 | STORE(t0, UNIT(-2)(dst), .Ls_exc_p2u) |
| 292 | STORE(t1, UNIT(-1)(dst), .Ls_exc_p1u) |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 293 | PREFS( 0, 8*32(src) ) |
| 294 | PREFD( 1, 8*32(dst) ) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 295 | bne len, rem, 1b |
| 296 | nop |
| 297 | |
| 298 | /* |
| 299 | * len == rem == the number of bytes left to copy < 8*NBYTES |
| 300 | */ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 301 | .Lcleanup_both_aligned: |
| 302 | beqz len, .Ldone |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 303 | sltu t0, len, 4*NBYTES |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 304 | bnez t0, .Lless_than_4units |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 305 | and rem, len, (NBYTES-1) # rem = len % NBYTES |
| 306 | /* |
| 307 | * len >= 4*NBYTES |
| 308 | */ |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 309 | LOAD( t0, UNIT(0)(src), .Ll_exc) |
| 310 | LOAD( t1, UNIT(1)(src), .Ll_exc_copy) |
| 311 | LOAD( t2, UNIT(2)(src), .Ll_exc_copy) |
| 312 | LOAD( t3, UNIT(3)(src), .Ll_exc_copy) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 313 | SUB len, len, 4*NBYTES |
| 314 | ADD src, src, 4*NBYTES |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 315 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 316 | STORE(t0, UNIT(0)(dst), .Ls_exc_p4u) |
| 317 | STORE(t1, UNIT(1)(dst), .Ls_exc_p3u) |
| 318 | STORE(t2, UNIT(2)(dst), .Ls_exc_p2u) |
| 319 | STORE(t3, UNIT(3)(dst), .Ls_exc_p1u) |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 320 | .set reorder /* DADDI_WAR */ |
| 321 | ADD dst, dst, 4*NBYTES |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 322 | beqz len, .Ldone |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 323 | .set noreorder |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 324 | .Lless_than_4units: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 325 | /* |
| 326 | * rem = len % NBYTES |
| 327 | */ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 328 | beq rem, len, .Lcopy_bytes |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 329 | nop |
| 330 | 1: |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 331 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 332 | LOAD(t0, 0(src), .Ll_exc) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 333 | ADD src, src, NBYTES |
| 334 | SUB len, len, NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 335 | STORE(t0, 0(dst), .Ls_exc_p1u) |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 336 | .set reorder /* DADDI_WAR */ |
| 337 | ADD dst, dst, NBYTES |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 338 | bne rem, len, 1b |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 339 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 340 | |
| 341 | /* |
| 342 | * src and dst are aligned, need to copy rem bytes (rem < NBYTES) |
| 343 | * A loop would do only a byte at a time with possible branch |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 344 | * mispredicts. Can't do an explicit LOAD dst,mask,or,STORE |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 345 | * because can't assume read-access to dst. Instead, use |
| 346 | * STREST dst, which doesn't require read access to dst. |
| 347 | * |
| 348 | * This code should perform better than a simple loop on modern, |
| 349 | * wide-issue mips processors because the code has fewer branches and |
| 350 | * more instruction-level parallelism. |
| 351 | */ |
| 352 | #define bits t2 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 353 | beqz len, .Ldone |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 354 | ADD t1, dst, len # t1 is just past last byte of dst |
| 355 | li bits, 8*NBYTES |
| 356 | SLL rem, len, 3 # rem = number of bits to keep |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 357 | LOAD(t0, 0(src), .Ll_exc) |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 358 | SUB bits, bits, rem # bits = number of bits to discard |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 359 | SHIFT_DISCARD t0, t0, bits |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 360 | STREST(t0, -1(t1), .Ls_exc) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 361 | jr ra |
| 362 | move len, zero |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 363 | .Ldst_unaligned: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 364 | /* |
| 365 | * dst is unaligned |
| 366 | * t0 = src & ADDRMASK |
| 367 | * t1 = dst & ADDRMASK; T1 > 0 |
| 368 | * len >= NBYTES |
| 369 | * |
| 370 | * Copy enough bytes to align dst |
| 371 | * Set match = (src and dst have same alignment) |
| 372 | */ |
| 373 | #define match rem |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 374 | LDFIRST(t3, FIRST(0)(src), .Ll_exc) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 375 | ADD t2, zero, NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 376 | LDREST(t3, REST(0)(src), .Ll_exc_copy) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 377 | SUB t2, t2, t1 # t2 = number of bytes copied |
| 378 | xor match, t0, t1 |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 379 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 380 | STFIRST(t3, FIRST(0)(dst), .Ls_exc) |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 381 | beq len, t2, .Ldone |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 382 | SUB len, len, t2 |
| 383 | ADD dst, dst, t2 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 384 | beqz match, .Lboth_aligned |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 385 | ADD src, src, t2 |
| 386 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 387 | .Lsrc_unaligned_dst_aligned: |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 388 | SRL t0, len, LOG_NBYTES+2 # +2 for 4 units/iter |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 389 | PREFS( 0, 3*32(src) ) |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 390 | beqz t0, .Lcleanup_src_unaligned |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 391 | and rem, len, (4*NBYTES-1) # rem = len % 4*NBYTES |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 392 | PREFD( 1, 3*32(dst) ) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 393 | 1: |
| 394 | /* |
| 395 | * Avoid consecutive LD*'s to the same register since some mips |
| 396 | * implementations can't issue them in the same cycle. |
| 397 | * It's OK to load FIRST(N+1) before REST(N) because the two addresses |
| 398 | * are to the same unit (unless src is aligned, but it's not). |
| 399 | */ |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 400 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 401 | LDFIRST(t0, FIRST(0)(src), .Ll_exc) |
| 402 | LDFIRST(t1, FIRST(1)(src), .Ll_exc_copy) |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 403 | SUB len, len, 4*NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 404 | LDREST(t0, REST(0)(src), .Ll_exc_copy) |
| 405 | LDREST(t1, REST(1)(src), .Ll_exc_copy) |
| 406 | LDFIRST(t2, FIRST(2)(src), .Ll_exc_copy) |
| 407 | LDFIRST(t3, FIRST(3)(src), .Ll_exc_copy) |
| 408 | LDREST(t2, REST(2)(src), .Ll_exc_copy) |
| 409 | LDREST(t3, REST(3)(src), .Ll_exc_copy) |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 410 | PREFS( 0, 9*32(src) ) # 0 is PREF_LOAD (not streamed) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 411 | ADD src, src, 4*NBYTES |
| 412 | #ifdef CONFIG_CPU_SB1 |
| 413 | nop # improves slotting |
| 414 | #endif |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 415 | STORE(t0, UNIT(0)(dst), .Ls_exc_p4u) |
| 416 | STORE(t1, UNIT(1)(dst), .Ls_exc_p3u) |
| 417 | STORE(t2, UNIT(2)(dst), .Ls_exc_p2u) |
| 418 | STORE(t3, UNIT(3)(dst), .Ls_exc_p1u) |
Markos Chandras | bda4d98 | 2014-01-07 15:59:03 +0000 | [diff] [blame^] | 419 | PREFD( 1, 9*32(dst) ) # 1 is PREF_STORE (not streamed) |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 420 | .set reorder /* DADDI_WAR */ |
| 421 | ADD dst, dst, 4*NBYTES |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 422 | bne len, rem, 1b |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 423 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 424 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 425 | .Lcleanup_src_unaligned: |
| 426 | beqz len, .Ldone |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 427 | and rem, len, NBYTES-1 # rem = len % NBYTES |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 428 | beq rem, len, .Lcopy_bytes |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 429 | nop |
| 430 | 1: |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 431 | R10KCBARRIER(0(ra)) |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 432 | LDFIRST(t0, FIRST(0)(src), .Ll_exc) |
| 433 | LDREST(t0, REST(0)(src), .Ll_exc_copy) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 434 | ADD src, src, NBYTES |
| 435 | SUB len, len, NBYTES |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 436 | STORE(t0, 0(dst), .Ls_exc_p1u) |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 437 | .set reorder /* DADDI_WAR */ |
| 438 | ADD dst, dst, NBYTES |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 439 | bne len, rem, 1b |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 440 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 441 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 442 | .Lcopy_bytes_checklen: |
| 443 | beqz len, .Ldone |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 444 | nop |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 445 | .Lcopy_bytes: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 446 | /* 0 < len < NBYTES */ |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 447 | R10KCBARRIER(0(ra)) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 448 | #define COPY_BYTE(N) \ |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 449 | LOADB(t0, N(src), .Ll_exc); \ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 450 | SUB len, len, 1; \ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 451 | beqz len, .Ldone; \ |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 452 | STOREB(t0, N(dst), .Ls_exc_p1) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 453 | |
| 454 | COPY_BYTE(0) |
| 455 | COPY_BYTE(1) |
| 456 | #ifdef USE_DOUBLE |
| 457 | COPY_BYTE(2) |
| 458 | COPY_BYTE(3) |
| 459 | COPY_BYTE(4) |
| 460 | COPY_BYTE(5) |
| 461 | #endif |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 462 | LOADB(t0, NBYTES-2(src), .Ll_exc) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 463 | SUB len, len, 1 |
| 464 | jr ra |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 465 | STOREB(t0, NBYTES-2(dst), .Ls_exc_p1) |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 466 | .Ldone: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 467 | jr ra |
| 468 | nop |
| 469 | END(memcpy) |
| 470 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 471 | .Ll_exc_copy: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 472 | /* |
| 473 | * Copy bytes from src until faulting load address (or until a |
| 474 | * lb faults) |
| 475 | * |
| 476 | * When reached by a faulting LDFIRST/LDREST, THREAD_BUADDR($28) |
| 477 | * may be more than a byte beyond the last address. |
| 478 | * Hence, the lb below may get an exception. |
| 479 | * |
| 480 | * Assumes src < THREAD_BUADDR($28) |
| 481 | */ |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 482 | LOADK t0, TI_TASK($28) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 483 | nop |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 484 | LOADK t0, THREAD_BUADDR(t0) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 485 | 1: |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 486 | LOADB(t1, 0(src), .Ll_exc) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 487 | ADD src, src, 1 |
| 488 | sb t1, 0(dst) # can't fault -- we're copy_from_user |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 489 | .set reorder /* DADDI_WAR */ |
| 490 | ADD dst, dst, 1 |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 491 | bne src, t0, 1b |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 492 | .set noreorder |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 493 | .Ll_exc: |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 494 | LOADK t0, TI_TASK($28) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 495 | nop |
Markos Chandras | 5bc0597 | 2014-01-07 12:57:04 +0000 | [diff] [blame] | 496 | LOADK t0, THREAD_BUADDR(t0) # t0 is just past last good address |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 497 | nop |
| 498 | SUB len, AT, t0 # len number of uncopied bytes |
David Daney | bb0757e | 2012-06-06 23:00:31 +0100 | [diff] [blame] | 499 | bnez t6, .Ldone /* Skip the zeroing part if inatomic */ |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 500 | /* |
| 501 | * Here's where we rely on src and dst being incremented in tandem, |
| 502 | * See (3) above. |
| 503 | * dst += (fault addr - src) to put dst at first byte to clear |
| 504 | */ |
| 505 | ADD dst, t0 # compute start address in a1 |
| 506 | SUB dst, src |
| 507 | /* |
| 508 | * Clear len bytes starting at dst. Can't call __bzero because it |
| 509 | * might modify len. An inefficient loop for these rare times... |
| 510 | */ |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 511 | .set reorder /* DADDI_WAR */ |
| 512 | SUB src, len, 1 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 513 | beqz len, .Ldone |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 514 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 515 | 1: sb zero, 0(dst) |
| 516 | ADD dst, dst, 1 |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 517 | #ifndef CONFIG_CPU_DADDI_WORKAROUNDS |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 518 | bnez src, 1b |
| 519 | SUB src, src, 1 |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 520 | #else |
| 521 | .set push |
| 522 | .set noat |
| 523 | li v1, 1 |
| 524 | bnez src, 1b |
| 525 | SUB src, src, v1 |
| 526 | .set pop |
| 527 | #endif |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 528 | jr ra |
| 529 | nop |
| 530 | |
| 531 | |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 532 | #define SEXC(n) \ |
Ralf Baechle | 7034228 | 2013-01-22 12:59:30 +0100 | [diff] [blame] | 533 | .set reorder; /* DADDI_WAR */ \ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 534 | .Ls_exc_p ## n ## u: \ |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 535 | ADD len, len, n*NBYTES; \ |
| 536 | jr ra; \ |
| 537 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 538 | |
| 539 | SEXC(8) |
| 540 | SEXC(7) |
| 541 | SEXC(6) |
| 542 | SEXC(5) |
| 543 | SEXC(4) |
| 544 | SEXC(3) |
| 545 | SEXC(2) |
| 546 | SEXC(1) |
| 547 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 548 | .Ls_exc_p1: |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 549 | .set reorder /* DADDI_WAR */ |
| 550 | ADD len, len, 1 |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 551 | jr ra |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 552 | .set noreorder |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 553 | .Ls_exc: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 554 | jr ra |
| 555 | nop |
| 556 | |
| 557 | .align 5 |
| 558 | LEAF(memmove) |
| 559 | ADD t0, a0, a2 |
| 560 | ADD t1, a1, a2 |
| 561 | sltu t0, a1, t0 # dst + len <= src -> memcpy |
| 562 | sltu t1, a0, t1 # dst >= src + len -> memcpy |
| 563 | and t0, t1 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 564 | beqz t0, .L__memcpy |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 565 | move v0, a0 /* return value */ |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 566 | beqz a2, .Lr_out |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 567 | END(memmove) |
| 568 | |
| 569 | /* fall through to __rmemcpy */ |
| 570 | LEAF(__rmemcpy) /* a0=dst a1=src a2=len */ |
| 571 | sltu t0, a1, a0 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 572 | beqz t0, .Lr_end_bytes_up # src >= dst |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 573 | nop |
| 574 | ADD a0, a2 # dst = dst + len |
| 575 | ADD a1, a2 # src = src + len |
| 576 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 577 | .Lr_end_bytes: |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 578 | R10KCBARRIER(0(ra)) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 579 | lb t0, -1(a1) |
| 580 | SUB a2, a2, 0x1 |
| 581 | sb t0, -1(a0) |
| 582 | SUB a1, a1, 0x1 |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 583 | .set reorder /* DADDI_WAR */ |
| 584 | SUB a0, a0, 0x1 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 585 | bnez a2, .Lr_end_bytes |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 586 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 587 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 588 | .Lr_out: |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 589 | jr ra |
| 590 | move a2, zero |
| 591 | |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 592 | .Lr_end_bytes_up: |
Thomas Bogendoerfer | 930bff8 | 2007-11-25 11:47:56 +0100 | [diff] [blame] | 593 | R10KCBARRIER(0(ra)) |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 594 | lb t0, (a1) |
| 595 | SUB a2, a2, 0x1 |
| 596 | sb t0, (a0) |
| 597 | ADD a1, a1, 0x1 |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 598 | .set reorder /* DADDI_WAR */ |
| 599 | ADD a0, a0, 0x1 |
Ralf Baechle | c5ec198 | 2008-01-29 10:14:59 +0000 | [diff] [blame] | 600 | bnez a2, .Lr_end_bytes_up |
Maciej W. Rozycki | 619b6e1 | 2007-10-23 12:43:25 +0100 | [diff] [blame] | 601 | .set noreorder |
Linus Torvalds | 1da177e | 2005-04-16 15:20:36 -0700 | [diff] [blame] | 602 | |
| 603 | jr ra |
| 604 | move a2, zero |
| 605 | END(__rmemcpy) |