pw_log_basic/BUILD.gn

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("$dir_pw_docgen/docs.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

config("backend_config") {
  include_dirs = [ "public_overrides" ]
}

if (dir_pw_log_backend == dir_pw_log_basic) {
  source_set("pw_log_basic") {
    public_configs = [
      ":backend_config",
      ":default_config",
    ]
    deps = [ ":pw_log_basic_core" ]
    public = [ "public_overrides/pw_log_backend/log_backend.h" ]
    sources = public
  }
}

source_set("pw_log_basic_core") {
  public_configs = [ ":default_config" ]
  deps = [
    "$dir_pw_log:facade",
    "$dir_pw_preprocessor",
    "$dir_pw_string",
    "$dir_pw_sys_io",
  ]
  public = [ "public/pw_log_basic/log_basic.h" ]
  sources = public + [ "log_basic.cc" ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}