Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 1 | /* |
| 2 | * Based on arch/arm/mm/proc.S |
| 3 | * |
| 4 | * Copyright (C) 2001 Deep Blue Solutions Ltd. |
| 5 | * Copyright (C) 2012 ARM Ltd. |
| 6 | * Author: Catalin Marinas <catalin.marinas@arm.com> |
| 7 | * |
| 8 | * This program is free software; you can redistribute it and/or modify |
| 9 | * it under the terms of the GNU General Public License version 2 as |
| 10 | * published by the Free Software Foundation. |
| 11 | * |
| 12 | * This program is distributed in the hope that it will be useful, |
| 13 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | * GNU General Public License for more details. |
| 16 | * |
| 17 | * You should have received a copy of the GNU General Public License |
| 18 | * along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 19 | */ |
| 20 | |
| 21 | #include <linux/init.h> |
| 22 | #include <linux/linkage.h> |
| 23 | #include <asm/assembler.h> |
| 24 | #include <asm/asm-offsets.h> |
| 25 | #include <asm/hwcap.h> |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 26 | #include <asm/pgtable.h> |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 27 | #include <asm/pgtable-hwdef.h> |
Andrew Pinski | 104a0c0 | 2016-02-24 17:44:57 -0800 | [diff] [blame] | 28 | #include <asm/cpufeature.h> |
| 29 | #include <asm/alternative.h> |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 30 | |
Catalin Marinas | 35a8697 | 2014-04-02 17:55:40 +0100 | [diff] [blame] | 31 | #ifdef CONFIG_ARM64_64K_PAGES |
| 32 | #define TCR_TG_FLAGS TCR_TG0_64K | TCR_TG1_64K |
Suzuki K. Poulose | 44eaacf | 2015-10-19 14:19:37 +0100 | [diff] [blame] | 33 | #elif defined(CONFIG_ARM64_16K_PAGES) |
| 34 | #define TCR_TG_FLAGS TCR_TG0_16K | TCR_TG1_16K |
| 35 | #else /* CONFIG_ARM64_4K_PAGES */ |
Catalin Marinas | 35a8697 | 2014-04-02 17:55:40 +0100 | [diff] [blame] | 36 | #define TCR_TG_FLAGS TCR_TG0_4K | TCR_TG1_4K |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 37 | #endif |
| 38 | |
Catalin Marinas | 35a8697 | 2014-04-02 17:55:40 +0100 | [diff] [blame] | 39 | #define TCR_SMP_FLAGS TCR_SHARED |
Catalin Marinas | 35a8697 | 2014-04-02 17:55:40 +0100 | [diff] [blame] | 40 | |
| 41 | /* PTWs cacheable, inner/outer WBWA */ |
| 42 | #define TCR_CACHE_FLAGS TCR_IRGN_WBWA | TCR_ORGN_WBWA |
| 43 | |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 44 | #define MAIR(attr, mt) ((attr) << ((mt) * 8)) |
| 45 | |
| 46 | /* |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 47 | * cpu_do_idle() |
| 48 | * |
| 49 | * Idle the processor (wait for interrupt). |
| 50 | */ |
| 51 | ENTRY(cpu_do_idle) |
| 52 | dsb sy // WFI may enter a low-power mode |
| 53 | wfi |
| 54 | ret |
| 55 | ENDPROC(cpu_do_idle) |
| 56 | |
Lorenzo Pieralisi | af3cfdb | 2015-01-26 18:33:44 +0000 | [diff] [blame] | 57 | #ifdef CONFIG_CPU_PM |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 58 | /** |
| 59 | * cpu_do_suspend - save CPU registers context |
| 60 | * |
| 61 | * x0: virtual address of context pointer |
| 62 | */ |
| 63 | ENTRY(cpu_do_suspend) |
| 64 | mrs x2, tpidr_el0 |
| 65 | mrs x3, tpidrro_el0 |
| 66 | mrs x4, contextidr_el1 |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 67 | mrs x5, cpacr_el1 |
| 68 | mrs x6, tcr_el1 |
| 69 | mrs x7, vbar_el1 |
| 70 | mrs x8, mdscr_el1 |
| 71 | mrs x9, oslsr_el1 |
| 72 | mrs x10, sctlr_el1 |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 73 | stp x2, x3, [x0] |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 74 | stp x4, xzr, [x0, #16] |
| 75 | stp x5, x6, [x0, #32] |
| 76 | stp x7, x8, [x0, #48] |
| 77 | stp x9, x10, [x0, #64] |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 78 | ret |
| 79 | ENDPROC(cpu_do_suspend) |
| 80 | |
| 81 | /** |
| 82 | * cpu_do_resume - restore CPU register context |
| 83 | * |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 84 | * x0: Address of context pointer |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 85 | */ |
Will Deacon | 574e44d | 2018-04-03 12:09:23 +0100 | [diff] [blame^] | 86 | .pushsection ".idmap.text", "awx" |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 87 | ENTRY(cpu_do_resume) |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 88 | ldp x2, x3, [x0] |
| 89 | ldp x4, x5, [x0, #16] |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 90 | ldp x6, x8, [x0, #32] |
| 91 | ldp x9, x10, [x0, #48] |
| 92 | ldp x11, x12, [x0, #64] |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 93 | msr tpidr_el0, x2 |
| 94 | msr tpidrro_el0, x3 |
| 95 | msr contextidr_el1, x4 |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 96 | msr cpacr_el1, x6 |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 97 | |
| 98 | /* Don't change t0sz here, mask those bits when restoring */ |
| 99 | mrs x5, tcr_el1 |
| 100 | bfi x8, x5, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH |
| 101 | |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 102 | msr tcr_el1, x8 |
| 103 | msr vbar_el1, x9 |
James Morse | 744c6c3 | 2016-08-26 16:03:42 +0100 | [diff] [blame] | 104 | |
| 105 | /* |
| 106 | * __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking |
| 107 | * debug exceptions. By restoring MDSCR_EL1 here, we may take a debug |
| 108 | * exception. Mask them until local_dbg_restore() in cpu_suspend() |
| 109 | * resets them. |
| 110 | */ |
| 111 | disable_dbg |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 112 | msr mdscr_el1, x10 |
James Morse | 744c6c3 | 2016-08-26 16:03:42 +0100 | [diff] [blame] | 113 | |
James Morse | cabe1c8 | 2016-04-27 17:47:07 +0100 | [diff] [blame] | 114 | msr sctlr_el1, x12 |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 115 | /* |
| 116 | * Restore oslsr_el1 by writing oslar_el1 |
| 117 | */ |
| 118 | ubfx x11, x11, #1, #1 |
| 119 | msr oslar_el1, x11 |
Lorenzo Pieralisi | f436b2a | 2016-01-13 14:50:03 +0000 | [diff] [blame] | 120 | reset_pmuserenr_el0 x0 // Disable PMU access from EL0 |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 121 | isb |
| 122 | ret |
| 123 | ENDPROC(cpu_do_resume) |
James Morse | b611303 | 2016-08-24 18:27:29 +0100 | [diff] [blame] | 124 | .popsection |
Lorenzo Pieralisi | 6732bc6 | 2013-07-17 10:14:45 +0100 | [diff] [blame] | 125 | #endif |
| 126 | |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 127 | /* |
Jingoo Han | 812944e | 2014-01-27 07:19:32 +0000 | [diff] [blame] | 128 | * cpu_do_switch_mm(pgd_phys, tsk) |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 129 | * |
| 130 | * Set the translation table base pointer to be pgd_phys. |
| 131 | * |
| 132 | * - pgd_phys - physical address of new TTB |
| 133 | */ |
| 134 | ENTRY(cpu_do_switch_mm) |
Will Deacon | 984e60a | 2018-04-03 12:08:58 +0100 | [diff] [blame] | 135 | mrs x2, ttbr1_el1 |
Will Deacon | 5aec715 | 2015-10-06 18:46:24 +0100 | [diff] [blame] | 136 | mmid x1, x1 // get mm->context.id |
Will Deacon | 984e60a | 2018-04-03 12:08:58 +0100 | [diff] [blame] | 137 | bfi x2, x1, #48, #16 // set the ASID |
| 138 | msr ttbr1_el1, x2 // in TTBR1 (since TCR.A1 is set) |
| 139 | isb |
| 140 | msr ttbr0_el1, x0 // now update TTBR0 |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 141 | isb |
Mark Rutland | 6ba3b55 | 2016-09-07 11:07:09 +0100 | [diff] [blame] | 142 | alternative_if ARM64_WORKAROUND_CAVIUM_27456 |
Andrew Pinski | 104a0c0 | 2016-02-24 17:44:57 -0800 | [diff] [blame] | 143 | ic iallu |
| 144 | dsb nsh |
| 145 | isb |
Mark Rutland | 6ba3b55 | 2016-09-07 11:07:09 +0100 | [diff] [blame] | 146 | alternative_else_nop_endif |
Andrew Pinski | 104a0c0 | 2016-02-24 17:44:57 -0800 | [diff] [blame] | 147 | ret |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 148 | ENDPROC(cpu_do_switch_mm) |
| 149 | |
Will Deacon | 574e44d | 2018-04-03 12:09:23 +0100 | [diff] [blame^] | 150 | .pushsection ".idmap.text", "awx" |
Will Deacon | 4025fe1 | 2018-04-03 12:09:20 +0100 | [diff] [blame] | 151 | |
| 152 | .macro __idmap_cpu_set_reserved_ttbr1, tmp1, tmp2 |
| 153 | adrp \tmp1, empty_zero_page |
| 154 | msr ttbr1_el1, \tmp1 |
| 155 | isb |
| 156 | tlbi vmalle1 |
| 157 | dsb nsh |
| 158 | isb |
| 159 | .endm |
| 160 | |
Mark Rutland | 50e1881 | 2016-01-25 11:45:01 +0000 | [diff] [blame] | 161 | /* |
| 162 | * void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd) |
| 163 | * |
| 164 | * This is the low-level counterpart to cpu_replace_ttbr1, and should not be |
| 165 | * called by anything else. It can only be executed from a TTBR0 mapping. |
| 166 | */ |
| 167 | ENTRY(idmap_cpu_replace_ttbr1) |
| 168 | mrs x2, daif |
| 169 | msr daifset, #0xf |
| 170 | |
Will Deacon | 4025fe1 | 2018-04-03 12:09:20 +0100 | [diff] [blame] | 171 | __idmap_cpu_set_reserved_ttbr1 x1, x3 |
Mark Rutland | 50e1881 | 2016-01-25 11:45:01 +0000 | [diff] [blame] | 172 | |
| 173 | msr ttbr1_el1, x0 |
| 174 | isb |
| 175 | |
| 176 | msr daif, x2 |
| 177 | |
| 178 | ret |
| 179 | ENDPROC(idmap_cpu_replace_ttbr1) |
| 180 | .popsection |
| 181 | |
Will Deacon | 4025fe1 | 2018-04-03 12:09:20 +0100 | [diff] [blame] | 182 | #ifdef CONFIG_UNMAP_KERNEL_AT_EL0 |
Will Deacon | 574e44d | 2018-04-03 12:09:23 +0100 | [diff] [blame^] | 183 | .pushsection ".idmap.text", "awx" |
Will Deacon | 4025fe1 | 2018-04-03 12:09:20 +0100 | [diff] [blame] | 184 | |
| 185 | .macro __idmap_kpti_get_pgtable_ent, type |
| 186 | dc cvac, cur_\()\type\()p // Ensure any existing dirty |
| 187 | dmb sy // lines are written back before |
| 188 | ldr \type, [cur_\()\type\()p] // loading the entry |
| 189 | tbz \type, #0, next_\()\type // Skip invalid entries |
| 190 | .endm |
| 191 | |
| 192 | .macro __idmap_kpti_put_pgtable_ent_ng, type |
| 193 | orr \type, \type, #PTE_NG // Same bit for blocks and pages |
| 194 | str \type, [cur_\()\type\()p] // Update the entry and ensure it |
| 195 | dc civac, cur_\()\type\()p // is visible to all CPUs. |
| 196 | .endm |
| 197 | |
| 198 | /* |
| 199 | * void __kpti_install_ng_mappings(int cpu, int num_cpus, phys_addr_t swapper) |
| 200 | * |
| 201 | * Called exactly once from stop_machine context by each CPU found during boot. |
| 202 | */ |
| 203 | __idmap_kpti_flag: |
| 204 | .long 1 |
| 205 | ENTRY(idmap_kpti_install_ng_mappings) |
| 206 | cpu .req w0 |
| 207 | num_cpus .req w1 |
| 208 | swapper_pa .req x2 |
| 209 | swapper_ttb .req x3 |
| 210 | flag_ptr .req x4 |
| 211 | cur_pgdp .req x5 |
| 212 | end_pgdp .req x6 |
| 213 | pgd .req x7 |
| 214 | cur_pudp .req x8 |
| 215 | end_pudp .req x9 |
| 216 | pud .req x10 |
| 217 | cur_pmdp .req x11 |
| 218 | end_pmdp .req x12 |
| 219 | pmd .req x13 |
| 220 | cur_ptep .req x14 |
| 221 | end_ptep .req x15 |
| 222 | pte .req x16 |
| 223 | |
| 224 | mrs swapper_ttb, ttbr1_el1 |
| 225 | adr flag_ptr, __idmap_kpti_flag |
| 226 | |
| 227 | cbnz cpu, __idmap_kpti_secondary |
| 228 | |
| 229 | /* We're the boot CPU. Wait for the others to catch up */ |
| 230 | sevl |
| 231 | 1: wfe |
| 232 | ldaxr w18, [flag_ptr] |
| 233 | eor w18, w18, num_cpus |
| 234 | cbnz w18, 1b |
| 235 | |
| 236 | /* We need to walk swapper, so turn off the MMU. */ |
| 237 | mrs x18, sctlr_el1 |
| 238 | bic x18, x18, #SCTLR_ELx_M |
| 239 | msr sctlr_el1, x18 |
| 240 | isb |
| 241 | |
| 242 | /* Everybody is enjoying the idmap, so we can rewrite swapper. */ |
| 243 | /* PGD */ |
| 244 | mov cur_pgdp, swapper_pa |
| 245 | add end_pgdp, cur_pgdp, #(PTRS_PER_PGD * 8) |
| 246 | do_pgd: __idmap_kpti_get_pgtable_ent pgd |
| 247 | tbnz pgd, #1, walk_puds |
| 248 | __idmap_kpti_put_pgtable_ent_ng pgd |
| 249 | next_pgd: |
| 250 | add cur_pgdp, cur_pgdp, #8 |
| 251 | cmp cur_pgdp, end_pgdp |
| 252 | b.ne do_pgd |
| 253 | |
| 254 | /* Publish the updated tables and nuke all the TLBs */ |
| 255 | dsb sy |
| 256 | tlbi vmalle1is |
| 257 | dsb ish |
| 258 | isb |
| 259 | |
| 260 | /* We're done: fire up the MMU again */ |
| 261 | mrs x18, sctlr_el1 |
| 262 | orr x18, x18, #SCTLR_ELx_M |
| 263 | msr sctlr_el1, x18 |
| 264 | isb |
| 265 | |
| 266 | /* Set the flag to zero to indicate that we're all done */ |
| 267 | str wzr, [flag_ptr] |
| 268 | ret |
| 269 | |
| 270 | /* PUD */ |
| 271 | walk_puds: |
| 272 | .if CONFIG_PGTABLE_LEVELS > 3 |
| 273 | pte_to_phys cur_pudp, pgd |
| 274 | add end_pudp, cur_pudp, #(PTRS_PER_PUD * 8) |
| 275 | do_pud: __idmap_kpti_get_pgtable_ent pud |
| 276 | tbnz pud, #1, walk_pmds |
| 277 | __idmap_kpti_put_pgtable_ent_ng pud |
| 278 | next_pud: |
| 279 | add cur_pudp, cur_pudp, 8 |
| 280 | cmp cur_pudp, end_pudp |
| 281 | b.ne do_pud |
| 282 | b next_pgd |
| 283 | .else /* CONFIG_PGTABLE_LEVELS <= 3 */ |
| 284 | mov pud, pgd |
| 285 | b walk_pmds |
| 286 | next_pud: |
| 287 | b next_pgd |
| 288 | .endif |
| 289 | |
| 290 | /* PMD */ |
| 291 | walk_pmds: |
| 292 | .if CONFIG_PGTABLE_LEVELS > 2 |
| 293 | pte_to_phys cur_pmdp, pud |
| 294 | add end_pmdp, cur_pmdp, #(PTRS_PER_PMD * 8) |
| 295 | do_pmd: __idmap_kpti_get_pgtable_ent pmd |
| 296 | tbnz pmd, #1, walk_ptes |
| 297 | __idmap_kpti_put_pgtable_ent_ng pmd |
| 298 | next_pmd: |
| 299 | add cur_pmdp, cur_pmdp, #8 |
| 300 | cmp cur_pmdp, end_pmdp |
| 301 | b.ne do_pmd |
| 302 | b next_pud |
| 303 | .else /* CONFIG_PGTABLE_LEVELS <= 2 */ |
| 304 | mov pmd, pud |
| 305 | b walk_ptes |
| 306 | next_pmd: |
| 307 | b next_pud |
| 308 | .endif |
| 309 | |
| 310 | /* PTE */ |
| 311 | walk_ptes: |
| 312 | pte_to_phys cur_ptep, pmd |
| 313 | add end_ptep, cur_ptep, #(PTRS_PER_PTE * 8) |
| 314 | do_pte: __idmap_kpti_get_pgtable_ent pte |
| 315 | __idmap_kpti_put_pgtable_ent_ng pte |
| 316 | next_pte: |
| 317 | add cur_ptep, cur_ptep, #8 |
| 318 | cmp cur_ptep, end_ptep |
| 319 | b.ne do_pte |
| 320 | b next_pmd |
| 321 | |
| 322 | /* Secondary CPUs end up here */ |
| 323 | __idmap_kpti_secondary: |
| 324 | /* Uninstall swapper before surgery begins */ |
| 325 | __idmap_cpu_set_reserved_ttbr1 x18, x17 |
| 326 | |
| 327 | /* Increment the flag to let the boot CPU we're ready */ |
| 328 | 1: ldxr w18, [flag_ptr] |
| 329 | add w18, w18, #1 |
| 330 | stxr w17, w18, [flag_ptr] |
| 331 | cbnz w17, 1b |
| 332 | |
| 333 | /* Wait for the boot CPU to finish messing around with swapper */ |
| 334 | sevl |
| 335 | 1: wfe |
| 336 | ldxr w18, [flag_ptr] |
| 337 | cbnz w18, 1b |
| 338 | |
| 339 | /* All done, act like nothing happened */ |
| 340 | msr ttbr1_el1, swapper_ttb |
| 341 | isb |
| 342 | ret |
| 343 | |
| 344 | .unreq cpu |
| 345 | .unreq num_cpus |
| 346 | .unreq swapper_pa |
| 347 | .unreq swapper_ttb |
| 348 | .unreq flag_ptr |
| 349 | .unreq cur_pgdp |
| 350 | .unreq end_pgdp |
| 351 | .unreq pgd |
| 352 | .unreq cur_pudp |
| 353 | .unreq end_pudp |
| 354 | .unreq pud |
| 355 | .unreq cur_pmdp |
| 356 | .unreq end_pmdp |
| 357 | .unreq pmd |
| 358 | .unreq cur_ptep |
| 359 | .unreq end_ptep |
| 360 | .unreq pte |
| 361 | ENDPROC(idmap_kpti_install_ng_mappings) |
| 362 | .popsection |
| 363 | #endif |
| 364 | |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 365 | /* |
| 366 | * __cpu_setup |
| 367 | * |
| 368 | * Initialise the processor for turning the MMU on. Return in x0 the |
| 369 | * value of the SCTLR_EL1 register. |
| 370 | */ |
Will Deacon | 574e44d | 2018-04-03 12:09:23 +0100 | [diff] [blame^] | 371 | .pushsection ".idmap.text", "awx" |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 372 | ENTRY(__cpu_setup) |
Will Deacon | fa7aae8 | 2015-10-06 18:46:22 +0100 | [diff] [blame] | 373 | tlbi vmalle1 // Invalidate local TLB |
| 374 | dsb nsh |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 375 | |
| 376 | mov x0, #3 << 20 |
| 377 | msr cpacr_el1, x0 // Enable FP/ASIMD |
Will Deacon | d8d23fa | 2015-08-20 11:47:13 +0100 | [diff] [blame] | 378 | mov x0, #1 << 12 // Reset mdscr_el1 and disable |
| 379 | msr mdscr_el1, x0 // access to the DCC from EL0 |
Will Deacon | 2ce39ad | 2016-07-19 15:07:37 +0100 | [diff] [blame] | 380 | isb // Unmask debug exceptions now, |
| 381 | enable_dbg // since this is per-cpu |
Lorenzo Pieralisi | f436b2a | 2016-01-13 14:50:03 +0000 | [diff] [blame] | 382 | reset_pmuserenr_el0 x0 // Disable PMU access from EL0 |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 383 | /* |
| 384 | * Memory region attributes for LPAE: |
| 385 | * |
| 386 | * n = AttrIndx[2:0] |
| 387 | * n MAIR |
| 388 | * DEVICE_nGnRnE 000 00000000 |
| 389 | * DEVICE_nGnRE 001 00000100 |
| 390 | * DEVICE_GRE 010 00001100 |
| 391 | * NORMAL_NC 011 01000100 |
| 392 | * NORMAL 100 11111111 |
Jonathan (Zhixiong) Zhang | 8d446c8 | 2015-08-07 09:36:59 +0100 | [diff] [blame] | 393 | * NORMAL_WT 101 10111011 |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 394 | */ |
| 395 | ldr x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \ |
| 396 | MAIR(0x04, MT_DEVICE_nGnRE) | \ |
| 397 | MAIR(0x0c, MT_DEVICE_GRE) | \ |
| 398 | MAIR(0x44, MT_NORMAL_NC) | \ |
Jonathan (Zhixiong) Zhang | 8d446c8 | 2015-08-07 09:36:59 +0100 | [diff] [blame] | 399 | MAIR(0xff, MT_NORMAL) | \ |
| 400 | MAIR(0xbb, MT_NORMAL_WT) |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 401 | msr mair_el1, x5 |
| 402 | /* |
| 403 | * Prepare SCTLR |
| 404 | */ |
| 405 | adr x5, crval |
| 406 | ldp w5, w6, [x5] |
| 407 | mrs x0, sctlr_el1 |
| 408 | bic x0, x0, x5 // clear bits |
| 409 | orr x0, x0, x6 // set bits |
| 410 | /* |
| 411 | * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for |
| 412 | * both user and kernel. |
| 413 | */ |
Catalin Marinas | 35a8697 | 2014-04-02 17:55:40 +0100 | [diff] [blame] | 414 | ldr x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \ |
Will Deacon | 984e60a | 2018-04-03 12:08:58 +0100 | [diff] [blame] | 415 | TCR_TG_FLAGS | TCR_ASID16 | TCR_TBI0 | TCR_A1 |
Ard Biesheuvel | dd006da | 2015-03-19 16:42:27 +0000 | [diff] [blame] | 416 | tcr_set_idmap_t0sz x10, x9 |
| 417 | |
Radha Mohan Chintakuntla | 87366d8 | 2014-03-07 08:49:25 +0000 | [diff] [blame] | 418 | /* |
| 419 | * Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in |
| 420 | * TCR_EL1. |
| 421 | */ |
| 422 | mrs x9, ID_AA64MMFR0_EL1 |
| 423 | bfi x10, x9, #32, #3 |
Catalin Marinas | 2f4b829 | 2015-07-10 17:24:28 +0100 | [diff] [blame] | 424 | #ifdef CONFIG_ARM64_HW_AFDBM |
| 425 | /* |
| 426 | * Hardware update of the Access and Dirty bits. |
| 427 | */ |
| 428 | mrs x9, ID_AA64MMFR1_EL1 |
| 429 | and x9, x9, #0xf |
| 430 | cbz x9, 2f |
| 431 | cmp x9, #2 |
| 432 | b.lt 1f |
| 433 | orr x10, x10, #TCR_HD // hardware Dirty flag update |
| 434 | 1: orr x10, x10, #TCR_HA // hardware Access flag update |
| 435 | 2: |
| 436 | #endif /* CONFIG_ARM64_HW_AFDBM */ |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 437 | msr tcr_el1, x10 |
| 438 | ret // return to head.S |
| 439 | ENDPROC(__cpu_setup) |
| 440 | |
| 441 | /* |
Suzuki K. Poulose | 9f71ac9 | 2014-12-17 15:50:21 +0000 | [diff] [blame] | 442 | * We set the desired value explicitly, including those of the |
| 443 | * reserved bits. The values of bits EE & E0E were set early in |
| 444 | * el2_setup, which are left untouched below. |
| 445 | * |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 446 | * n n T |
| 447 | * U E WT T UD US IHBS |
| 448 | * CE0 XWHW CZ ME TEEA S |
| 449 | * .... .IEE .... NEAI TE.I ..AD DEN0 ACAM |
Suzuki K. Poulose | 9f71ac9 | 2014-12-17 15:50:21 +0000 | [diff] [blame] | 450 | * 0011 0... 1101 ..0. ..0. 10.. .0.. .... < hardware reserved |
| 451 | * .... .1.. .... 01.1 11.1 ..01 0.01 1101 < software settings |
Catalin Marinas | 9cce7a4 | 2012-03-05 11:49:28 +0000 | [diff] [blame] | 452 | */ |
| 453 | .type crval, #object |
| 454 | crval: |
Suzuki K. Poulose | 9f71ac9 | 2014-12-17 15:50:21 +0000 | [diff] [blame] | 455 | .word 0xfcffffff // clear |
| 456 | .word 0x34d5d91d // set |
James Morse | b611303 | 2016-08-24 18:27:29 +0100 | [diff] [blame] | 457 | .popsection |