MIYASAKA Masaru | a2e6a9d | 2006-02-04 00:00:00 +0000 | [diff] [blame^] | 1 | ; |
| 2 | ; jisseflt.asm - floating-point IDCT (SSE & MMX) |
| 3 | ; |
| 4 | ; x86 SIMD extension for IJG JPEG library |
| 5 | ; Copyright (C) 1999-2006, MIYASAKA Masaru. |
| 6 | ; For conditions of distribution and use, see copyright notice in jsimdext.inc |
| 7 | ; |
| 8 | ; This file should be assembled with NASM (Netwide Assembler), |
| 9 | ; can *not* be assembled with Microsoft's MASM or any compatible |
| 10 | ; assembler (including Borland's Turbo Assembler). |
| 11 | ; NASM is available from http://nasm.sourceforge.net/ or |
| 12 | ; http://sourceforge.net/project/showfiles.php?group_id=6208 |
| 13 | ; |
| 14 | ; This file contains a floating-point implementation of the inverse DCT |
| 15 | ; (Discrete Cosine Transform). The following code is based directly on |
| 16 | ; the IJG's original jidctflt.c; see the jidctflt.c for more details. |
| 17 | ; |
| 18 | ; Last Modified : February 4, 2006 |
| 19 | ; |
| 20 | ; [TAB8] |
| 21 | |
| 22 | %include "jsimdext.inc" |
| 23 | %include "jdct.inc" |
| 24 | |
| 25 | %ifdef DCT_FLOAT_SUPPORTED |
| 26 | %ifdef JIDCT_FLT_SSE_MMX_SUPPORTED |
| 27 | |
| 28 | ; This module is specialized to the case DCTSIZE = 8. |
| 29 | ; |
| 30 | %if DCTSIZE != 8 |
| 31 | %error "Sorry, this code only copes with 8x8 DCTs." |
| 32 | %endif |
| 33 | |
| 34 | ; -------------------------------------------------------------------------- |
| 35 | |
| 36 | %macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5) |
| 37 | shufps %1,%2,0x44 |
| 38 | %endmacro |
| 39 | |
| 40 | %macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7) |
| 41 | shufps %1,%2,0xEE |
| 42 | %endmacro |
| 43 | |
| 44 | ; -------------------------------------------------------------------------- |
| 45 | SECTION SEG_CONST |
| 46 | |
| 47 | alignz 16 |
| 48 | global EXTN(jconst_idct_float_sse) |
| 49 | |
| 50 | EXTN(jconst_idct_float_sse): |
| 51 | |
| 52 | PD_1_414 times 4 dd 1.414213562373095048801689 |
| 53 | PD_1_847 times 4 dd 1.847759065022573512256366 |
| 54 | PD_1_082 times 4 dd 1.082392200292393968799446 |
| 55 | PD_M2_613 times 4 dd -2.613125929752753055713286 |
| 56 | PD_0_125 times 4 dd 0.125 ; 1/8 |
| 57 | PB_CENTERJSAMP times 8 db CENTERJSAMPLE |
| 58 | |
| 59 | alignz 16 |
| 60 | |
| 61 | ; -------------------------------------------------------------------------- |
| 62 | SECTION SEG_TEXT |
| 63 | BITS 32 |
| 64 | ; |
| 65 | ; Perform dequantization and inverse DCT on one block of coefficients. |
| 66 | ; |
| 67 | ; GLOBAL(void) |
| 68 | ; jpeg_idct_float_sse (j_decompress_ptr cinfo, jpeg_component_info * compptr, |
| 69 | ; JCOEFPTR coef_block, |
| 70 | ; JSAMPARRAY output_buf, JDIMENSION output_col) |
| 71 | ; |
| 72 | |
| 73 | %define cinfo(b) (b)+8 ; j_decompress_ptr cinfo |
| 74 | %define compptr(b) (b)+12 ; jpeg_component_info * compptr |
| 75 | %define coef_block(b) (b)+16 ; JCOEFPTR coef_block |
| 76 | %define output_buf(b) (b)+20 ; JSAMPARRAY output_buf |
| 77 | %define output_col(b) (b)+24 ; JDIMENSION output_col |
| 78 | |
| 79 | %define original_ebp ebp+0 |
| 80 | %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM] |
| 81 | %define WK_NUM 2 |
| 82 | %define workspace wk(0)-DCTSIZE2*SIZEOF_FAST_FLOAT |
| 83 | ; FAST_FLOAT workspace[DCTSIZE2] |
| 84 | |
| 85 | align 16 |
| 86 | global EXTN(jpeg_idct_float_sse) |
| 87 | |
| 88 | EXTN(jpeg_idct_float_sse): |
| 89 | push ebp |
| 90 | mov eax,esp ; eax = original ebp |
| 91 | sub esp, byte 4 |
| 92 | and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits |
| 93 | mov [esp],eax |
| 94 | mov ebp,esp ; ebp = aligned ebp |
| 95 | lea esp, [workspace] |
| 96 | push ebx |
| 97 | ; push ecx ; need not be preserved |
| 98 | ; push edx ; need not be preserved |
| 99 | push esi |
| 100 | push edi |
| 101 | |
| 102 | get_GOT ebx ; get GOT address |
| 103 | |
| 104 | ; ---- Pass 1: process columns from input, store into work array. |
| 105 | |
| 106 | ; mov eax, [original_ebp] |
| 107 | mov edx, POINTER [compptr(eax)] |
| 108 | mov edx, POINTER [jcompinfo_dct_table(edx)] ; quantptr |
| 109 | mov esi, JCOEFPTR [coef_block(eax)] ; inptr |
| 110 | lea edi, [workspace] ; FAST_FLOAT * wsptr |
| 111 | mov ecx, DCTSIZE/4 ; ctr |
| 112 | alignx 16,7 |
| 113 | .columnloop: |
| 114 | %ifndef NO_ZERO_COLUMN_TEST_FLOAT_SSE |
| 115 | mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 116 | or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 117 | jnz near .columnDCT |
| 118 | |
| 119 | movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 120 | movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 121 | por mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)] |
| 122 | por mm1, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)] |
| 123 | por mm0, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)] |
| 124 | por mm1, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)] |
| 125 | por mm0, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)] |
| 126 | por mm1,mm0 |
| 127 | packsswb mm1,mm1 |
| 128 | movd eax,mm1 |
| 129 | test eax,eax |
| 130 | jnz short .columnDCT |
| 131 | |
| 132 | ; -- AC terms all zero |
| 133 | |
| 134 | movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)] |
| 135 | |
| 136 | punpckhwd mm1,mm0 ; mm1=(** 02 ** 03) |
| 137 | punpcklwd mm0,mm0 ; mm0=(00 00 01 01) |
| 138 | psrad mm1,(DWORD_BIT-WORD_BIT) ; mm1=in0H=(02 03) |
| 139 | psrad mm0,(DWORD_BIT-WORD_BIT) ; mm0=in0L=(00 01) |
| 140 | cvtpi2ps xmm3,mm1 ; xmm3=(02 03 ** **) |
| 141 | cvtpi2ps xmm0,mm0 ; xmm0=(00 01 ** **) |
| 142 | movlhps xmm0,xmm3 ; xmm0=in0=(00 01 02 03) |
| 143 | |
| 144 | mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 145 | |
| 146 | movaps xmm1,xmm0 |
| 147 | movaps xmm2,xmm0 |
| 148 | movaps xmm3,xmm0 |
| 149 | |
| 150 | shufps xmm0,xmm0,0x00 ; xmm0=(00 00 00 00) |
| 151 | shufps xmm1,xmm1,0x55 ; xmm1=(01 01 01 01) |
| 152 | shufps xmm2,xmm2,0xAA ; xmm2=(02 02 02 02) |
| 153 | shufps xmm3,xmm3,0xFF ; xmm3=(03 03 03 03) |
| 154 | |
| 155 | movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm0 |
| 156 | movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm0 |
| 157 | movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm1 |
| 158 | movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm1 |
| 159 | movaps XMMWORD [XMMBLOCK(2,0,edi,SIZEOF_FAST_FLOAT)], xmm2 |
| 160 | movaps XMMWORD [XMMBLOCK(2,1,edi,SIZEOF_FAST_FLOAT)], xmm2 |
| 161 | movaps XMMWORD [XMMBLOCK(3,0,edi,SIZEOF_FAST_FLOAT)], xmm3 |
| 162 | movaps XMMWORD [XMMBLOCK(3,1,edi,SIZEOF_FAST_FLOAT)], xmm3 |
| 163 | jmp near .nextcolumn |
| 164 | alignx 16,7 |
| 165 | %endif |
| 166 | .columnDCT: |
| 167 | |
| 168 | ; -- Even part |
| 169 | |
| 170 | movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)] |
| 171 | movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 172 | movq mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)] |
| 173 | movq mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)] |
| 174 | |
| 175 | punpckhwd mm4,mm0 ; mm4=(** 02 ** 03) |
| 176 | punpcklwd mm0,mm0 ; mm0=(00 00 01 01) |
| 177 | punpckhwd mm5,mm1 ; mm5=(** 22 ** 23) |
| 178 | punpcklwd mm1,mm1 ; mm1=(20 20 21 21) |
| 179 | |
| 180 | psrad mm4,(DWORD_BIT-WORD_BIT) ; mm4=in0H=(02 03) |
| 181 | psrad mm0,(DWORD_BIT-WORD_BIT) ; mm0=in0L=(00 01) |
| 182 | cvtpi2ps xmm4,mm4 ; xmm4=(02 03 ** **) |
| 183 | cvtpi2ps xmm0,mm0 ; xmm0=(00 01 ** **) |
| 184 | psrad mm5,(DWORD_BIT-WORD_BIT) ; mm5=in2H=(22 23) |
| 185 | psrad mm1,(DWORD_BIT-WORD_BIT) ; mm1=in2L=(20 21) |
| 186 | cvtpi2ps xmm5,mm5 ; xmm5=(22 23 ** **) |
| 187 | cvtpi2ps xmm1,mm1 ; xmm1=(20 21 ** **) |
| 188 | |
| 189 | punpckhwd mm6,mm2 ; mm6=(** 42 ** 43) |
| 190 | punpcklwd mm2,mm2 ; mm2=(40 40 41 41) |
| 191 | punpckhwd mm7,mm3 ; mm7=(** 62 ** 63) |
| 192 | punpcklwd mm3,mm3 ; mm3=(60 60 61 61) |
| 193 | |
| 194 | psrad mm6,(DWORD_BIT-WORD_BIT) ; mm6=in4H=(42 43) |
| 195 | psrad mm2,(DWORD_BIT-WORD_BIT) ; mm2=in4L=(40 41) |
| 196 | cvtpi2ps xmm6,mm6 ; xmm6=(42 43 ** **) |
| 197 | cvtpi2ps xmm2,mm2 ; xmm2=(40 41 ** **) |
| 198 | psrad mm7,(DWORD_BIT-WORD_BIT) ; mm7=in6H=(62 63) |
| 199 | psrad mm3,(DWORD_BIT-WORD_BIT) ; mm3=in6L=(60 61) |
| 200 | cvtpi2ps xmm7,mm7 ; xmm7=(62 63 ** **) |
| 201 | cvtpi2ps xmm3,mm3 ; xmm3=(60 61 ** **) |
| 202 | |
| 203 | movlhps xmm0,xmm4 ; xmm0=in0=(00 01 02 03) |
| 204 | movlhps xmm1,xmm5 ; xmm1=in2=(20 21 22 23) |
| 205 | mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 206 | mulps xmm1, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 207 | |
| 208 | movlhps xmm2,xmm6 ; xmm2=in4=(40 41 42 43) |
| 209 | movlhps xmm3,xmm7 ; xmm3=in6=(60 61 62 63) |
| 210 | mulps xmm2, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 211 | mulps xmm3, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 212 | |
| 213 | movaps xmm4,xmm0 |
| 214 | movaps xmm5,xmm1 |
| 215 | subps xmm0,xmm2 ; xmm0=tmp11 |
| 216 | subps xmm1,xmm3 |
| 217 | addps xmm4,xmm2 ; xmm4=tmp10 |
| 218 | addps xmm5,xmm3 ; xmm5=tmp13 |
| 219 | |
| 220 | mulps xmm1,[GOTOFF(ebx,PD_1_414)] |
| 221 | subps xmm1,xmm5 ; xmm1=tmp12 |
| 222 | |
| 223 | movaps xmm6,xmm4 |
| 224 | movaps xmm7,xmm0 |
| 225 | subps xmm4,xmm5 ; xmm4=tmp3 |
| 226 | subps xmm0,xmm1 ; xmm0=tmp2 |
| 227 | addps xmm6,xmm5 ; xmm6=tmp0 |
| 228 | addps xmm7,xmm1 ; xmm7=tmp1 |
| 229 | |
| 230 | movaps XMMWORD [wk(1)], xmm4 ; tmp3 |
| 231 | movaps XMMWORD [wk(0)], xmm0 ; tmp2 |
| 232 | |
| 233 | ; -- Odd part |
| 234 | |
| 235 | movq mm4, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 236 | movq mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)] |
| 237 | movq mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)] |
| 238 | movq mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)] |
| 239 | |
| 240 | punpckhwd mm6,mm4 ; mm6=(** 12 ** 13) |
| 241 | punpcklwd mm4,mm4 ; mm4=(10 10 11 11) |
| 242 | punpckhwd mm2,mm0 ; mm2=(** 32 ** 33) |
| 243 | punpcklwd mm0,mm0 ; mm0=(30 30 31 31) |
| 244 | |
| 245 | psrad mm6,(DWORD_BIT-WORD_BIT) ; mm6=in1H=(12 13) |
| 246 | psrad mm4,(DWORD_BIT-WORD_BIT) ; mm4=in1L=(10 11) |
| 247 | cvtpi2ps xmm4,mm6 ; xmm4=(12 13 ** **) |
| 248 | cvtpi2ps xmm2,mm4 ; xmm2=(10 11 ** **) |
| 249 | psrad mm2,(DWORD_BIT-WORD_BIT) ; mm2=in3H=(32 33) |
| 250 | psrad mm0,(DWORD_BIT-WORD_BIT) ; mm0=in3L=(30 31) |
| 251 | cvtpi2ps xmm0,mm2 ; xmm0=(32 33 ** **) |
| 252 | cvtpi2ps xmm3,mm0 ; xmm3=(30 31 ** **) |
| 253 | |
| 254 | punpckhwd mm7,mm5 ; mm7=(** 52 ** 53) |
| 255 | punpcklwd mm5,mm5 ; mm5=(50 50 51 51) |
| 256 | punpckhwd mm3,mm1 ; mm3=(** 72 ** 73) |
| 257 | punpcklwd mm1,mm1 ; mm1=(70 70 71 71) |
| 258 | |
| 259 | movlhps xmm2,xmm4 ; xmm2=in1=(10 11 12 13) |
| 260 | movlhps xmm3,xmm0 ; xmm3=in3=(30 31 32 33) |
| 261 | |
| 262 | psrad mm7,(DWORD_BIT-WORD_BIT) ; mm7=in5H=(52 53) |
| 263 | psrad mm5,(DWORD_BIT-WORD_BIT) ; mm5=in5L=(50 51) |
| 264 | cvtpi2ps xmm4,mm7 ; xmm4=(52 53 ** **) |
| 265 | cvtpi2ps xmm5,mm5 ; xmm5=(50 51 ** **) |
| 266 | psrad mm3,(DWORD_BIT-WORD_BIT) ; mm3=in7H=(72 73) |
| 267 | psrad mm1,(DWORD_BIT-WORD_BIT) ; mm1=in7L=(70 71) |
| 268 | cvtpi2ps xmm0,mm3 ; xmm0=(72 73 ** **) |
| 269 | cvtpi2ps xmm1,mm1 ; xmm1=(70 71 ** **) |
| 270 | |
| 271 | mulps xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 272 | mulps xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 273 | |
| 274 | movlhps xmm5,xmm4 ; xmm5=in5=(50 51 52 53) |
| 275 | movlhps xmm1,xmm0 ; xmm1=in7=(70 71 72 73) |
| 276 | mulps xmm5, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 277 | mulps xmm1, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_FLOAT_MULT_TYPE)] |
| 278 | |
| 279 | movaps xmm4,xmm2 |
| 280 | movaps xmm0,xmm5 |
| 281 | addps xmm2,xmm1 ; xmm2=z11 |
| 282 | addps xmm5,xmm3 ; xmm5=z13 |
| 283 | subps xmm4,xmm1 ; xmm4=z12 |
| 284 | subps xmm0,xmm3 ; xmm0=z10 |
| 285 | |
| 286 | movaps xmm1,xmm2 |
| 287 | subps xmm2,xmm5 |
| 288 | addps xmm1,xmm5 ; xmm1=tmp7 |
| 289 | |
| 290 | mulps xmm2,[GOTOFF(ebx,PD_1_414)] ; xmm2=tmp11 |
| 291 | |
| 292 | movaps xmm3,xmm0 |
| 293 | addps xmm0,xmm4 |
| 294 | mulps xmm0,[GOTOFF(ebx,PD_1_847)] ; xmm0=z5 |
| 295 | mulps xmm3,[GOTOFF(ebx,PD_M2_613)] ; xmm3=(z10 * -2.613125930) |
| 296 | mulps xmm4,[GOTOFF(ebx,PD_1_082)] ; xmm4=(z12 * 1.082392200) |
| 297 | addps xmm3,xmm0 ; xmm3=tmp12 |
| 298 | subps xmm4,xmm0 ; xmm4=tmp10 |
| 299 | |
| 300 | ; -- Final output stage |
| 301 | |
| 302 | subps xmm3,xmm1 ; xmm3=tmp6 |
| 303 | movaps xmm5,xmm6 |
| 304 | movaps xmm0,xmm7 |
| 305 | addps xmm6,xmm1 ; xmm6=data0=(00 01 02 03) |
| 306 | addps xmm7,xmm3 ; xmm7=data1=(10 11 12 13) |
| 307 | subps xmm5,xmm1 ; xmm5=data7=(70 71 72 73) |
| 308 | subps xmm0,xmm3 ; xmm0=data6=(60 61 62 63) |
| 309 | subps xmm2,xmm3 ; xmm2=tmp5 |
| 310 | |
| 311 | movaps xmm1,xmm6 ; transpose coefficients(phase 1) |
| 312 | unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11) |
| 313 | unpckhps xmm1,xmm7 ; xmm1=(02 12 03 13) |
| 314 | movaps xmm3,xmm0 ; transpose coefficients(phase 1) |
| 315 | unpcklps xmm0,xmm5 ; xmm0=(60 70 61 71) |
| 316 | unpckhps xmm3,xmm5 ; xmm3=(62 72 63 73) |
| 317 | |
| 318 | movaps xmm7, XMMWORD [wk(0)] ; xmm7=tmp2 |
| 319 | movaps xmm5, XMMWORD [wk(1)] ; xmm5=tmp3 |
| 320 | |
| 321 | movaps XMMWORD [wk(0)], xmm0 ; wk(0)=(60 70 61 71) |
| 322 | movaps XMMWORD [wk(1)], xmm3 ; wk(1)=(62 72 63 73) |
| 323 | |
| 324 | addps xmm4,xmm2 ; xmm4=tmp4 |
| 325 | movaps xmm0,xmm7 |
| 326 | movaps xmm3,xmm5 |
| 327 | addps xmm7,xmm2 ; xmm7=data2=(20 21 22 23) |
| 328 | addps xmm5,xmm4 ; xmm5=data4=(40 41 42 43) |
| 329 | subps xmm0,xmm2 ; xmm0=data5=(50 51 52 53) |
| 330 | subps xmm3,xmm4 ; xmm3=data3=(30 31 32 33) |
| 331 | |
| 332 | movaps xmm2,xmm7 ; transpose coefficients(phase 1) |
| 333 | unpcklps xmm7,xmm3 ; xmm7=(20 30 21 31) |
| 334 | unpckhps xmm2,xmm3 ; xmm2=(22 32 23 33) |
| 335 | movaps xmm4,xmm5 ; transpose coefficients(phase 1) |
| 336 | unpcklps xmm5,xmm0 ; xmm5=(40 50 41 51) |
| 337 | unpckhps xmm4,xmm0 ; xmm4=(42 52 43 53) |
| 338 | |
| 339 | movaps xmm3,xmm6 ; transpose coefficients(phase 2) |
| 340 | unpcklps2 xmm6,xmm7 ; xmm6=(00 10 20 30) |
| 341 | unpckhps2 xmm3,xmm7 ; xmm3=(01 11 21 31) |
| 342 | movaps xmm0,xmm1 ; transpose coefficients(phase 2) |
| 343 | unpcklps2 xmm1,xmm2 ; xmm1=(02 12 22 32) |
| 344 | unpckhps2 xmm0,xmm2 ; xmm0=(03 13 23 33) |
| 345 | |
| 346 | movaps xmm7, XMMWORD [wk(0)] ; xmm7=(60 70 61 71) |
| 347 | movaps xmm2, XMMWORD [wk(1)] ; xmm2=(62 72 63 73) |
| 348 | |
| 349 | movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm6 |
| 350 | movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm3 |
| 351 | movaps XMMWORD [XMMBLOCK(2,0,edi,SIZEOF_FAST_FLOAT)], xmm1 |
| 352 | movaps XMMWORD [XMMBLOCK(3,0,edi,SIZEOF_FAST_FLOAT)], xmm0 |
| 353 | |
| 354 | movaps xmm6,xmm5 ; transpose coefficients(phase 2) |
| 355 | unpcklps2 xmm5,xmm7 ; xmm5=(40 50 60 70) |
| 356 | unpckhps2 xmm6,xmm7 ; xmm6=(41 51 61 71) |
| 357 | movaps xmm3,xmm4 ; transpose coefficients(phase 2) |
| 358 | unpcklps2 xmm4,xmm2 ; xmm4=(42 52 62 72) |
| 359 | unpckhps2 xmm3,xmm2 ; xmm3=(43 53 63 73) |
| 360 | |
| 361 | movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm5 |
| 362 | movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm6 |
| 363 | movaps XMMWORD [XMMBLOCK(2,1,edi,SIZEOF_FAST_FLOAT)], xmm4 |
| 364 | movaps XMMWORD [XMMBLOCK(3,1,edi,SIZEOF_FAST_FLOAT)], xmm3 |
| 365 | |
| 366 | .nextcolumn: |
| 367 | add esi, byte 4*SIZEOF_JCOEF ; coef_block |
| 368 | add edx, byte 4*SIZEOF_FLOAT_MULT_TYPE ; quantptr |
| 369 | add edi, 4*DCTSIZE*SIZEOF_FAST_FLOAT ; wsptr |
| 370 | dec ecx ; ctr |
| 371 | jnz near .columnloop |
| 372 | |
| 373 | ; -- Prefetch the next coefficient block |
| 374 | |
| 375 | prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 0*32] |
| 376 | prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 1*32] |
| 377 | prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 2*32] |
| 378 | prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 3*32] |
| 379 | |
| 380 | ; ---- Pass 2: process rows from work array, store into output array. |
| 381 | |
| 382 | mov eax, [original_ebp] |
| 383 | lea esi, [workspace] ; FAST_FLOAT * wsptr |
| 384 | mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *) |
| 385 | mov eax, JDIMENSION [output_col(eax)] |
| 386 | mov ecx, DCTSIZE/4 ; ctr |
| 387 | alignx 16,7 |
| 388 | .rowloop: |
| 389 | |
| 390 | ; -- Even part |
| 391 | |
| 392 | movaps xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)] |
| 393 | movaps xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_FAST_FLOAT)] |
| 394 | movaps xmm2, XMMWORD [XMMBLOCK(4,0,esi,SIZEOF_FAST_FLOAT)] |
| 395 | movaps xmm3, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_FAST_FLOAT)] |
| 396 | |
| 397 | movaps xmm4,xmm0 |
| 398 | movaps xmm5,xmm1 |
| 399 | subps xmm0,xmm2 ; xmm0=tmp11 |
| 400 | subps xmm1,xmm3 |
| 401 | addps xmm4,xmm2 ; xmm4=tmp10 |
| 402 | addps xmm5,xmm3 ; xmm5=tmp13 |
| 403 | |
| 404 | mulps xmm1,[GOTOFF(ebx,PD_1_414)] |
| 405 | subps xmm1,xmm5 ; xmm1=tmp12 |
| 406 | |
| 407 | movaps xmm6,xmm4 |
| 408 | movaps xmm7,xmm0 |
| 409 | subps xmm4,xmm5 ; xmm4=tmp3 |
| 410 | subps xmm0,xmm1 ; xmm0=tmp2 |
| 411 | addps xmm6,xmm5 ; xmm6=tmp0 |
| 412 | addps xmm7,xmm1 ; xmm7=tmp1 |
| 413 | |
| 414 | movaps XMMWORD [wk(1)], xmm4 ; tmp3 |
| 415 | movaps XMMWORD [wk(0)], xmm0 ; tmp2 |
| 416 | |
| 417 | ; -- Odd part |
| 418 | |
| 419 | movaps xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)] |
| 420 | movaps xmm3, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_FAST_FLOAT)] |
| 421 | movaps xmm5, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_FAST_FLOAT)] |
| 422 | movaps xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_FAST_FLOAT)] |
| 423 | |
| 424 | movaps xmm4,xmm2 |
| 425 | movaps xmm0,xmm5 |
| 426 | addps xmm2,xmm1 ; xmm2=z11 |
| 427 | addps xmm5,xmm3 ; xmm5=z13 |
| 428 | subps xmm4,xmm1 ; xmm4=z12 |
| 429 | subps xmm0,xmm3 ; xmm0=z10 |
| 430 | |
| 431 | movaps xmm1,xmm2 |
| 432 | subps xmm2,xmm5 |
| 433 | addps xmm1,xmm5 ; xmm1=tmp7 |
| 434 | |
| 435 | mulps xmm2,[GOTOFF(ebx,PD_1_414)] ; xmm2=tmp11 |
| 436 | |
| 437 | movaps xmm3,xmm0 |
| 438 | addps xmm0,xmm4 |
| 439 | mulps xmm0,[GOTOFF(ebx,PD_1_847)] ; xmm0=z5 |
| 440 | mulps xmm3,[GOTOFF(ebx,PD_M2_613)] ; xmm3=(z10 * -2.613125930) |
| 441 | mulps xmm4,[GOTOFF(ebx,PD_1_082)] ; xmm4=(z12 * 1.082392200) |
| 442 | addps xmm3,xmm0 ; xmm3=tmp12 |
| 443 | subps xmm4,xmm0 ; xmm4=tmp10 |
| 444 | |
| 445 | ; -- Final output stage |
| 446 | |
| 447 | subps xmm3,xmm1 ; xmm3=tmp6 |
| 448 | movaps xmm5,xmm6 |
| 449 | movaps xmm0,xmm7 |
| 450 | addps xmm6,xmm1 ; xmm6=data0=(00 10 20 30) |
| 451 | addps xmm7,xmm3 ; xmm7=data1=(01 11 21 31) |
| 452 | subps xmm5,xmm1 ; xmm5=data7=(07 17 27 37) |
| 453 | subps xmm0,xmm3 ; xmm0=data6=(06 16 26 36) |
| 454 | subps xmm2,xmm3 ; xmm2=tmp5 |
| 455 | |
| 456 | movaps xmm1,[GOTOFF(ebx,PD_0_125)] ; xmm1=[PD_0_125] |
| 457 | |
| 458 | mulps xmm6,xmm1 ; descale(1/8) |
| 459 | mulps xmm7,xmm1 ; descale(1/8) |
| 460 | mulps xmm5,xmm1 ; descale(1/8) |
| 461 | mulps xmm0,xmm1 ; descale(1/8) |
| 462 | |
| 463 | movhlps xmm3,xmm6 |
| 464 | movhlps xmm1,xmm7 |
| 465 | cvtps2pi mm0,xmm6 ; round to int32, mm0=data0L=(00 10) |
| 466 | cvtps2pi mm1,xmm7 ; round to int32, mm1=data1L=(01 11) |
| 467 | cvtps2pi mm2,xmm3 ; round to int32, mm2=data0H=(20 30) |
| 468 | cvtps2pi mm3,xmm1 ; round to int32, mm3=data1H=(21 31) |
| 469 | packssdw mm0,mm2 ; mm0=data0=(00 10 20 30) |
| 470 | packssdw mm1,mm3 ; mm1=data1=(01 11 21 31) |
| 471 | |
| 472 | movhlps xmm6,xmm5 |
| 473 | movhlps xmm7,xmm0 |
| 474 | cvtps2pi mm4,xmm5 ; round to int32, mm4=data7L=(07 17) |
| 475 | cvtps2pi mm5,xmm0 ; round to int32, mm5=data6L=(06 16) |
| 476 | cvtps2pi mm6,xmm6 ; round to int32, mm6=data7H=(27 37) |
| 477 | cvtps2pi mm7,xmm7 ; round to int32, mm7=data6H=(26 36) |
| 478 | packssdw mm4,mm6 ; mm4=data7=(07 17 27 37) |
| 479 | packssdw mm5,mm7 ; mm5=data6=(06 16 26 36) |
| 480 | |
| 481 | packsswb mm0,mm5 ; mm0=(00 10 20 30 06 16 26 36) |
| 482 | packsswb mm1,mm4 ; mm1=(01 11 21 31 07 17 27 37) |
| 483 | |
| 484 | movaps xmm3, XMMWORD [wk(0)] ; xmm3=tmp2 |
| 485 | movaps xmm1, XMMWORD [wk(1)] ; xmm1=tmp3 |
| 486 | |
| 487 | movaps xmm6,[GOTOFF(ebx,PD_0_125)] ; xmm6=[PD_0_125] |
| 488 | |
| 489 | addps xmm4,xmm2 ; xmm4=tmp4 |
| 490 | movaps xmm5,xmm3 |
| 491 | movaps xmm0,xmm1 |
| 492 | addps xmm3,xmm2 ; xmm3=data2=(02 12 22 32) |
| 493 | addps xmm1,xmm4 ; xmm1=data4=(04 14 24 34) |
| 494 | subps xmm5,xmm2 ; xmm5=data5=(05 15 25 35) |
| 495 | subps xmm0,xmm4 ; xmm0=data3=(03 13 23 33) |
| 496 | |
| 497 | mulps xmm3,xmm6 ; descale(1/8) |
| 498 | mulps xmm1,xmm6 ; descale(1/8) |
| 499 | mulps xmm5,xmm6 ; descale(1/8) |
| 500 | mulps xmm0,xmm6 ; descale(1/8) |
| 501 | |
| 502 | movhlps xmm7,xmm3 |
| 503 | movhlps xmm2,xmm1 |
| 504 | cvtps2pi mm2,xmm3 ; round to int32, mm2=data2L=(02 12) |
| 505 | cvtps2pi mm3,xmm1 ; round to int32, mm3=data4L=(04 14) |
| 506 | cvtps2pi mm6,xmm7 ; round to int32, mm6=data2H=(22 32) |
| 507 | cvtps2pi mm7,xmm2 ; round to int32, mm7=data4H=(24 34) |
| 508 | packssdw mm2,mm6 ; mm2=data2=(02 12 22 32) |
| 509 | packssdw mm3,mm7 ; mm3=data4=(04 14 24 34) |
| 510 | |
| 511 | movhlps xmm4,xmm5 |
| 512 | movhlps xmm6,xmm0 |
| 513 | cvtps2pi mm5,xmm5 ; round to int32, mm5=data5L=(05 15) |
| 514 | cvtps2pi mm4,xmm0 ; round to int32, mm4=data3L=(03 13) |
| 515 | cvtps2pi mm6,xmm4 ; round to int32, mm6=data5H=(25 35) |
| 516 | cvtps2pi mm7,xmm6 ; round to int32, mm7=data3H=(23 33) |
| 517 | packssdw mm5,mm6 ; mm5=data5=(05 15 25 35) |
| 518 | packssdw mm4,mm7 ; mm4=data3=(03 13 23 33) |
| 519 | |
| 520 | movq mm6,[GOTOFF(ebx,PB_CENTERJSAMP)] ; mm6=[PB_CENTERJSAMP] |
| 521 | |
| 522 | packsswb mm2,mm3 ; mm2=(02 12 22 32 04 14 24 34) |
| 523 | packsswb mm4,mm5 ; mm4=(03 13 23 33 05 15 25 35) |
| 524 | |
| 525 | paddb mm0,mm6 |
| 526 | paddb mm1,mm6 |
| 527 | paddb mm2,mm6 |
| 528 | paddb mm4,mm6 |
| 529 | |
| 530 | movq mm7,mm0 ; transpose coefficients(phase 1) |
| 531 | punpcklbw mm0,mm1 ; mm0=(00 01 10 11 20 21 30 31) |
| 532 | punpckhbw mm7,mm1 ; mm7=(06 07 16 17 26 27 36 37) |
| 533 | movq mm3,mm2 ; transpose coefficients(phase 1) |
| 534 | punpcklbw mm2,mm4 ; mm2=(02 03 12 13 22 23 32 33) |
| 535 | punpckhbw mm3,mm4 ; mm3=(04 05 14 15 24 25 34 35) |
| 536 | |
| 537 | movq mm5,mm0 ; transpose coefficients(phase 2) |
| 538 | punpcklwd mm0,mm2 ; mm0=(00 01 02 03 10 11 12 13) |
| 539 | punpckhwd mm5,mm2 ; mm5=(20 21 22 23 30 31 32 33) |
| 540 | movq mm6,mm3 ; transpose coefficients(phase 2) |
| 541 | punpcklwd mm3,mm7 ; mm3=(04 05 06 07 14 15 16 17) |
| 542 | punpckhwd mm6,mm7 ; mm6=(24 25 26 27 34 35 36 37) |
| 543 | |
| 544 | movq mm1,mm0 ; transpose coefficients(phase 3) |
| 545 | punpckldq mm0,mm3 ; mm0=(00 01 02 03 04 05 06 07) |
| 546 | punpckhdq mm1,mm3 ; mm1=(10 11 12 13 14 15 16 17) |
| 547 | movq mm4,mm5 ; transpose coefficients(phase 3) |
| 548 | punpckldq mm5,mm6 ; mm5=(20 21 22 23 24 25 26 27) |
| 549 | punpckhdq mm4,mm6 ; mm4=(30 31 32 33 34 35 36 37) |
| 550 | |
| 551 | pushpic ebx ; save GOT address |
| 552 | |
| 553 | mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW] |
| 554 | mov ebx, JSAMPROW [edi+1*SIZEOF_JSAMPROW] |
| 555 | movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm0 |
| 556 | movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm1 |
| 557 | mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW] |
| 558 | mov ebx, JSAMPROW [edi+3*SIZEOF_JSAMPROW] |
| 559 | movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm5 |
| 560 | movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm4 |
| 561 | |
| 562 | poppic ebx ; restore GOT address |
| 563 | |
| 564 | add esi, byte 4*SIZEOF_FAST_FLOAT ; wsptr |
| 565 | add edi, byte 4*SIZEOF_JSAMPROW |
| 566 | dec ecx ; ctr |
| 567 | jnz near .rowloop |
| 568 | |
| 569 | emms ; empty MMX state |
| 570 | |
| 571 | pop edi |
| 572 | pop esi |
| 573 | ; pop edx ; need not be preserved |
| 574 | ; pop ecx ; need not be preserved |
| 575 | pop ebx |
| 576 | mov esp,ebp ; esp <- aligned ebp |
| 577 | pop esp ; esp <- original ebp |
| 578 | pop ebp |
| 579 | ret |
| 580 | |
| 581 | %endif ; JIDCT_FLT_SSE_MMX_SUPPORTED |
| 582 | %endif ; DCT_FLOAT_SUPPORTED |