mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 1 | # Copyright 2016 Google Inc. |
| 2 | # |
| 3 | # Use of this source code is governed by a BSD-style license that can be |
| 4 | # found in the LICENSE file. |
| 5 | |
mikejurka | 8c24f4f | 2016-09-12 16:51:58 -0700 | [diff] [blame] | 6 | import("gn/shared_sources.gni") |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 7 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 8 | declare_args() { |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 9 | skia_enable_tools = !is_fuchsia && !is_component_build |
| 10 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 11 | skia_use_expat = true |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 12 | skia_use_fontconfig = is_linux |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 13 | skia_use_freetype = is_android || is_fuchsia || is_linux |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 14 | skia_use_giflib = !is_fuchsia |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 15 | skia_use_libjpeg_turbo = true |
| 16 | skia_use_libpng = true |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 17 | skia_use_libwebp = !is_fuchsia |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 18 | skia_use_sfntly = !is_fuchsia |
mtklein | f29180e | 2016-09-16 07:01:17 -0700 | [diff] [blame] | 19 | skia_use_vulkan = is_android && defined(ndk_api) && ndk_api >= 24 |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 20 | skia_use_zlib = true |
mtklein | 1bd72ba | 2016-09-16 07:45:52 -0700 | [diff] [blame] | 21 | |
| 22 | skia_enable_android_framework_defines = false |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 23 | } |
| 24 | |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 25 | fontmgr_android_enabled = skia_use_expat && skia_use_freetype |
| 26 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 27 | skia_public_includes = [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 28 | "include/android", |
mtklein | fa84d94 | 2016-07-28 09:45:14 -0700 | [diff] [blame] | 29 | "include/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 30 | "include/codec", |
| 31 | "include/config", |
| 32 | "include/core", |
| 33 | "include/effects", |
| 34 | "include/gpu", |
| 35 | "include/gpu/gl", |
| 36 | "include/images", |
| 37 | "include/pathops", |
| 38 | "include/ports", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 39 | "include/svg", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 40 | "include/utils", |
| 41 | "include/utils/mac", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 42 | "include/xml", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 43 | ] |
| 44 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 45 | # Skia public API, generally provided by :skia. |
| 46 | config("skia_public") { |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 47 | include_dirs = skia_public_includes |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 48 | defines = [ "SKIA_DLL" ] |
jcgregorio | 5561e3d | 2016-08-25 09:25:11 -0700 | [diff] [blame] | 49 | if (is_linux) { |
| 50 | defines += [ "SK_SAMPLES_FOR_X" ] |
| 51 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 52 | } |
| 53 | |
| 54 | # Skia internal APIs, used by Skia itself and a few test tools. |
| 55 | config("skia_private") { |
| 56 | visibility = [ ":*" ] |
| 57 | |
| 58 | include_dirs = [ |
| 59 | "include/private", |
| 60 | "src/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 61 | "src/codec", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 62 | "src/config", |
| 63 | "src/core", |
| 64 | "src/effects", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 65 | "src/effects/gradients", |
| 66 | "src/fonts", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 67 | "src/gpu", |
| 68 | "src/image", |
| 69 | "src/images", |
| 70 | "src/lazy", |
| 71 | "src/opts", |
| 72 | "src/pathops", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 73 | "src/pdf", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 74 | "src/ports", |
| 75 | "src/sfnt", |
mtklein | 9e0d9dd | 2016-08-30 10:37:19 -0700 | [diff] [blame] | 76 | "src/sksl", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 77 | "src/utils", |
mtklein | 7a1f45f | 2016-08-04 06:19:33 -0700 | [diff] [blame] | 78 | "src/utils/win", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 79 | "third_party/etc1", |
| 80 | "third_party/ktx", |
| 81 | ] |
mtklein | 150d113 | 2016-08-01 06:56:40 -0700 | [diff] [blame] | 82 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 83 | defines = [ "SK_GAMMA_APPLY_TO_A8" ] |
mtklein | b37c034 | 2016-09-09 11:07:45 -0700 | [diff] [blame] | 84 | if (is_android) { |
| 85 | defines += [ |
| 86 | "SK_GAMMA_EXPONENT=1.4", |
| 87 | "SK_GAMMA_CONTRAST=0.0", |
| 88 | ] |
| 89 | } |
mtklein | 88a7ac0 | 2016-09-14 11:16:49 -0700 | [diff] [blame] | 90 | if (is_official_build || is_android) { |
| 91 | # TODO(bsalomon): it'd be nice to make Android normal. |
| 92 | defines += [ "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0" ] |
| 93 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 94 | } |
| 95 | |
| 96 | # Any code that's linked into Skia-the-library should use this config via += skia_library_configs. |
| 97 | config("skia_library") { |
| 98 | visibility = [ ":*" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 99 | defines = [ "SKIA_IMPLEMENTATION=1" ] |
| 100 | } |
| 101 | |
| 102 | skia_library_configs = [ |
| 103 | ":skia_public", |
| 104 | ":skia_private", |
| 105 | ":skia_library", |
| 106 | ] |
| 107 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 108 | # Use for CPU-specific Skia code that needs particular compiler flags. |
| 109 | template("opts") { |
| 110 | if (invoker.enabled) { |
| 111 | source_set(target_name) { |
| 112 | forward_variables_from(invoker, "*") |
| 113 | configs += skia_library_configs |
| 114 | } |
| 115 | } else { |
| 116 | # If not enabled, a phony empty target that swallows all otherwise unused variables. |
| 117 | source_set(target_name) { |
| 118 | forward_variables_from(invoker, |
| 119 | "*", |
| 120 | [ |
| 121 | "sources", |
| 122 | "cflags", |
| 123 | ]) |
| 124 | } |
| 125 | } |
anmittal | a7eaf2e | 2016-08-17 13:57:26 -0700 | [diff] [blame] | 126 | } |
| 127 | |
mtklein | 422310d | 2016-08-16 18:28:43 -0700 | [diff] [blame] | 128 | is_x86 = current_cpu == "x64" || current_cpu == "x86" |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 129 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 130 | opts("none") { |
| 131 | enabled = !is_x86 && current_cpu != "arm" && current_cpu != "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 132 | sources = skia_opts.none_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 133 | cflags = [] |
| 134 | } |
| 135 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 136 | opts("armv7") { |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 137 | enabled = current_cpu == "arm" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 138 | sources = skia_opts.armv7_sources + skia_opts.neon_sources |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 139 | cflags = [] |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 140 | } |
| 141 | |
| 142 | opts("arm64") { |
| 143 | enabled = current_cpu == "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 144 | sources = skia_opts.arm64_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 145 | cflags = [] |
| 146 | } |
| 147 | |
| 148 | opts("crc32") { |
| 149 | enabled = current_cpu == "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 150 | sources = skia_opts.crc32_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 151 | cflags = [ "-march=armv8-a+crc" ] |
| 152 | } |
| 153 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 154 | opts("sse2") { |
| 155 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 156 | sources = skia_opts.sse2_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 157 | cflags = [ "-msse2" ] |
| 158 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 159 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 160 | opts("ssse3") { |
| 161 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 162 | sources = skia_opts.ssse3_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 163 | cflags = [ "-mssse3" ] |
| 164 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 165 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 166 | opts("sse41") { |
| 167 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 168 | sources = skia_opts.sse41_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 169 | cflags = [ "-msse4.1" ] |
| 170 | } |
mtklein | 4e97607 | 2016-08-08 09:06:27 -0700 | [diff] [blame] | 171 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 172 | opts("sse42") { |
| 173 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 174 | sources = skia_opts.sse42_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 175 | cflags = [ "-msse4.2" ] |
| 176 | } |
| 177 | |
| 178 | opts("avx") { |
| 179 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 180 | sources = skia_opts.avx_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 181 | cflags = [ "-mavx" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 182 | } |
| 183 | |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 184 | opts("dsp") { |
| 185 | enabled = current_cpu == "mipsel" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 186 | sources = skia_opts.mips_dsp_sources |
mtklein | b6064ef | 2016-08-30 11:49:24 -0700 | [diff] [blame] | 187 | cflags = [] |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 188 | } |
| 189 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 190 | # Any feature of Skia that requires third-party code should be optional and use this template. |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 191 | template("optional") { |
| 192 | if (invoker.enabled) { |
| 193 | config(target_name + "_public") { |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 194 | if (defined(invoker.public_defines)) { |
| 195 | defines = invoker.public_defines |
| 196 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 197 | } |
| 198 | source_set(target_name) { |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 199 | forward_variables_from(invoker, |
| 200 | "*", |
| 201 | [ |
| 202 | "public_defines", |
| 203 | "sources_when_disabled", |
| 204 | ]) |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 205 | all_dependent_configs = [ ":" + target_name + "_public" ] |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 206 | configs += skia_library_configs |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 207 | } |
| 208 | } else { |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 209 | source_set(target_name) { |
| 210 | forward_variables_from(invoker, |
| 211 | "*", |
| 212 | [ |
| 213 | "public_defines", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 214 | "deps", |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 215 | "libs", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 216 | "sources", |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 217 | "sources_when_disabled", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 218 | ]) |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 219 | if (defined(invoker.sources_when_disabled)) { |
| 220 | sources = invoker.sources_when_disabled |
| 221 | } |
| 222 | configs += skia_library_configs |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 223 | } |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 224 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 225 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 226 | |
mtklein | 1bd72ba | 2016-09-16 07:45:52 -0700 | [diff] [blame] | 227 | optional("android_framework_defines") { |
| 228 | enabled = skia_enable_android_framework_defines |
| 229 | public_defines = skia_android_framework_defines |
| 230 | } |
| 231 | |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 232 | optional("fontmgr_android") { |
| 233 | enabled = fontmgr_android_enabled |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 234 | |
| 235 | deps = [ |
| 236 | "//third_party/expat", |
| 237 | "//third_party/freetype2", |
| 238 | ] |
| 239 | sources = [ |
| 240 | "src/ports/SkFontMgr_android.cpp", |
| 241 | "src/ports/SkFontMgr_android_factory.cpp", |
| 242 | "src/ports/SkFontMgr_android_parser.cpp", |
| 243 | ] |
| 244 | } |
| 245 | |
mtklein | d2e39db | 2016-09-07 07:52:55 -0700 | [diff] [blame] | 246 | optional("fontmgr_custom") { |
| 247 | enabled = is_linux && skia_use_freetype && !skia_use_fontconfig |
| 248 | |
| 249 | deps = [ |
| 250 | "//third_party/freetype2", |
| 251 | ] |
| 252 | sources = [ |
| 253 | "src/ports/SkFontMgr_custom.cpp", |
| 254 | "src/ports/SkFontMgr_custom_directory_factory.cpp", |
| 255 | ] |
| 256 | } |
| 257 | |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 258 | optional("fontmgr_fontconfig") { |
| 259 | enabled = skia_use_freetype && skia_use_fontconfig |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 260 | |
| 261 | deps = [ |
| 262 | "//third_party:fontconfig", |
| 263 | "//third_party/freetype2", |
| 264 | ] |
| 265 | sources = [ |
bungeman | 1ae0e01 | 2016-09-19 12:13:16 -0700 | [diff] [blame^] | 266 | "src/ports/SkFontConfigInterface.cpp", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 267 | "src/ports/SkFontConfigInterface_direct.cpp", |
| 268 | "src/ports/SkFontConfigInterface_direct_factory.cpp", |
| 269 | "src/ports/SkFontMgr_FontConfigInterface.cpp", |
| 270 | "src/ports/SkFontMgr_fontconfig.cpp", |
| 271 | "src/ports/SkFontMgr_fontconfig_factory.cpp", |
| 272 | ] |
| 273 | } |
| 274 | |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 275 | optional("fontmgr_fuchsia") { |
| 276 | enabled = is_fuchsia && skia_use_freetype |
| 277 | |
| 278 | deps = [ |
| 279 | "//third_party/freetype2", |
| 280 | ] |
| 281 | sources = [ |
| 282 | "src/ports/SkFontMgr_custom.cpp", |
| 283 | "src/ports/SkFontMgr_custom_empty_factory.cpp", |
| 284 | ] |
| 285 | } |
| 286 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 287 | optional("gif") { |
| 288 | enabled = skia_use_giflib |
| 289 | public_defines = [ "SK_HAS_GIF_LIBRARY" ] |
| 290 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 291 | deps = [ |
| 292 | "//third_party/giflib", |
| 293 | ] |
| 294 | sources = [ |
| 295 | "src/codec/SkGifCodec.cpp", |
| 296 | ] |
| 297 | } |
| 298 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 299 | optional("jpeg") { |
| 300 | enabled = skia_use_libjpeg_turbo |
| 301 | public_defines = [ "SK_HAS_JPEG_LIBRARY" ] |
| 302 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 303 | deps = [ |
| 304 | "//third_party/libjpeg-turbo:libjpeg", |
| 305 | ] |
| 306 | sources = [ |
| 307 | "src/codec/SkJpegCodec.cpp", |
| 308 | "src/codec/SkJpegDecoderMgr.cpp", |
| 309 | "src/codec/SkJpegUtility.cpp", |
| 310 | "src/images/SkJPEGImageEncoder.cpp", |
| 311 | "src/images/SkJPEGWriteUtility.cpp", |
| 312 | ] |
| 313 | } |
| 314 | |
| 315 | optional("pdf") { |
| 316 | enabled = skia_use_zlib |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 317 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 318 | deps = [ |
| 319 | "//third_party/zlib", |
| 320 | ] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 321 | sources = skia_pdf_sources |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 322 | sources_when_disabled = [ "src/pdf/SkDocument_PDF_None.cpp" ] |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 323 | |
| 324 | if (skia_use_sfntly) { |
| 325 | deps += [ "//third_party/sfntly" ] |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 326 | public_defines = [ "SK_PDF_USE_SFNTLY" ] |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 327 | } |
| 328 | } |
| 329 | |
| 330 | optional("png") { |
| 331 | enabled = skia_use_libpng |
| 332 | public_defines = [ "SK_HAS_PNG_LIBRARY" ] |
| 333 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 334 | deps = [ |
| 335 | "//third_party/libpng", |
| 336 | ] |
| 337 | sources = [ |
| 338 | "src/codec/SkIcoCodec.cpp", |
| 339 | "src/codec/SkPngCodec.cpp", |
| 340 | "src/images/SkPNGImageEncoder.cpp", |
| 341 | ] |
| 342 | } |
| 343 | |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 344 | optional("typeface_freetype") { |
| 345 | enabled = skia_use_freetype |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 346 | |
| 347 | deps = [ |
| 348 | "//third_party/freetype2", |
| 349 | ] |
| 350 | sources = [ |
| 351 | "src/ports/SkFontHost_FreeType.cpp", |
| 352 | "src/ports/SkFontHost_FreeType_common.cpp", |
| 353 | ] |
| 354 | } |
| 355 | |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 356 | optional("vulkan") { |
| 357 | enabled = skia_use_vulkan |
| 358 | public_defines = [ "SK_VULKAN" ] |
| 359 | libs = [ "vulkan" ] |
| 360 | sources = skia_vk_sources |
| 361 | } |
| 362 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 363 | optional("webp") { |
| 364 | enabled = skia_use_libwebp |
| 365 | public_defines = [ "SK_HAS_WEBP_LIBRARY" ] |
| 366 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 367 | deps = [ |
| 368 | "//third_party/libwebp", |
| 369 | ] |
| 370 | sources = [ |
| 371 | "src/codec/SkWebpAdapterCodec.cpp", |
| 372 | "src/codec/SkWebpCodec.cpp", |
| 373 | "src/images/SkWEBPImageEncoder.cpp", |
| 374 | ] |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 375 | } |
| 376 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 377 | optional("xml") { |
| 378 | enabled = skia_use_expat |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 379 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 380 | deps = [ |
| 381 | "//third_party/expat", |
| 382 | ] |
| 383 | sources = [ |
| 384 | "src/xml/SkDOM.cpp", |
| 385 | "src/xml/SkXMLParser.cpp", |
| 386 | "src/xml/SkXMLWriter.cpp", |
| 387 | ] |
| 388 | } |
| 389 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 390 | component("skia") { |
| 391 | public_configs = [ ":skia_public" ] |
| 392 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 393 | |
| 394 | deps = [ |
mtklein | 1bd72ba | 2016-09-16 07:45:52 -0700 | [diff] [blame] | 395 | ":android_framework_defines", |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 396 | ":arm64", |
| 397 | ":armv7", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 398 | ":avx", |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 399 | ":crc32", |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 400 | ":dsp", |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 401 | ":fontmgr_android", |
mtklein | d2e39db | 2016-09-07 07:52:55 -0700 | [diff] [blame] | 402 | ":fontmgr_custom", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 403 | ":fontmgr_fontconfig", |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 404 | ":fontmgr_fuchsia", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 405 | ":gif", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 406 | ":jpeg", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 407 | ":none", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 408 | ":pdf", |
| 409 | ":png", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 410 | ":sse2", |
| 411 | ":sse41", |
| 412 | ":sse42", |
| 413 | ":ssse3", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 414 | ":typeface_freetype", |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 415 | ":vulkan", |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 416 | ":webp", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 417 | ":xml", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 418 | ] |
| 419 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 420 | sources = [] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 421 | sources += skia_core_sources |
| 422 | sources += skia_effects_sources |
| 423 | sources += skia_gpu_sources |
| 424 | sources += skia_sksl_sources |
| 425 | sources += skia_utils_sources |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 426 | sources += [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 427 | "src/android/SkBitmapRegionCodec.cpp", |
| 428 | "src/android/SkBitmapRegionDecoder.cpp", |
| 429 | "src/codec/SkAndroidCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 430 | "src/codec/SkBmpCodec.cpp", |
| 431 | "src/codec/SkBmpMaskCodec.cpp", |
| 432 | "src/codec/SkBmpRLECodec.cpp", |
| 433 | "src/codec/SkBmpStandardCodec.cpp", |
| 434 | "src/codec/SkCodec.cpp", |
| 435 | "src/codec/SkCodecImageGenerator.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 436 | "src/codec/SkMaskSwizzler.cpp", |
| 437 | "src/codec/SkMasks.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 438 | "src/codec/SkSampledCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 439 | "src/codec/SkSampler.cpp", |
| 440 | "src/codec/SkSwizzler.cpp", |
| 441 | "src/codec/SkWbmpCodec.cpp", |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 442 | "src/gpu/gl/GrGLDefaultInterface_native.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 443 | "src/images/SkImageEncoder.cpp", |
| 444 | "src/images/SkImageEncoder_Factory.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 445 | "src/images/SkKTXImageEncoder.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 446 | "src/ports/SkDiscardableMemory_none.cpp", |
| 447 | "src/ports/SkGlobalInitialization_default.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 448 | "src/ports/SkImageGenerator_skia.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 449 | "src/ports/SkMemory_malloc.cpp", |
| 450 | "src/ports/SkOSFile_stdio.cpp", |
| 451 | "src/sfnt/SkOTTable_name.cpp", |
| 452 | "src/sfnt/SkOTUtils.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 453 | "src/svg/SkSVGCanvas.cpp", |
| 454 | "src/svg/SkSVGDevice.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 455 | "src/utils/mac/SkStream_mac.cpp", |
| 456 | "third_party/etc1/etc1.cpp", |
| 457 | "third_party/ktx/ktx.cpp", |
| 458 | ] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 459 | |
| 460 | # These paths need to be absolute to match the ones produced by |
| 461 | # shared_sources.gni, but this file may be used from different directory |
| 462 | # locations. |
| 463 | sources -= get_path_info([ |
| 464 | "src/gpu/gl/GrGLCreateNativeInterface_none.cpp", |
| 465 | "src/gpu/gl/GrGLDefaultInterface_none.cpp", |
| 466 | ], |
| 467 | "abspath") |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 468 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 469 | libs = [] |
| 470 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 471 | if (is_win) { |
| 472 | sources += [ |
| 473 | "src/ports/SkDebug_win.cpp", |
| 474 | "src/ports/SkFontHost_win.cpp", |
| 475 | "src/ports/SkFontMgr_win_dw.cpp", |
| 476 | "src/ports/SkFontMgr_win_dw_factory.cpp", |
| 477 | "src/ports/SkImageEncoder_WIC.cpp", |
| 478 | "src/ports/SkImageGeneratorWIC.cpp", |
| 479 | "src/ports/SkOSFile_win.cpp", |
| 480 | "src/ports/SkScalerContext_win_dw.cpp", |
| 481 | "src/ports/SkTLS_win.cpp", |
| 482 | "src/ports/SkTypeface_win_dw.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 483 | "src/xps/SkDocument_XPS.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 484 | ] |
mtklein | b9be979 | 2016-09-16 14:44:18 -0700 | [diff] [blame] | 485 | sources -= |
| 486 | [ get_path_info("src/utils/SkThreadUtils_pthread.cpp", "abspath") ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 487 | } else { |
| 488 | sources += [ |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 489 | "src/ports/SkOSFile_posix.cpp", |
| 490 | "src/ports/SkTLS_pthread.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 491 | "src/xps/SkDocument_XPS_None.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 492 | ] |
| 493 | } |
| 494 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 495 | if (is_android) { |
| 496 | deps += [ |
| 497 | "//third_party/cpu-features", |
| 498 | "//third_party/expat", |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 499 | ] |
| 500 | sources += [ |
| 501 | "src/gpu/gl/android/GrGLCreateNativeInterface_android.cpp", |
| 502 | "src/ports/SkDebug_android.cpp", |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 503 | ] |
| 504 | libs += [ |
| 505 | "EGL", |
| 506 | "GLESv2", |
| 507 | "log", |
| 508 | ] |
| 509 | } |
| 510 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 511 | if (is_linux) { |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 512 | libs += [ |
| 513 | "GL", |
| 514 | "GLU", |
| 515 | "X11", |
| 516 | ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 517 | sources += [ |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 518 | "src/gpu/gl/glx/GrGLCreateNativeInterface_glx.cpp", |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 519 | "src/ports/SkDebug_stdio.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 520 | ] |
| 521 | } |
| 522 | |
| 523 | if (is_mac) { |
| 524 | sources += [ |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 525 | "src/gpu/gl/mac/GrGLCreateNativeInterface_mac.cpp", |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 526 | "src/ports/SkDebug_stdio.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 527 | "src/ports/SkFontHost_mac.cpp", |
| 528 | "src/ports/SkImageEncoder_CG.cpp", |
| 529 | "src/ports/SkImageGeneratorCG.cpp", |
| 530 | ] |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 531 | libs += [ |
| 532 | "ApplicationServices.framework", |
| 533 | "OpenGL.framework", |
| 534 | ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 535 | } |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 536 | |
| 537 | if (is_fuchsia) { |
mikejurka | 21cc995 | 2016-09-13 16:15:03 -0700 | [diff] [blame] | 538 | sources += [ |
| 539 | "src/gpu/gl/GrGLCreateNativeInterface_none.cpp", |
| 540 | "src/ports/SkDebug_stdio.cpp", |
| 541 | ] |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 542 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 543 | } |
| 544 | |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 545 | skia_h_headers = exec_script("gyp/find.py", |
| 546 | [ "*.h" ] + rebase_path(skia_public_includes), |
| 547 | "list lines", |
| 548 | []) - |
| 549 | [ |
| 550 | rebase_path("include/gpu/gl/GrGLConfig_chrome.h"), |
| 551 | rebase_path("include/gpu/vk/GrVkBackendContext.h"), |
| 552 | rebase_path("include/gpu/vk/GrVkDefines.h"), |
| 553 | rebase_path("include/gpu/vk/GrVkInterface.h"), |
| 554 | rebase_path("include/gpu/vk/GrVkTypes.h"), |
| 555 | rebase_path("include/ports/SkFontMgr_fontconfig.h"), |
| 556 | ] |
| 557 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 558 | action("skia.h") { |
| 559 | script = "gn/echo_headers.py" |
| 560 | args = [ rebase_path("$target_gen_dir/skia.h", root_build_dir) ] + |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 561 | rebase_path(skia_h_headers, target_gen_dir) |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 562 | outputs = [ |
| 563 | "$target_gen_dir/skia.h", |
| 564 | ] |
| 565 | } |
| 566 | |
mtklein | 1fbdf98 | 2016-09-15 12:07:48 -0700 | [diff] [blame] | 567 | if (target_cpu == "x64") { |
| 568 | # Our bots only have 64-bit libOSMesa installed. |
| 569 | # TODO: worth fixing? |
| 570 | executable("fiddle") { |
| 571 | include_dirs = [ "$target_gen_dir" ] |
| 572 | libs = [] |
| 573 | if (is_linux) { |
| 574 | libs += [ "OSMesa" ] |
| 575 | } |
mtklein | 56d5669 | 2016-09-15 11:18:55 -0700 | [diff] [blame] | 576 | |
mtklein | 1fbdf98 | 2016-09-15 12:07:48 -0700 | [diff] [blame] | 577 | sources = [ |
| 578 | "src/images/SkForceLinking.cpp", |
| 579 | "tools/fiddle/draw.cpp", |
| 580 | "tools/fiddle/fiddle_main.cpp", |
| 581 | ] |
| 582 | deps = [ |
| 583 | ":skia", |
| 584 | ":skia.h", |
| 585 | ] |
| 586 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 587 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 588 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 589 | # Targets guarded by skia_enable_tools may use //third_party freely. |
| 590 | if (skia_enable_tools) { |
| 591 | template("test_lib") { |
| 592 | config(target_name + "_config") { |
| 593 | include_dirs = invoker.public_include_dirs |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 594 | } |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 595 | source_set(target_name) { |
| 596 | forward_variables_from(invoker, "*", [ "public_include_dirs" ]) |
| 597 | public_configs = [ |
| 598 | ":" + target_name + "_config", |
| 599 | ":skia_private", |
| 600 | ] |
| 601 | |
| 602 | if (!defined(deps)) { |
| 603 | deps = [] |
| 604 | } |
| 605 | deps += [ ":skia" ] |
| 606 | testonly = true |
| 607 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 608 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 609 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 610 | test_lib("gpu_tool_utils") { |
| 611 | public_include_dirs = [ "tools/gpu" ] |
| 612 | sources = [ |
| 613 | "tools/gpu/GrContextFactory.cpp", |
| 614 | "tools/gpu/GrTest.cpp", |
| 615 | "tools/gpu/TestContext.cpp", |
| 616 | "tools/gpu/gl/GLTestContext.cpp", |
| 617 | "tools/gpu/gl/debug/DebugGLTestContext.cpp", |
| 618 | "tools/gpu/gl/debug/GrBufferObj.cpp", |
| 619 | "tools/gpu/gl/debug/GrFrameBufferObj.cpp", |
| 620 | "tools/gpu/gl/debug/GrProgramObj.cpp", |
| 621 | "tools/gpu/gl/debug/GrShaderObj.cpp", |
| 622 | "tools/gpu/gl/debug/GrTextureObj.cpp", |
| 623 | "tools/gpu/gl/debug/GrTextureUnitObj.cpp", |
| 624 | "tools/gpu/gl/null/NullGLTestContext.cpp", |
| 625 | ] |
| 626 | libs = [] |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 627 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 628 | if (is_android) { |
| 629 | sources += [ "tools/gpu/gl/egl/CreatePlatformGLTestContext_egl.cpp" ] |
| 630 | } else if (is_linux) { |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 631 | sources += [ "tools/gpu/gl/glx/CreatePlatformGLTestContext_glx.cpp" ] |
| 632 | } else if (is_mac) { |
| 633 | sources += [ "tools/gpu/gl/mac/CreatePlatformGLTestContext_mac.cpp" ] |
| 634 | } |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 635 | |
| 636 | if (skia_use_vulkan) { |
| 637 | sources += [ "tools/gpu/vk/VkTestContext.cpp" ] |
| 638 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 639 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 640 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 641 | test_lib("flags") { |
| 642 | public_include_dirs = [ "tools/flags" ] |
| 643 | sources = [ |
| 644 | "tools/flags/SkCommandLineFlags.cpp", |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 645 | ] |
| 646 | } |
| 647 | test_lib("common_flags") { |
| 648 | public_include_dirs = [ "tools/flags" ] |
| 649 | sources = [ |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 650 | "tools/flags/SkCommonFlags.cpp", |
| 651 | "tools/flags/SkCommonFlagsConfig.cpp", |
| 652 | ] |
| 653 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 654 | ":flags", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 655 | ":gpu_tool_utils", |
| 656 | ] |
| 657 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 658 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 659 | test_lib("tool_utils") { |
| 660 | public_include_dirs = [ |
| 661 | "tools", |
| 662 | "tools/debugger", |
| 663 | "tools/timer", |
| 664 | ] |
| 665 | sources = [ |
| 666 | "src/images/SkForceLinking.cpp", |
| 667 | "src/utils/SkMultiPictureDocumentReader.cpp", # TODO(halcanary): move to tools? |
mtklein | b37c034 | 2016-09-09 11:07:45 -0700 | [diff] [blame] | 668 | "tools/AndroidSkDebugToStdOut.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 669 | "tools/CrashHandler.cpp", |
mtklein | 0590fa5 | 2016-09-01 07:06:54 -0700 | [diff] [blame] | 670 | "tools/LsanSuppressions.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 671 | "tools/ProcStats.cpp", |
| 672 | "tools/Resources.cpp", |
| 673 | "tools/ThermalManager.cpp", |
| 674 | "tools/UrlDataManager.cpp", |
| 675 | "tools/debugger/SkDebugCanvas.cpp", |
| 676 | "tools/debugger/SkDrawCommand.cpp", |
| 677 | "tools/debugger/SkJsonWriteBuffer.cpp", |
| 678 | "tools/debugger/SkObjectParser.cpp", |
| 679 | "tools/debugger/SkOverdrawMode.cpp", |
| 680 | "tools/picture_utils.cpp", |
| 681 | "tools/random_parse_path.cpp", |
| 682 | "tools/sk_tool_utils.cpp", |
| 683 | "tools/sk_tool_utils_font.cpp", |
| 684 | "tools/timer/Timer.cpp", |
| 685 | ] |
| 686 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 687 | ":common_flags", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 688 | ":flags", |
| 689 | "//third_party/libpng", |
| 690 | ] |
| 691 | public_deps = [ |
| 692 | "//third_party/jsoncpp", |
| 693 | ] |
| 694 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 695 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 696 | gm_sources = exec_script("gyp/find.py", |
| 697 | [ |
| 698 | "*.c*", |
| 699 | rebase_path("gm"), |
| 700 | ], |
| 701 | "list lines", |
| 702 | []) |
| 703 | test_lib("gm") { |
| 704 | public_include_dirs = [ "gm" ] |
| 705 | sources = gm_sources |
| 706 | deps = [ |
| 707 | ":gpu_tool_utils", |
| 708 | ":skia", |
| 709 | ":tool_utils", |
| 710 | ] |
| 711 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 712 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 713 | tests_sources = exec_script("gyp/find.py", |
| 714 | [ |
| 715 | "*.c*", |
| 716 | rebase_path("tests"), |
| 717 | ], |
| 718 | "list lines", |
| 719 | []) |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 720 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 721 | test_lib("tests") { |
| 722 | public_include_dirs = [ "tests" ] |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 723 | sources = tests_sources - [ |
| 724 | rebase_path("tests/PathOpsSkpClipTest.cpp"), # alternate main |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 725 | rebase_path("tests/SkpSkGrTest.cpp"), # doesn't compile |
| 726 | rebase_path("tests/skia_test.cpp"), # alternate main |
| 727 | ] |
| 728 | if (!fontmgr_android_enabled) { |
| 729 | sources -= [ rebase_path("tests/FontMgrAndroidParserTest.cpp") ] |
| 730 | } |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 731 | deps = [ |
fmalita | 6cf896d | 2016-08-25 08:44:35 -0700 | [diff] [blame] | 732 | ":experimental_svg_model", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 733 | ":flags", |
| 734 | ":gpu_tool_utils", |
| 735 | ":skia", |
| 736 | ":tool_utils", |
| 737 | "//third_party/libpng", |
| 738 | "//third_party/zlib", |
| 739 | ] |
| 740 | } |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 741 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 742 | bench_sources = exec_script("gyp/find.py", |
| 743 | [ |
| 744 | "*.c*", |
| 745 | rebase_path("bench"), |
| 746 | ], |
| 747 | "list lines", |
| 748 | []) |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 749 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 750 | test_lib("bench") { |
| 751 | public_include_dirs = [ "bench" ] |
| 752 | sources = bench_sources |
| 753 | sources -= [ |
| 754 | rebase_path("bench/nanobench.cpp"), |
| 755 | rebase_path("bench/nanobenchAndroid.cpp"), |
| 756 | ] |
| 757 | deps = [ |
| 758 | ":flags", |
| 759 | ":gm", |
| 760 | ":gpu_tool_utils", |
| 761 | ":skia", |
| 762 | ":tool_utils", |
| 763 | ] |
| 764 | } |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 765 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 766 | test_lib("experimental_svg_model") { |
| 767 | public_include_dirs = [ "experimental/svg/model" ] |
| 768 | sources = [ |
| 769 | "experimental/svg/model/SkSVGAttribute.cpp", |
| 770 | "experimental/svg/model/SkSVGAttributeParser.cpp", |
| 771 | "experimental/svg/model/SkSVGCircle.cpp", |
| 772 | "experimental/svg/model/SkSVGContainer.cpp", |
| 773 | "experimental/svg/model/SkSVGDOM.cpp", |
| 774 | "experimental/svg/model/SkSVGEllipse.cpp", |
| 775 | "experimental/svg/model/SkSVGLine.cpp", |
fmalita | 28d5b72 | 2016-09-12 17:06:47 -0700 | [diff] [blame] | 776 | "experimental/svg/model/SkSVGLinearGradient.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 777 | "experimental/svg/model/SkSVGNode.cpp", |
| 778 | "experimental/svg/model/SkSVGPath.cpp", |
| 779 | "experimental/svg/model/SkSVGPoly.cpp", |
| 780 | "experimental/svg/model/SkSVGRect.cpp", |
| 781 | "experimental/svg/model/SkSVGRenderContext.cpp", |
| 782 | "experimental/svg/model/SkSVGSVG.cpp", |
| 783 | "experimental/svg/model/SkSVGShape.cpp", |
fmalita | 28d5b72 | 2016-09-12 17:06:47 -0700 | [diff] [blame] | 784 | "experimental/svg/model/SkSVGStop.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 785 | "experimental/svg/model/SkSVGTransformableNode.cpp", |
| 786 | "experimental/svg/model/SkSVGValue.cpp", |
| 787 | ] |
| 788 | deps = [ |
| 789 | ":skia", |
| 790 | ] |
| 791 | } |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 792 | |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 793 | executable("dm") { |
| 794 | sources = [ |
| 795 | "dm/DM.cpp", |
| 796 | "dm/DMJsonWriter.cpp", |
| 797 | "dm/DMSrcSink.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 798 | ] |
| 799 | include_dirs = [ "tests" ] |
| 800 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 801 | ":common_flags", |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 802 | ":experimental_svg_model", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 803 | ":flags", |
| 804 | ":gm", |
| 805 | ":gpu_tool_utils", |
| 806 | ":skia", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 807 | ":tests", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 808 | ":tool_utils", |
| 809 | "//third_party/jsoncpp", |
| 810 | "//third_party/libpng", |
| 811 | ] |
| 812 | testonly = true |
| 813 | } |
| 814 | |
| 815 | executable("monobench") { |
| 816 | sources = [ |
| 817 | "tools/monobench.cpp", |
| 818 | ] |
| 819 | deps = [ |
| 820 | ":bench", |
| 821 | ":skia", |
| 822 | ] |
| 823 | testonly = true |
| 824 | } |
| 825 | |
| 826 | executable("nanobench") { |
| 827 | sources = [ |
| 828 | "bench/nanobench.cpp", |
| 829 | ] |
| 830 | deps = [ |
| 831 | ":bench", |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 832 | ":common_flags", |
fmalita | 6519c21 | 2016-09-14 08:05:17 -0700 | [diff] [blame] | 833 | ":experimental_svg_model", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 834 | ":flags", |
| 835 | ":gm", |
| 836 | ":gpu_tool_utils", |
| 837 | ":skia", |
| 838 | ":tool_utils", |
| 839 | "//third_party/jsoncpp", |
| 840 | ] |
| 841 | testonly = true |
| 842 | } |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 843 | |
csmartdalton | 4b5179b | 2016-09-19 11:03:58 -0700 | [diff] [blame] | 844 | executable("skpbench") { |
| 845 | sources = [ |
| 846 | "tools/skpbench/skpbench.cpp", |
| 847 | ] |
| 848 | deps = [ |
| 849 | ":flags", |
| 850 | ":gpu_tool_utils", |
| 851 | ":skia", |
| 852 | ":tool_utils", |
| 853 | ] |
| 854 | testonly = true |
| 855 | } |
| 856 | |
mtklein | 6f5df6a | 2016-08-29 16:01:10 -0700 | [diff] [blame] | 857 | if (current_cpu != "mipsel") { # Clang 3.8 crashes while compiling hb-icu.cc for mipsel. |
halcanary | 3eee9d9 | 2016-09-10 07:01:53 -0700 | [diff] [blame] | 858 | executable("sktexttopdf-hb") { |
mtklein | 6f5df6a | 2016-08-29 16:01:10 -0700 | [diff] [blame] | 859 | sources = [ |
| 860 | "tools/SkShaper_harfbuzz.cpp", |
| 861 | "tools/using_skia_and_harfbuzz.cpp", |
| 862 | ] |
| 863 | deps = [ |
| 864 | ":skia", |
| 865 | "//third_party/harfbuzz", |
| 866 | ] |
| 867 | testonly = true |
| 868 | } |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 869 | } |
halcanary | 3eee9d9 | 2016-09-10 07:01:53 -0700 | [diff] [blame] | 870 | executable("sktexttopdf") { |
| 871 | sources = [ |
| 872 | "tools/SkShaper_primitive.cpp", |
| 873 | "tools/using_skia_and_harfbuzz.cpp", |
| 874 | ] |
| 875 | deps = [ |
| 876 | ":skia", |
| 877 | ] |
| 878 | testonly = true |
| 879 | } |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 880 | |
| 881 | executable("get_images_from_skps") { |
| 882 | sources = [ |
| 883 | "tools/get_images_from_skps.cpp", |
| 884 | ] |
| 885 | deps = [ |
| 886 | ":flags", |
| 887 | ":skia", |
| 888 | "//third_party/jsoncpp", |
| 889 | ] |
| 890 | testonly = true |
| 891 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 892 | } |