build.gradle

buildscript {
  repositories {
    mavenCentral()
  }
  dependencies {
    classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.1"
  }
}

plugins {
  id 'net.saliman.cobertura' version '2.3.1'
  id 'com.github.kt3k.coveralls' version '2.6.3'
}

apply plugin: 'io.codearte.nexus-staging'
apply plugin: 'maven'
apply plugin: 'idea'

allprojects  {
  apply plugin: 'java'
  apply plugin: 'idea'
  apply plugin: 'jacoco'

  group = 'com.github.javaparser'
  version = '0.4-SNAPSHOT'

  repositories {
    mavenCentral()
    
    maven { url "http://repo.maven.apache.org/maven2" }
  }

  jacoco {
    toolVersion = "0.7.6.201602180812"
    reportsDir = file("$buildDir/test_coverage")
  }

  jacocoTestReport {
    reports {
        xml.enabled true
        csv.enabled false
        html.destination "${buildDir}/jacocoHtml"
    }
  }  
}

subprojects {
  apply plugin: 'java'
  sourceCompatibility = 1.8
  targetCompatibility = 1.8

  
  repositories {
    mavenCentral()
    
    maven { url "http://repo.maven.apache.org/maven2" }
  }

}


if (project.hasProperty('release')) {

  subprojects {

    task javadocJar(type: Jar) {
      classifier = 'javadoc'
      from javadoc
    }

    task sourcesJar(type: Jar) {
      classifier = 'sources'
      from sourceSets.main.allSource
    }

    artifacts {
      archives javadocJar, sourcesJar
    }
  }

  allprojects {
    apply plugin: 'signing'
    apply plugin: 'maven'

    // Signature of artifacts
    signing {
      sign configurations.archives
    }

    if (JavaVersion.current().isJava8Compatible()) {
      allprojects {
        tasks.withType(Javadoc) {
          options.addStringOption('Xdoclint:none', '-quiet')
        }
      }
    }

    // OSSRH publication
    uploadArchives {
      repositories {
        mavenDeployer {
          // POM signature
          beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
          // Target repository
          repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
            authentication(userName: ossrhUsername, password: ossrhPassword)
          }
          pom.project {
            name project.name
            description project.description
            packaging 'jar'
            url 'https://github.com/javaparser/java-symbol-solver'

            scm {
              connection 'scm:git:https://github.com/javaparser/java-symbol-solver.git'
              developerConnection 'scm:git:git@github.com:javaparser/java-symbol-solver.git'
              url 'https://github.com/ftomassetti/java-symbol-solver.git'
            }

            licenses {
              license {
                name 'The MIT License (MIT)'
                url 'http://opensource.org/licenses/MIT'
                distribution 'repo'
              }
            }

            developers {
              developer {
                id = 'ftomassetti'
                name = 'Federico Tomassetti'
                email = 'federico@tomassetti.me'
              }
            }
          }
        }
      }
    }

  }
}

def v_ossrhUsername="FOO"
def v_ossrhPassword="FOO"

if (project.hasProperty("ossrhUsername")) {
  v_ossrhUsername = ossrhUsername
}
if (project.hasProperty("ossrhPassword")) {
  v_ossrhPassword = ossrhPassword
}

nexusStaging {
  username = v_ossrhUsername
  password = v_ossrhPassword
}

test {
  testLogging {
    exceptionFormat = 'full'
  }
}