mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 1 | # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved. |
| 2 | # |
| 3 | # Use of this source code is governed by a BSD-style license |
| 4 | # that can be found in the LICENSE file in the root of the source |
| 5 | # tree. An additional intellectual property rights grant can be found |
| 6 | # in the file PATENTS. All contributing project authors may |
| 7 | # be found in the AUTHORS file in the root of the source tree. |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 8 | import("//build/config/arm.gni") |
| 9 | import("//build/config/features.gni") |
| 10 | import("//build/config/mips.gni") |
| 11 | import("//build/config/sanitizers/sanitizers.gni") |
ehmaldonado | 0d729b3 | 2017-02-10 01:38:23 -0800 | [diff] [blame] | 12 | import("//build/config/ui.gni") |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 13 | import("//build_overrides/build.gni") |
mbonadei | 9660627 | 2017-03-03 19:41:59 -0800 | [diff] [blame] | 14 | |
| 15 | if (!build_with_chromium && is_component_build) { |
| 16 | print("The Gn argument `is_component_build` is currently " + |
| 17 | "ignored for WebRTC builds.") |
| 18 | print("Component builds are supported by Chromium and the argument " + |
| 19 | "`is_component_build` makes it possible to create shared libraries " + |
| 20 | "instead of static libraries.") |
| 21 | print("If an app depends on WebRTC it makes sense to just depend on the " + |
| 22 | "WebRTC static library, so there is no difference between " + |
| 23 | "`is_component_build=true` and `is_component_build=false`.") |
| 24 | print( |
| 25 | "More info about component builds at: " + "https://chromium.googlesource.com/chromium/src/+/master/docs/component_build.md") |
| 26 | assert(!is_component_build, "Component builds are not supported in WebRTC.") |
| 27 | } |
| 28 | |
kthelgason | 4065a57 | 2017-02-14 04:58:56 -0800 | [diff] [blame] | 29 | if (is_ios) { |
| 30 | import("//build/config/ios/rules.gni") |
| 31 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 32 | |
| 33 | declare_args() { |
Karl Wiberg | eb254b4 | 2017-11-01 15:08:12 +0100 | [diff] [blame] | 34 | # Include the iLBC audio codec? |
| 35 | rtc_include_ilbc = true |
| 36 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 37 | # Disable this to avoid building the Opus audio codec. |
| 38 | rtc_include_opus = true |
| 39 | |
minyue | 2e03c66 | 2017-02-01 17:31:11 -0800 | [diff] [blame] | 40 | # Enable this if the Opus version upon which WebRTC is built supports direct |
| 41 | # encoding of 120 ms packets. |
minyue-webrtc | 516711c | 2017-07-27 17:45:49 +0200 | [diff] [blame] | 42 | rtc_opus_support_120ms_ptime = true |
minyue | 2e03c66 | 2017-02-01 17:31:11 -0800 | [diff] [blame] | 43 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 44 | # Enable this to let the Opus audio codec change complexity on the fly. |
| 45 | rtc_opus_variable_complexity = false |
| 46 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 47 | # Used to specify an external Jsoncpp include path when not compiling the |
| 48 | # library that comes with WebRTC (i.e. rtc_build_json == 0). |
| 49 | rtc_jsoncpp_root = "//third_party/jsoncpp/source/include" |
| 50 | |
| 51 | # Used to specify an external OpenSSL include path when not compiling the |
| 52 | # library that comes with WebRTC (i.e. rtc_build_ssl == 0). |
| 53 | rtc_ssl_root = "" |
| 54 | |
| 55 | # Selects fixed-point code where possible. |
| 56 | rtc_prefer_fixed_point = false |
| 57 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 58 | # Disable the code for the intelligibility enhancer by default. |
| 59 | rtc_enable_intelligibility_enhancer = false |
| 60 | |
| 61 | # Enable when an external authentication mechanism is used for performing |
| 62 | # packet authentication for RTP packets instead of libsrtp. |
| 63 | rtc_enable_external_auth = build_with_chromium |
| 64 | |
| 65 | # Selects whether debug dumps for the audio processing module |
| 66 | # should be generated. |
| 67 | apm_debug_dump = false |
| 68 | |
| 69 | # Set this to true to enable BWE test logging. |
| 70 | rtc_enable_bwe_test_logging = false |
| 71 | |
Joachim Bauch | 93e9134 | 2017-12-07 01:25:53 +0100 | [diff] [blame] | 72 | # Set this to false to skip building examples. |
| 73 | rtc_build_examples = true |
| 74 | |
| 75 | # Set this to false to skip building tools. |
| 76 | rtc_build_tools = true |
| 77 | |
Joachim Bauch | 75f18fc | 2017-12-20 21:25:47 +0100 | [diff] [blame] | 78 | # Set this to false to skip building code that requires X11. |
| 79 | rtc_use_x11 = use_x11 |
| 80 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 81 | # Enable to use the Mozilla internal settings. |
| 82 | build_with_mozilla = false |
| 83 | |
henrika | 883d00f | 2018-03-16 10:09:49 +0100 | [diff] [blame] | 84 | # Enable use of Android AAudio which requires Android SDK 26 or above and |
| 85 | # NDK r16 or above. |
| 86 | rtc_enable_android_aaudio = false |
| 87 | |
| 88 | # TODO(henrika): can this flag be removed? |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 89 | rtc_enable_android_opensl = false |
| 90 | |
| 91 | # Link-Time Optimizations. |
| 92 | # Executes code generation at link-time instead of compile-time. |
| 93 | # https://gcc.gnu.org/wiki/LinkTimeOptimization |
| 94 | rtc_use_lto = false |
| 95 | |
| 96 | # Set to "func", "block", "edge" for coverage generation. |
| 97 | # At unit test runtime set UBSAN_OPTIONS="coverage=1". |
| 98 | # It is recommend to set include_examples=0. |
| 99 | # Use llvm's sancov -html-report for human readable reports. |
| 100 | # See http://clang.llvm.org/docs/SanitizerCoverage.html . |
| 101 | rtc_sanitize_coverage = "" |
| 102 | |
perkj | 650fdae | 2017-08-25 05:00:11 -0700 | [diff] [blame] | 103 | # Links a default implementation of task queues to targets |
| 104 | # that depend on the target rtc_task_queue. Set to false to |
| 105 | # use an external implementation. |
| 106 | rtc_link_task_queue_impl = true |
| 107 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 108 | if (current_cpu == "arm" || current_cpu == "arm64") { |
| 109 | rtc_prefer_fixed_point = true |
| 110 | } |
| 111 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 112 | # Determines whether NEON code will be built. |
| 113 | rtc_build_with_neon = |
| 114 | (current_cpu == "arm" && arm_use_neon) || current_cpu == "arm64" |
| 115 | |
| 116 | # Enable this to build OpenH264 encoder/FFmpeg decoder. This is supported on |
| 117 | # all platforms except Android and iOS. Because FFmpeg can be built |
| 118 | # with/without H.264 support, |ffmpeg_branding| has to separately be set to a |
| 119 | # value that includes H.264, for example "Chrome". If FFmpeg is built without |
| 120 | # H.264, compilation succeeds but |H264DecoderImpl| fails to initialize. See |
| 121 | # also: |rtc_initialize_ffmpeg|. |
| 122 | # CHECK THE OPENH264, FFMPEG AND H.264 LICENSES/PATENTS BEFORE BUILDING. |
| 123 | # http://www.openh264.org, https://www.ffmpeg.org/ |
Patrik Höglund | 3bb1194 | 2018-03-16 12:36:26 +0000 | [diff] [blame] | 124 | rtc_use_h264 = proprietary_codecs && !is_android && !is_ios |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 125 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 126 | # By default, use normal platform audio support or dummy audio, but don't |
| 127 | # use file-based audio playout and record. |
| 128 | rtc_use_dummy_audio_file_devices = false |
| 129 | |
henrika | 7be7883 | 2017-06-13 17:34:16 +0200 | [diff] [blame] | 130 | # When set to true, replace the audio output with a sinus tone at 440Hz. |
| 131 | # The ADM will ask for audio data from WebRTC but instead of reading real |
| 132 | # audio samples from NetEQ, a sinus tone will be generated and replace the |
| 133 | # real audio samples. |
| 134 | rtc_audio_device_plays_sinus_tone = false |
| 135 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 136 | # When set to true, test targets will declare the files needed to run memcheck |
| 137 | # as data dependencies. This is to enable memcheck execution on swarming bots. |
| 138 | rtc_use_memcheck = false |
| 139 | |
| 140 | # FFmpeg must be initialized for |H264DecoderImpl| to work. This can be done |
| 141 | # by WebRTC during |H264DecoderImpl::InitDecode| or externally. FFmpeg must |
| 142 | # only be initialized once. Projects that initialize FFmpeg externally, such |
| 143 | # as Chromium, must turn this flag off so that WebRTC does not also |
| 144 | # initialize. |
| 145 | rtc_initialize_ffmpeg = !build_with_chromium |
Anders Carlsson | dd8c165 | 2018-01-30 10:32:13 +0100 | [diff] [blame] | 146 | |
| 147 | # Disable this to build without support for built-in software codecs. |
| 148 | rtc_use_builtin_sw_codecs = true |
Dan Minor | 9c68613 | 2018-01-15 10:20:00 -0500 | [diff] [blame] | 149 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 150 | |
Dan Minor | 9c68613 | 2018-01-15 10:20:00 -0500 | [diff] [blame] | 151 | if (!build_with_mozilla) { |
| 152 | import("//testing/test.gni") |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 153 | } |
| 154 | |
| 155 | # A second declare_args block, so that declarations within it can |
| 156 | # depend on the possibly overridden variables in the first |
| 157 | # declare_args block. |
| 158 | declare_args() { |
Dan Minor | 9c68613 | 2018-01-15 10:20:00 -0500 | [diff] [blame] | 159 | # Enables the use of protocol buffers for debug recordings. |
| 160 | rtc_enable_protobuf = !build_with_mozilla |
| 161 | |
| 162 | # Set this to disable building with support for SCTP data channels. |
| 163 | rtc_enable_sctp = !build_with_mozilla |
| 164 | |
| 165 | # Disable these to not build components which can be externally provided. |
| 166 | rtc_build_json = !build_with_mozilla |
| 167 | rtc_build_libsrtp = !build_with_mozilla |
| 168 | rtc_build_libvpx = !build_with_mozilla |
| 169 | rtc_libvpx_build_vp9 = !build_with_mozilla |
| 170 | rtc_build_openmax_dl = !build_with_mozilla |
| 171 | rtc_build_opus = !build_with_mozilla |
| 172 | rtc_build_ssl = !build_with_mozilla |
| 173 | rtc_build_usrsctp = !build_with_mozilla |
| 174 | |
| 175 | # Enable libevent task queues on platforms that support it. |
| 176 | # rtc_link_task_queue_impl must be set to true for this to |
| 177 | # have an effect. |
Wez | 00cecb9 | 2018-02-09 10:41:00 -0800 | [diff] [blame] | 178 | if (is_win || is_mac || is_ios || is_nacl || is_fuchsia) { |
Dan Minor | 9c68613 | 2018-01-15 10:20:00 -0500 | [diff] [blame] | 179 | rtc_enable_libevent = false |
| 180 | rtc_build_libevent = false |
| 181 | } else { |
| 182 | rtc_enable_libevent = true |
| 183 | rtc_build_libevent = !build_with_mozilla |
| 184 | } |
| 185 | |
| 186 | if (!is_ios && (current_cpu != "arm" || arm_version >= 7) && |
| 187 | current_cpu != "mips64el" && !build_with_mozilla) { |
| 188 | rtc_use_openmax_dl = true |
| 189 | } else { |
| 190 | rtc_use_openmax_dl = false |
| 191 | } |
| 192 | |
| 193 | # Build sources requiring GTK. NOTICE: This is not present in Chrome OS |
| 194 | # build environments, even if available for Chromium builds. |
| 195 | rtc_use_gtk = !build_with_chromium && !build_with_mozilla |
| 196 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 197 | # Excluded in Chromium since its prerequisites don't require Pulse Audio. |
| 198 | rtc_include_pulse_audio = !build_with_chromium |
| 199 | |
| 200 | # Chromium uses its own IO handling, so the internal ADM is only built for |
| 201 | # standalone WebRTC. |
| 202 | rtc_include_internal_audio_device = !build_with_chromium |
| 203 | |
| 204 | # Include tests in standalone checkout. |
Dan Minor | 9c68613 | 2018-01-15 10:20:00 -0500 | [diff] [blame] | 205 | rtc_include_tests = !build_with_chromium && !build_with_mozilla |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 206 | } |
| 207 | |
| 208 | # Make it possible to provide custom locations for some libraries (move these |
| 209 | # up into declare_args should we need to actually use them for the GN build). |
| 210 | rtc_libvpx_dir = "//third_party/libvpx" |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 211 | rtc_opus_dir = "//third_party/opus" |
| 212 | |
| 213 | # Desktop capturer is supported only on Windows, OSX and Linux. |
Joachim Bauch | 75f18fc | 2017-12-20 21:25:47 +0100 | [diff] [blame] | 214 | rtc_desktop_capture_supported = is_win || is_mac || (is_linux && rtc_use_x11) |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 215 | |
| 216 | ############################################################################### |
| 217 | # Templates |
| 218 | # |
| 219 | |
Mirko Bonadei | 92ea95e | 2017-09-15 06:47:31 +0200 | [diff] [blame] | 220 | # Points to // in webrtc stand-alone or to //third_party/webrtc/ in |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 221 | # chromium. |
| 222 | # We need absolute paths for all configs in templates as they are shared in |
| 223 | # different subdirectories. |
| 224 | webrtc_root = get_path_info(".", "abspath") |
| 225 | |
| 226 | # Global configuration that should be applied to all WebRTC targets. |
| 227 | # You normally shouldn't need to include this in your target as it's |
| 228 | # automatically included when using the rtc_* templates. |
| 229 | # It sets defines, include paths and compilation warnings accordingly, |
| 230 | # both for WebRTC stand-alone builds and for the scenario when WebRTC |
| 231 | # native code is built as part of Chromium. |
| 232 | rtc_common_configs = [ webrtc_root + ":common_config" ] |
| 233 | |
kthelgason | c097710 | 2017-04-24 00:57:16 -0700 | [diff] [blame] | 234 | if (is_mac || is_ios) { |
| 235 | rtc_common_configs += [ "//build/config/compiler:enable_arc" ] |
| 236 | } |
| 237 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 238 | # Global public configuration that should be applied to all WebRTC targets. You |
| 239 | # normally shouldn't need to include this in your target as it's automatically |
| 240 | # included when using the rtc_* templates. It set the defines, include paths and |
| 241 | # compilation warnings that should be propagated to dependents of the targets |
| 242 | # depending on the target having this config. |
| 243 | rtc_common_inherited_config = webrtc_root + ":common_inherited_config" |
| 244 | |
| 245 | # Common configs to remove or add in all rtc targets. |
| 246 | rtc_remove_configs = [] |
| 247 | rtc_add_configs = rtc_common_configs |
| 248 | |
| 249 | set_defaults("rtc_test") { |
| 250 | configs = rtc_add_configs |
| 251 | suppressed_configs = [] |
| 252 | } |
| 253 | |
| 254 | set_defaults("rtc_source_set") { |
| 255 | configs = rtc_add_configs |
| 256 | suppressed_configs = [] |
| 257 | } |
| 258 | |
| 259 | set_defaults("rtc_executable") { |
| 260 | configs = rtc_add_configs |
| 261 | suppressed_configs = [] |
| 262 | } |
| 263 | |
| 264 | set_defaults("rtc_static_library") { |
| 265 | configs = rtc_add_configs |
| 266 | suppressed_configs = [] |
| 267 | } |
| 268 | |
| 269 | set_defaults("rtc_shared_library") { |
| 270 | configs = rtc_add_configs |
| 271 | suppressed_configs = [] |
| 272 | } |
| 273 | |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 274 | webrtc_default_visibility = [ webrtc_root + "/*" ] |
| 275 | if (build_with_chromium) { |
| 276 | # Allow Chromium's WebRTC overrides targets to bypass the regular |
| 277 | # visibility restrictions. |
| 278 | webrtc_default_visibility += [ webrtc_root + "/../webrtc_overrides/*" ] |
| 279 | } |
| 280 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 281 | template("rtc_test") { |
| 282 | test(target_name) { |
| 283 | forward_variables_from(invoker, |
| 284 | "*", |
| 285 | [ |
| 286 | "configs", |
| 287 | "public_configs", |
| 288 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 289 | "visibility", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 290 | ]) |
Mirko Bonadei | dd41194 | 2017-11-21 15:35:27 +0100 | [diff] [blame] | 291 | |
| 292 | # Always override to public because when target_os is Android the `test` |
| 293 | # template can override it to [ "*" ] and we want to avoid conditional |
| 294 | # visibility. |
Mirko Bonadei | 2155881 | 2017-11-21 12:47:34 +0100 | [diff] [blame] | 295 | visibility = [ "*" ] |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 296 | configs += invoker.configs |
| 297 | configs -= rtc_remove_configs |
| 298 | configs -= invoker.suppressed_configs |
| 299 | public_configs = [ rtc_common_inherited_config ] |
| 300 | if (defined(invoker.public_configs)) { |
| 301 | public_configs += invoker.public_configs |
| 302 | } |
sakal | d7fdb80 | 2017-05-26 01:51:53 -0700 | [diff] [blame] | 303 | if (!build_with_chromium && is_android) { |
Jianjun Zhu | 037f3e4 | 2017-08-15 21:48:37 +0800 | [diff] [blame] | 304 | android_manifest = webrtc_root + "test/android/AndroidManifest.xml" |
| 305 | deps += [ webrtc_root + "test:native_test_java" ] |
sakal | d7fdb80 | 2017-05-26 01:51:53 -0700 | [diff] [blame] | 306 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 307 | } |
| 308 | } |
| 309 | |
| 310 | template("rtc_source_set") { |
| 311 | source_set(target_name) { |
| 312 | forward_variables_from(invoker, |
| 313 | "*", |
| 314 | [ |
| 315 | "configs", |
| 316 | "public_configs", |
| 317 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 318 | "visibility", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 319 | ]) |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 320 | forward_variables_from(invoker, [ "visibility" ]) |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 321 | if (!defined(visibility)) { |
| 322 | visibility = webrtc_default_visibility |
| 323 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 324 | configs += invoker.configs |
| 325 | configs -= rtc_remove_configs |
| 326 | configs -= invoker.suppressed_configs |
| 327 | public_configs = [ rtc_common_inherited_config ] |
| 328 | if (defined(invoker.public_configs)) { |
| 329 | public_configs += invoker.public_configs |
| 330 | } |
| 331 | } |
| 332 | } |
| 333 | |
| 334 | template("rtc_executable") { |
| 335 | executable(target_name) { |
| 336 | forward_variables_from(invoker, |
| 337 | "*", |
| 338 | [ |
| 339 | "deps", |
| 340 | "configs", |
| 341 | "public_configs", |
| 342 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 343 | "visibility", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 344 | ]) |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 345 | forward_variables_from(invoker, [ "visibility" ]) |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 346 | if (!defined(visibility)) { |
| 347 | visibility = webrtc_default_visibility |
| 348 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 349 | configs += invoker.configs |
| 350 | configs -= rtc_remove_configs |
| 351 | configs -= invoker.suppressed_configs |
| 352 | deps = [ |
thomasanderson | 7f52f08 | 2017-05-18 23:51:46 -0700 | [diff] [blame] | 353 | "//build/config:exe_and_shlib_deps", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 354 | ] |
| 355 | deps += invoker.deps |
perkj | 650fdae | 2017-08-25 05:00:11 -0700 | [diff] [blame] | 356 | |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 357 | public_configs = [ rtc_common_inherited_config ] |
| 358 | if (defined(invoker.public_configs)) { |
| 359 | public_configs += invoker.public_configs |
| 360 | } |
| 361 | } |
| 362 | } |
| 363 | |
| 364 | template("rtc_static_library") { |
| 365 | static_library(target_name) { |
| 366 | forward_variables_from(invoker, |
| 367 | "*", |
| 368 | [ |
| 369 | "configs", |
| 370 | "public_configs", |
| 371 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 372 | "visibility", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 373 | ]) |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 374 | forward_variables_from(invoker, [ "visibility" ]) |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 375 | if (!defined(visibility)) { |
| 376 | visibility = webrtc_default_visibility |
| 377 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 378 | configs += invoker.configs |
| 379 | configs -= rtc_remove_configs |
| 380 | configs -= invoker.suppressed_configs |
| 381 | public_configs = [ rtc_common_inherited_config ] |
| 382 | if (defined(invoker.public_configs)) { |
| 383 | public_configs += invoker.public_configs |
| 384 | } |
| 385 | } |
| 386 | } |
| 387 | |
| 388 | template("rtc_shared_library") { |
| 389 | shared_library(target_name) { |
| 390 | forward_variables_from(invoker, |
| 391 | "*", |
| 392 | [ |
| 393 | "configs", |
| 394 | "public_configs", |
| 395 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 396 | "visibility", |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 397 | ]) |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 398 | forward_variables_from(invoker, [ "visibility" ]) |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 399 | if (!defined(visibility)) { |
| 400 | visibility = webrtc_default_visibility |
| 401 | } |
mbonadei | 9aa3f0a | 2017-01-24 06:58:22 -0800 | [diff] [blame] | 402 | configs += invoker.configs |
| 403 | configs -= rtc_remove_configs |
| 404 | configs -= invoker.suppressed_configs |
| 405 | public_configs = [ rtc_common_inherited_config ] |
| 406 | if (defined(invoker.public_configs)) { |
| 407 | public_configs += invoker.public_configs |
| 408 | } |
| 409 | } |
| 410 | } |
kthelgason | 4065a57 | 2017-02-14 04:58:56 -0800 | [diff] [blame] | 411 | |
| 412 | if (is_ios) { |
| 413 | set_defaults("rtc_ios_xctest_test") { |
| 414 | configs = rtc_add_configs |
| 415 | suppressed_configs = [] |
| 416 | } |
| 417 | |
| 418 | template("rtc_ios_xctest_test") { |
| 419 | ios_xctest_test(target_name) { |
| 420 | forward_variables_from(invoker, |
| 421 | "*", |
| 422 | [ |
| 423 | "configs", |
| 424 | "public_configs", |
| 425 | "suppressed_configs", |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 426 | "visibility", |
kthelgason | 4065a57 | 2017-02-14 04:58:56 -0800 | [diff] [blame] | 427 | ]) |
Karl Wiberg | 138d4ac | 2017-10-16 11:16:19 +0200 | [diff] [blame] | 428 | forward_variables_from(invoker, [ "visibility" ]) |
Per Kjellander | a7f2d84 | 2018-01-10 15:54:53 +0000 | [diff] [blame] | 429 | if (!defined(visibility)) { |
| 430 | visibility = webrtc_default_visibility |
| 431 | } |
kthelgason | 4065a57 | 2017-02-14 04:58:56 -0800 | [diff] [blame] | 432 | configs += invoker.configs |
| 433 | configs -= rtc_remove_configs |
| 434 | configs -= invoker.suppressed_configs |
| 435 | public_configs = [ rtc_common_inherited_config ] |
| 436 | if (defined(invoker.public_configs)) { |
| 437 | public_configs += invoker.public_configs |
| 438 | } |
| 439 | } |
| 440 | } |
Anders Carlsson | dc6b477 | 2018-01-15 13:31:03 +0100 | [diff] [blame] | 441 | |
| 442 | template("ios_framework_bundle_with_umbrella_header") { |
| 443 | forward_variables_from(invoker, [ "output_name" ]) |
| 444 | umbrella_header_path = |
| 445 | "$target_gen_dir/$output_name.framework/Headers/$output_name.h" |
| 446 | |
| 447 | ios_framework_bundle(target_name) { |
| 448 | forward_variables_from(invoker, "*", []) |
| 449 | |
| 450 | deps += [ ":copy_umbrella_header_$target_name" ] |
| 451 | } |
| 452 | |
| 453 | action("umbrella_header_$target_name") { |
| 454 | forward_variables_from(invoker, [ "public_headers" ]) |
| 455 | |
| 456 | script = "//tools_webrtc/ios/generate_umbrella_header.py" |
| 457 | |
| 458 | outputs = [ |
| 459 | umbrella_header_path, |
| 460 | ] |
| 461 | args = [ |
| 462 | "--out", |
| 463 | rebase_path(umbrella_header_path, root_build_dir), |
| 464 | "--sources", |
| 465 | ] + rebase_path(public_headers, "objc/Framework/Headers/") |
| 466 | } |
| 467 | |
| 468 | copy("copy_umbrella_header_$target_name") { |
| 469 | sources = [ |
| 470 | umbrella_header_path, |
| 471 | ] |
| 472 | outputs = [ |
| 473 | "$root_out_dir/$output_name.framework/Headers/$output_name.h", |
| 474 | ] |
| 475 | |
| 476 | deps = [ |
| 477 | ":umbrella_header_$target_name", |
| 478 | ] |
| 479 | } |
| 480 | } |
| 481 | |
| 482 | set_defaults("ios_framework_bundle_with_umbrella_header") { |
| 483 | configs = default_shared_library_configs |
| 484 | } |
kthelgason | 4065a57 | 2017-02-14 04:58:56 -0800 | [diff] [blame] | 485 | } |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 486 | |
| 487 | if (is_android) { |
| 488 | template("rtc_android_library") { |
| 489 | android_library(target_name) { |
| 490 | forward_variables_from(invoker, |
| 491 | "*", |
| 492 | [ |
| 493 | "configs", |
| 494 | "public_configs", |
| 495 | "suppressed_configs", |
| 496 | "visibility", |
| 497 | ]) |
| 498 | |
Sami Kalliomäki | e7fac68 | 2018-03-20 16:32:49 +0100 | [diff] [blame] | 499 | javac_args = [] |
| 500 | |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 501 | # Treat warnings as errors. |
Sami Kalliomäki | e7fac68 | 2018-03-20 16:32:49 +0100 | [diff] [blame] | 502 | javac_args += [ "-Werror" ] |
| 503 | |
Sami Kalliomäki | dc52651 | 2018-03-27 17:07:27 +0200 | [diff] [blame] | 504 | # TODO(crbug.com/824679): Find out why this fails in Chromium |
| 505 | if (!build_with_chromium) { |
| 506 | javac_args += [ |
| 507 | "-Xep:ParameterNotNullable:ERROR", |
| 508 | "-Xep:FieldMissingNullable:ERROR", |
| 509 | "-Xep:ReturnMissingNullable:ERROR", |
| 510 | ] |
| 511 | } |
| 512 | |
Sami Kalliomäki | e7fac68 | 2018-03-20 16:32:49 +0100 | [diff] [blame] | 513 | # Add any arguments defined by the invoker. |
| 514 | if (defined(invoker.javac_args)) { |
| 515 | javac_args += invoker.javac_args |
| 516 | } |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 517 | |
Sami Kalliomäki | dc52651 | 2018-03-27 17:07:27 +0200 | [diff] [blame] | 518 | if (!defined(deps)) { |
| 519 | deps = [] |
| 520 | } |
| 521 | deps += [ "//third_party/jsr-305:jsr_305_javalib" ] |
| 522 | |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 523 | no_build_hooks = true |
| 524 | } |
| 525 | } |
| 526 | |
| 527 | template("rtc_android_apk") { |
| 528 | android_apk(target_name) { |
| 529 | forward_variables_from(invoker, |
| 530 | "*", |
| 531 | [ |
| 532 | "configs", |
| 533 | "public_configs", |
| 534 | "suppressed_configs", |
| 535 | "visibility", |
| 536 | ]) |
| 537 | |
| 538 | # Treat warnings as errors. |
| 539 | javac_args = [ "-Werror" ] |
| 540 | |
Sami Kalliomäki | dc52651 | 2018-03-27 17:07:27 +0200 | [diff] [blame] | 541 | # TODO(crbug.com/824679): Find out why this fails in Chromium |
| 542 | if (!build_with_chromium) { |
| 543 | javac_args += [ |
| 544 | "-Xep:ParameterNotNullable:ERROR", |
| 545 | "-Xep:FieldMissingNullable:ERROR", |
| 546 | "-Xep:ReturnMissingNullable:ERROR", |
| 547 | ] |
| 548 | } |
| 549 | |
| 550 | if (!defined(deps)) { |
| 551 | deps = [] |
| 552 | } |
| 553 | deps += [ "//third_party/jsr-305:jsr_305_javalib" ] |
| 554 | |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 555 | no_build_hooks = true |
| 556 | } |
| 557 | } |
| 558 | |
| 559 | template("rtc_instrumentation_test_apk") { |
| 560 | instrumentation_test_apk(target_name) { |
| 561 | forward_variables_from(invoker, |
| 562 | "*", |
| 563 | [ |
| 564 | "configs", |
| 565 | "public_configs", |
| 566 | "suppressed_configs", |
| 567 | "visibility", |
| 568 | ]) |
| 569 | |
| 570 | # Treat warnings as errors. |
| 571 | javac_args = [ "-Werror" ] |
| 572 | |
Sami Kalliomäki | dc52651 | 2018-03-27 17:07:27 +0200 | [diff] [blame] | 573 | # TODO(crbug.com/824679): Find out why this fails in Chromium |
| 574 | if (!build_with_chromium) { |
| 575 | javac_args += [ |
| 576 | "-Xep:ParameterNotNullable:ERROR", |
| 577 | "-Xep:FieldMissingNullable:ERROR", |
| 578 | "-Xep:ReturnMissingNullable:ERROR", |
| 579 | ] |
| 580 | } |
| 581 | |
| 582 | if (!defined(deps)) { |
| 583 | deps = [] |
| 584 | } |
| 585 | deps += [ "//third_party/jsr-305:jsr_305_javalib" ] |
| 586 | |
Mirko Bonadei | fbb3b7d | 2017-11-07 15:36:33 +0000 | [diff] [blame] | 587 | no_build_hooks = true |
| 588 | } |
| 589 | } |
| 590 | } |