Gitiles
Code Review Sign In
gerrit-public.fairphone.software / platform / external / libjpeg-turbo / 5eb84ff97f00c02aadfdce0cb30ab3e899c1b113 / . / simd / jdmermmx.asm
blob: 8d82e40a06a3ba11349d67de2fd8e95372577d1d [file] [log] [blame]
Pierre Ossman5eb84ff2009-03-09 13:25:30 +0000[diff] [blame^]1;
2; jdmermmx.asm - merged upsampling/color conversion (MMX)
3;
4; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
5;
6; Based on
7; x86 SIMD extension for IJG JPEG library
8; Copyright (C) 1999-2006, MIYASAKA Masaru.
9; For conditions of distribution and use, see copyright notice in jsimdext.inc
10;
11; This file should be assembled with NASM (Netwide Assembler),
12; can *not* be assembled with Microsoft's MASM or any compatible
13; assembler (including Borland's Turbo Assembler).
14; NASM is available from http://nasm.sourceforge.net/ or
15; http://sourceforge.net/project/showfiles.php?group_id=6208
16;
17; [TAB8]
18
19%include "simd/jsimdext.inc"
20%include "simd/jcolsamp.inc"
21
22; --------------------------------------------------------------------------
23
24%define SCALEBITS 16
25
26F_0_344 equ 22554 ; FIX(0.34414)
27F_0_714 equ 46802 ; FIX(0.71414)
28F_1_402 equ 91881 ; FIX(1.40200)
29F_1_772 equ 116130 ; FIX(1.77200)
30F_0_402 equ (F_1_402 - 65536) ; FIX(1.40200) - FIX(1)
31F_0_285 equ ( 65536 - F_0_714) ; FIX(1) - FIX(0.71414)
32F_0_228 equ (131072 - F_1_772) ; FIX(2) - FIX(1.77200)
33
34; --------------------------------------------------------------------------
35 SECTION SEG_CONST
36
37 alignz 16
38 global EXTN(jconst_merged_upsample_mmx)
39
40EXTN(jconst_merged_upsample_mmx):
41
42PW_F0402 times 4 dw F_0_402
43PW_MF0228 times 4 dw -F_0_228
44PW_MF0344_F0285 times 2 dw -F_0_344, F_0_285
45PW_ONE times 4 dw 1
46PD_ONEHALF times 2 dd 1 << (SCALEBITS-1)
47
48 alignz 16
49
50; --------------------------------------------------------------------------
51 SECTION SEG_TEXT
52 BITS 32
53;
54; Upsample and color convert for the case of 2:1 horizontal and 1:1 vertical.
55;
56; GLOBAL(void)
57; jsimd_h2v1_merged_upsample_mmx (JDIMENSION output_width,
58; JSAMPIMAGE input_buf,
59; JDIMENSION in_row_group_ctr,
60; JSAMPARRAY output_buf);
61;
62
63%define output_width(b) (b)+8 ; JDIMENSION output_width
64%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
65%define in_row_group_ctr(b) (b)+16 ; JDIMENSION in_row_group_ctr
66%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
67
68%define original_ebp ebp+0
69%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
70%define WK_NUM 3
71%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
72
73 align 16
74 global EXTN(jsimd_h2v1_merged_upsample_mmx)
75
76EXTN(jsimd_h2v1_merged_upsample_mmx):
77 push ebp
78 mov eax,esp ; eax = original ebp
79 sub esp, byte 4
80 and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
81 mov [esp],eax
82 mov ebp,esp ; ebp = aligned ebp
83 lea esp, [wk(0)]
84 pushpic eax ; make a room for GOT address
85 push ebx
86; push ecx ; need not be preserved
87; push edx ; need not be preserved
88 push esi
89 push edi
90
91 get_GOT ebx ; get GOT address
92 movpic POINTER [gotptr], ebx ; save GOT address
93
94 mov ecx, JDIMENSION [output_width(eax)] ; col
95 test ecx,ecx
96 jz near .return
97
98 push ecx
99
100 mov edi, JSAMPIMAGE [input_buf(eax)]
101 mov ecx, JDIMENSION [in_row_group_ctr(eax)]
102 mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
103 mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
104 mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
105 mov edi, JSAMPARRAY [output_buf(eax)]
106 mov esi, JSAMPROW [esi+ecx*SIZEOF_JSAMPROW] ; inptr0
107 mov ebx, JSAMPROW [ebx+ecx*SIZEOF_JSAMPROW] ; inptr1
108 mov edx, JSAMPROW [edx+ecx*SIZEOF_JSAMPROW] ; inptr2
109 mov edi, JSAMPROW [edi] ; outptr
110
111 pop ecx ; col
112
113 alignx 16,7
114.columnloop:
115 movpic eax, POINTER [gotptr] ; load GOT address (eax)
116
117 movq mm6, MMWORD [ebx] ; mm6=Cb(01234567)
118 movq mm7, MMWORD [edx] ; mm7=Cr(01234567)
119
120 pxor mm1,mm1 ; mm1=(all 0's)
121 pcmpeqw mm3,mm3
122 psllw mm3,7 ; mm3={0xFF80 0xFF80 0xFF80 0xFF80}
123
124 movq mm4,mm6
125 punpckhbw mm6,mm1 ; mm6=Cb(4567)=CbH
126 punpcklbw mm4,mm1 ; mm4=Cb(0123)=CbL
127 movq mm0,mm7
128 punpckhbw mm7,mm1 ; mm7=Cr(4567)=CrH
129 punpcklbw mm0,mm1 ; mm0=Cr(0123)=CrL
130
131 paddw mm6,mm3
132 paddw mm4,mm3
133 paddw mm7,mm3
134 paddw mm0,mm3
135
136 ; (Original)
137 ; R = Y + 1.40200 * Cr
138 ; G = Y - 0.34414 * Cb - 0.71414 * Cr
139 ; B = Y + 1.77200 * Cb
140 ;
141 ; (This implementation)
142 ; R = Y + 0.40200 * Cr + Cr
143 ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
144 ; B = Y - 0.22800 * Cb + Cb + Cb
145
146 movq mm5,mm6 ; mm5=CbH
147 movq mm2,mm4 ; mm2=CbL
148 paddw mm6,mm6 ; mm6=2*CbH
149 paddw mm4,mm4 ; mm4=2*CbL
150 movq mm1,mm7 ; mm1=CrH
151 movq mm3,mm0 ; mm3=CrL
152 paddw mm7,mm7 ; mm7=2*CrH
153 paddw mm0,mm0 ; mm0=2*CrL
154
155 pmulhw mm6,[GOTOFF(eax,PW_MF0228)] ; mm6=(2*CbH * -FIX(0.22800))
156 pmulhw mm4,[GOTOFF(eax,PW_MF0228)] ; mm4=(2*CbL * -FIX(0.22800))
157 pmulhw mm7,[GOTOFF(eax,PW_F0402)] ; mm7=(2*CrH * FIX(0.40200))
158 pmulhw mm0,[GOTOFF(eax,PW_F0402)] ; mm0=(2*CrL * FIX(0.40200))
159
160 paddw mm6,[GOTOFF(eax,PW_ONE)]
161 paddw mm4,[GOTOFF(eax,PW_ONE)]
162 psraw mm6,1 ; mm6=(CbH * -FIX(0.22800))
163 psraw mm4,1 ; mm4=(CbL * -FIX(0.22800))
164 paddw mm7,[GOTOFF(eax,PW_ONE)]
165 paddw mm0,[GOTOFF(eax,PW_ONE)]
166 psraw mm7,1 ; mm7=(CrH * FIX(0.40200))
167 psraw mm0,1 ; mm0=(CrL * FIX(0.40200))
168
169 paddw mm6,mm5
170 paddw mm4,mm2
171 paddw mm6,mm5 ; mm6=(CbH * FIX(1.77200))=(B-Y)H
172 paddw mm4,mm2 ; mm4=(CbL * FIX(1.77200))=(B-Y)L
173 paddw mm7,mm1 ; mm7=(CrH * FIX(1.40200))=(R-Y)H
174 paddw mm0,mm3 ; mm0=(CrL * FIX(1.40200))=(R-Y)L
175
176 movq MMWORD [wk(0)], mm6 ; wk(0)=(B-Y)H
177 movq MMWORD [wk(1)], mm7 ; wk(1)=(R-Y)H
178
179 movq mm6,mm5
180 movq mm7,mm2
181 punpcklwd mm5,mm1
182 punpckhwd mm6,mm1
183 pmaddwd mm5,[GOTOFF(eax,PW_MF0344_F0285)]
184 pmaddwd mm6,[GOTOFF(eax,PW_MF0344_F0285)]
185 punpcklwd mm2,mm3
186 punpckhwd mm7,mm3
187 pmaddwd mm2,[GOTOFF(eax,PW_MF0344_F0285)]
188 pmaddwd mm7,[GOTOFF(eax,PW_MF0344_F0285)]
189
190 paddd mm5,[GOTOFF(eax,PD_ONEHALF)]
191 paddd mm6,[GOTOFF(eax,PD_ONEHALF)]
192 psrad mm5,SCALEBITS
193 psrad mm6,SCALEBITS
194 paddd mm2,[GOTOFF(eax,PD_ONEHALF)]
195 paddd mm7,[GOTOFF(eax,PD_ONEHALF)]
196 psrad mm2,SCALEBITS
197 psrad mm7,SCALEBITS
198
199 packssdw mm5,mm6 ; mm5=CbH*-FIX(0.344)+CrH*FIX(0.285)
200 packssdw mm2,mm7 ; mm2=CbL*-FIX(0.344)+CrL*FIX(0.285)
201 psubw mm5,mm1 ; mm5=CbH*-FIX(0.344)+CrH*-FIX(0.714)=(G-Y)H
202 psubw mm2,mm3 ; mm2=CbL*-FIX(0.344)+CrL*-FIX(0.714)=(G-Y)L
203
204 movq MMWORD [wk(2)], mm5 ; wk(2)=(G-Y)H
205
206 mov al,2 ; Yctr
207 jmp short .Yloop_1st
208 alignx 16,7
209
210.Yloop_2nd:
211 movq mm0, MMWORD [wk(1)] ; mm0=(R-Y)H
212 movq mm2, MMWORD [wk(2)] ; mm2=(G-Y)H
213 movq mm4, MMWORD [wk(0)] ; mm4=(B-Y)H
214 alignx 16,7
215
216.Yloop_1st:
217 movq mm7, MMWORD [esi] ; mm7=Y(01234567)
218
219 pcmpeqw mm6,mm6
220 psrlw mm6,BYTE_BIT ; mm6={0xFF 0x00 0xFF 0x00 ..}
221 pand mm6,mm7 ; mm6=Y(0246)=YE
222 psrlw mm7,BYTE_BIT ; mm7=Y(1357)=YO
223
224 movq mm1,mm0 ; mm1=mm0=(R-Y)(L/H)
225 movq mm3,mm2 ; mm3=mm2=(G-Y)(L/H)
226 movq mm5,mm4 ; mm5=mm4=(B-Y)(L/H)
227
228 paddw mm0,mm6 ; mm0=((R-Y)+YE)=RE=(R0 R2 R4 R6)
229 paddw mm1,mm7 ; mm1=((R-Y)+YO)=RO=(R1 R3 R5 R7)
230 packuswb mm0,mm0 ; mm0=(R0 R2 R4 R6 ** ** ** **)
231 packuswb mm1,mm1 ; mm1=(R1 R3 R5 R7 ** ** ** **)
232
233 paddw mm2,mm6 ; mm2=((G-Y)+YE)=GE=(G0 G2 G4 G6)
234 paddw mm3,mm7 ; mm3=((G-Y)+YO)=GO=(G1 G3 G5 G7)
235 packuswb mm2,mm2 ; mm2=(G0 G2 G4 G6 ** ** ** **)
236 packuswb mm3,mm3 ; mm3=(G1 G3 G5 G7 ** ** ** **)
237
238 paddw mm4,mm6 ; mm4=((B-Y)+YE)=BE=(B0 B2 B4 B6)
239 paddw mm5,mm7 ; mm5=((B-Y)+YO)=BO=(B1 B3 B5 B7)
240 packuswb mm4,mm4 ; mm4=(B0 B2 B4 B6 ** ** ** **)
241 packuswb mm5,mm5 ; mm5=(B1 B3 B5 B7 ** ** ** **)
242
243%if RGB_PIXELSIZE == 3 ; ---------------
244
245 ; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
246 ; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
247 ; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
248 ; mmG=(** ** ** ** ** ** ** **), mmH=(** ** ** ** ** ** ** **)
249
250 punpcklbw mmA,mmC ; mmA=(00 10 02 12 04 14 06 16)
251 punpcklbw mmE,mmB ; mmE=(20 01 22 03 24 05 26 07)
252 punpcklbw mmD,mmF ; mmD=(11 21 13 23 15 25 17 27)
253
254 movq mmG,mmA
255 movq mmH,mmA
256 punpcklwd mmA,mmE ; mmA=(00 10 20 01 02 12 22 03)
257 punpckhwd mmG,mmE ; mmG=(04 14 24 05 06 16 26 07)
258
259 psrlq mmH,2*BYTE_BIT ; mmH=(02 12 04 14 06 16 -- --)
260 psrlq mmE,2*BYTE_BIT ; mmE=(22 03 24 05 26 07 -- --)
261
262 movq mmC,mmD
263 movq mmB,mmD
264 punpcklwd mmD,mmH ; mmD=(11 21 02 12 13 23 04 14)
265 punpckhwd mmC,mmH ; mmC=(15 25 06 16 17 27 -- --)
266
267 psrlq mmB,2*BYTE_BIT ; mmB=(13 23 15 25 17 27 -- --)
268
269 movq mmF,mmE
270 punpcklwd mmE,mmB ; mmE=(22 03 13 23 24 05 15 25)
271 punpckhwd mmF,mmB ; mmF=(26 07 17 27 -- -- -- --)
272
273 punpckldq mmA,mmD ; mmA=(00 10 20 01 11 21 02 12)
274 punpckldq mmE,mmG ; mmE=(22 03 13 23 04 14 24 05)
275 punpckldq mmC,mmF ; mmC=(15 25 06 16 26 07 17 27)
276
277 cmp ecx, byte SIZEOF_MMWORD
278 jb short .column_st16
279
280 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
281 movq MMWORD [edi+1*SIZEOF_MMWORD], mmE
282 movq MMWORD [edi+2*SIZEOF_MMWORD], mmC
283
284 sub ecx, byte SIZEOF_MMWORD
285 jz short .endcolumn
286
287 add edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD ; outptr
288 add esi, byte SIZEOF_MMWORD ; inptr0
289 dec al ; Yctr
290 jnz near .Yloop_2nd
291
292 add ebx, byte SIZEOF_MMWORD ; inptr1
293 add edx, byte SIZEOF_MMWORD ; inptr2
294 jmp near .columnloop
295 alignx 16,7
296
297.column_st16:
298 lea ecx, [ecx+ecx*2] ; imul ecx, RGB_PIXELSIZE
299 cmp ecx, byte 2*SIZEOF_MMWORD
300 jb short .column_st8
301 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
302 movq MMWORD [edi+1*SIZEOF_MMWORD], mmE
303 movq mmA,mmC
304 sub ecx, byte 2*SIZEOF_MMWORD
305 add edi, byte 2*SIZEOF_MMWORD
306 jmp short .column_st4
307.column_st8:
308 cmp ecx, byte SIZEOF_MMWORD
309 jb short .column_st4
310 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
311 movq mmA,mmE
312 sub ecx, byte SIZEOF_MMWORD
313 add edi, byte SIZEOF_MMWORD
314.column_st4:
315 movd eax,mmA
316 cmp ecx, byte SIZEOF_DWORD
317 jb short .column_st2
318 mov DWORD [edi+0*SIZEOF_DWORD], eax
319 psrlq mmA,DWORD_BIT
320 movd eax,mmA
321 sub ecx, byte SIZEOF_DWORD
322 add edi, byte SIZEOF_DWORD
323.column_st2:
324 cmp ecx, byte SIZEOF_WORD
325 jb short .column_st1
326 mov WORD [edi+0*SIZEOF_WORD], ax
327 shr eax,WORD_BIT
328 sub ecx, byte SIZEOF_WORD
329 add edi, byte SIZEOF_WORD
330.column_st1:
331 cmp ecx, byte SIZEOF_BYTE
332 jb short .endcolumn
333 mov BYTE [edi+0*SIZEOF_BYTE], al
334
335%else ; RGB_PIXELSIZE == 4 ; -----------
336
337%ifdef RGBX_FILLER_0XFF
338 pcmpeqb mm6,mm6 ; mm6=(X0 X2 X4 X6 ** ** ** **)
339 pcmpeqb mm7,mm7 ; mm7=(X1 X3 X5 X7 ** ** ** **)
340%else
341 pxor mm6,mm6 ; mm6=(X0 X2 X4 X6 ** ** ** **)
342 pxor mm7,mm7 ; mm7=(X1 X3 X5 X7 ** ** ** **)
343%endif
344 ; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
345 ; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
346 ; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
347 ; mmG=(30 32 34 36 ** ** ** **), mmH=(31 33 35 37 ** ** ** **)
348
349 punpcklbw mmA,mmC ; mmA=(00 10 02 12 04 14 06 16)
350 punpcklbw mmE,mmG ; mmE=(20 30 22 32 24 34 26 36)
351 punpcklbw mmB,mmD ; mmB=(01 11 03 13 05 15 07 17)
352 punpcklbw mmF,mmH ; mmF=(21 31 23 33 25 35 27 37)
353
354 movq mmC,mmA
355 punpcklwd mmA,mmE ; mmA=(00 10 20 30 02 12 22 32)
356 punpckhwd mmC,mmE ; mmC=(04 14 24 34 06 16 26 36)
357 movq mmG,mmB
358 punpcklwd mmB,mmF ; mmB=(01 11 21 31 03 13 23 33)
359 punpckhwd mmG,mmF ; mmG=(05 15 25 35 07 17 27 37)
360
361 movq mmD,mmA
362 punpckldq mmA,mmB ; mmA=(00 10 20 30 01 11 21 31)
363 punpckhdq mmD,mmB ; mmD=(02 12 22 32 03 13 23 33)
364 movq mmH,mmC
365 punpckldq mmC,mmG ; mmC=(04 14 24 34 05 15 25 35)
366 punpckhdq mmH,mmG ; mmH=(06 16 26 36 07 17 27 37)
367
368 cmp ecx, byte SIZEOF_MMWORD
369 jb short .column_st16
370
371 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
372 movq MMWORD [edi+1*SIZEOF_MMWORD], mmD
373 movq MMWORD [edi+2*SIZEOF_MMWORD], mmC
374 movq MMWORD [edi+3*SIZEOF_MMWORD], mmH
375
376 sub ecx, byte SIZEOF_MMWORD
377 jz short .endcolumn
378
379 add edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD ; outptr
380 add esi, byte SIZEOF_MMWORD ; inptr0
381 dec al ; Yctr
382 jnz near .Yloop_2nd
383
384 add ebx, byte SIZEOF_MMWORD ; inptr1
385 add edx, byte SIZEOF_MMWORD ; inptr2
386 jmp near .columnloop
387 alignx 16,7
388
389.column_st16:
390 cmp ecx, byte SIZEOF_MMWORD/2
391 jb short .column_st8
392 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
393 movq MMWORD [edi+1*SIZEOF_MMWORD], mmD
394 movq mmA,mmC
395 movq mmD,mmH
396 sub ecx, byte SIZEOF_MMWORD/2
397 add edi, byte 2*SIZEOF_MMWORD
398.column_st8:
399 cmp ecx, byte SIZEOF_MMWORD/4
400 jb short .column_st4
401 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
402 movq mmA,mmD
403 sub ecx, byte SIZEOF_MMWORD/4
404 add edi, byte 1*SIZEOF_MMWORD
405.column_st4:
406 cmp ecx, byte SIZEOF_MMWORD/8
407 jb short .endcolumn
408 movd DWORD [edi+0*SIZEOF_DWORD], mmA
409
410%endif ; RGB_PIXELSIZE ; ---------------
411
412.endcolumn:
413 emms ; empty MMX state
414
415.return:
416 pop edi
417 pop esi
418; pop edx ; need not be preserved
419; pop ecx ; need not be preserved
420 pop ebx
421 mov esp,ebp ; esp <- aligned ebp
422 pop esp ; esp <- original ebp
423 pop ebp
424 ret
425
426; --------------------------------------------------------------------------
427;
428; Upsample and color convert for the case of 2:1 horizontal and 2:1 vertical.
429;
430; GLOBAL(void)
431; jsimd_h2v2_merged_upsample_mmx (JDIMENSION output_width,
432; JSAMPIMAGE input_buf,
433; JDIMENSION in_row_group_ctr,
434; JSAMPARRAY output_buf);
435;
436
437%define output_width(b) (b)+8 ; JDIMENSION output_width
438%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
439%define in_row_group_ctr(b) (b)+16 ; JDIMENSION in_row_group_ctr
440%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
441
442 align 16
443 global EXTN(jsimd_h2v2_merged_upsample_mmx)
444
445EXTN(jsimd_h2v2_merged_upsample_mmx):
446 push ebp
447 mov ebp,esp
448 push ebx
449; push ecx ; need not be preserved
450; push edx ; need not be preserved
451 push esi
452 push edi
453
454 mov eax, JDIMENSION [output_width(ebp)]
455
456 mov edi, JSAMPIMAGE [input_buf(ebp)]
457 mov ecx, JDIMENSION [in_row_group_ctr(ebp)]
458 mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
459 mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
460 mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
461 mov edi, JSAMPARRAY [output_buf(ebp)]
462 lea esi, [esi+ecx*SIZEOF_JSAMPROW]
463
464 push edx ; inptr2
465 push ebx ; inptr1
466 push esi ; inptr00
467 mov ebx,esp
468
469 push edi ; output_buf (outptr0)
470 push ecx ; in_row_group_ctr
471 push ebx ; input_buf
472 push eax ; output_width
473
474 call near EXTN(jsimd_h2v1_merged_upsample_mmx)
475
476 add esi, byte SIZEOF_JSAMPROW ; inptr01
477 add edi, byte SIZEOF_JSAMPROW ; outptr1
478 mov POINTER [ebx+0*SIZEOF_POINTER], esi
479 mov POINTER [ebx-1*SIZEOF_POINTER], edi
480
481 call near EXTN(jsimd_h2v1_merged_upsample_mmx)
482
483 add esp, byte 7*SIZEOF_DWORD
484
485 pop edi
486 pop esi
487; pop edx ; need not be preserved
488; pop ecx ; need not be preserved
489 pop ebx
490 pop ebp
491 ret
492