mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 1 | # Copyright 2016 Google Inc. |
| 2 | # |
| 3 | # Use of this source code is governed by a BSD-style license that can be |
| 4 | # found in the LICENSE file. |
| 5 | |
| 6 | declare_args() { |
| 7 | } |
| 8 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 9 | skia_public_includes = [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 10 | "include/android", |
mtklein | fa84d94 | 2016-07-28 09:45:14 -0700 | [diff] [blame] | 11 | "include/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 12 | "include/codec", |
| 13 | "include/config", |
| 14 | "include/core", |
| 15 | "include/effects", |
| 16 | "include/gpu", |
| 17 | "include/gpu/gl", |
| 18 | "include/images", |
| 19 | "include/pathops", |
| 20 | "include/ports", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 21 | "include/svg", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 22 | "include/utils", |
| 23 | "include/utils/mac", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 24 | "include/xml", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 25 | ] |
| 26 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 27 | # Skia public API, generally provided by :skia. |
| 28 | config("skia_public") { |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 29 | include_dirs = skia_public_includes |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 30 | defines = [ "SKIA_DLL" ] |
| 31 | } |
| 32 | |
| 33 | # Skia internal APIs, used by Skia itself and a few test tools. |
| 34 | config("skia_private") { |
| 35 | visibility = [ ":*" ] |
| 36 | |
| 37 | include_dirs = [ |
| 38 | "include/private", |
| 39 | "src/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 40 | "src/codec", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 41 | "src/config", |
| 42 | "src/core", |
| 43 | "src/effects", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 44 | "src/effects/gradients", |
| 45 | "src/fonts", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 46 | "src/gpu", |
| 47 | "src/image", |
| 48 | "src/images", |
| 49 | "src/lazy", |
| 50 | "src/opts", |
| 51 | "src/pathops", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 52 | "src/pdf", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 53 | "src/ports", |
| 54 | "src/sfnt", |
| 55 | "src/utils", |
mtklein | 7a1f45f | 2016-08-04 06:19:33 -0700 | [diff] [blame] | 56 | "src/utils/win", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 57 | "third_party/etc1", |
| 58 | "third_party/ktx", |
| 59 | ] |
mtklein | 150d113 | 2016-08-01 06:56:40 -0700 | [diff] [blame] | 60 | |
| 61 | defines = [ |
mtklein | 9be6866 | 2016-08-01 08:37:48 -0700 | [diff] [blame] | 62 | "SK_GAMMA_APPLY_TO_A8", |
| 63 | |
mtklein | 150d113 | 2016-08-01 06:56:40 -0700 | [diff] [blame] | 64 | "SK_HAS_GIF_LIBRARY", |
| 65 | "SK_HAS_JPEG_LIBRARY", |
| 66 | "SK_HAS_PNG_LIBRARY", |
| 67 | "SK_HAS_WEBP_LIBRARY", |
mtklein | 7c1ae7a | 2016-08-01 15:50:27 -0700 | [diff] [blame] | 68 | |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 69 | # TODO(halcanary): make this the default; this is the value Android uses. |
| 70 | "SK_SFNTLY_SUBSETTER=\"sample/chromium/font_subsetter.h\"", |
| 71 | |
mtklein | 7c1ae7a | 2016-08-01 15:50:27 -0700 | [diff] [blame] | 72 | "TURBO_HAS_565", |
| 73 | "TURBO_HAS_CROP", |
| 74 | "TURBO_HAS_SKIP", |
mtklein | 150d113 | 2016-08-01 06:56:40 -0700 | [diff] [blame] | 75 | ] |
mtklein | ee269f4 | 2016-08-04 09:52:11 -0700 | [diff] [blame] | 76 | if (is_linux) { |
| 77 | defines += [ "SK_SAMPLES_FOR_X" ] |
| 78 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 79 | } |
| 80 | |
| 81 | # Any code that's linked into Skia-the-library should use this config via += skia_library_configs. |
| 82 | config("skia_library") { |
| 83 | visibility = [ ":*" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 84 | defines = [ "SKIA_IMPLEMENTATION=1" ] |
| 85 | } |
| 86 | |
| 87 | skia_library_configs = [ |
| 88 | ":skia_public", |
| 89 | ":skia_private", |
| 90 | ":skia_library", |
| 91 | ] |
| 92 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 93 | core_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 94 | [ |
| 95 | rebase_path("gyp/core.gypi"), |
| 96 | "--replace=<(skia_include_path)=include", |
| 97 | "--replace=<(skia_src_path)=src", |
| 98 | ], |
| 99 | "scope", |
| 100 | [ "gyp/core.gypi" ]) |
| 101 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 102 | effects_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 103 | [ |
| 104 | rebase_path("gyp/effects.gypi"), |
| 105 | "--replace=<(skia_include_path)=include", |
| 106 | "--replace=<(skia_src_path)=src", |
| 107 | ], |
| 108 | "scope", |
| 109 | [ "gyp/effects.gypi" ]) |
| 110 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 111 | gpu_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 112 | [ |
| 113 | rebase_path("gyp/gpu.gypi"), |
| 114 | "--replace=<(skia_include_path)=include", |
| 115 | "--replace=<(skia_src_path)=src", |
| 116 | ], |
| 117 | "scope", |
| 118 | [ "gyp/gpu.gypi" ]) |
| 119 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 120 | opts_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 121 | [ |
| 122 | rebase_path("gyp/opts.gypi"), |
| 123 | "--replace=<(skia_include_path)=include", |
| 124 | "--replace=<(skia_src_path)=src", |
| 125 | ], |
| 126 | "scope", |
| 127 | [ "gyp/opts.gypi" ]) |
| 128 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 129 | pdf_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 130 | [ |
| 131 | rebase_path("gyp/pdf.gypi"), |
| 132 | "--replace=<(skia_include_path)=include", |
| 133 | "--replace=<(skia_src_path)=src", |
| 134 | ], |
| 135 | "scope", |
| 136 | [ "gyp/pdf.gypi" ]) |
| 137 | |
mtklein | 7fbfbbe | 2016-07-21 12:25:45 -0700 | [diff] [blame] | 138 | utils_gypi = exec_script("gn/gypi_to_gn.py", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 139 | [ |
| 140 | rebase_path("gyp/utils.gypi"), |
| 141 | "--replace=<(skia_include_path)=include", |
| 142 | "--replace=<(skia_src_path)=src", |
| 143 | ], |
| 144 | "scope", |
| 145 | [ "gyp/utils.gypi" ]) |
| 146 | |
| 147 | source_set("opts_ssse3") { |
| 148 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 149 | |
| 150 | sources = opts_gypi.ssse3_sources |
| 151 | cflags = [ "-mssse3" ] |
| 152 | } |
| 153 | |
| 154 | source_set("opts_sse41") { |
| 155 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 156 | |
| 157 | sources = opts_gypi.sse41_sources |
| 158 | cflags = [ "-msse4.1" ] |
| 159 | } |
| 160 | |
mtklein | 4e97607 | 2016-08-08 09:06:27 -0700 | [diff] [blame] | 161 | source_set("opts_sse42") { |
| 162 | configs += skia_library_configs |
| 163 | |
| 164 | sources = opts_gypi.sse42_sources |
| 165 | cflags = [ "-msse4.2" ] |
| 166 | } |
| 167 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 168 | source_set("opts_avx") { |
| 169 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 170 | |
| 171 | sources = opts_gypi.avx_sources |
| 172 | cflags = [ "-mavx" ] |
| 173 | } |
| 174 | |
| 175 | component("skia") { |
| 176 | public_configs = [ ":skia_public" ] |
| 177 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 178 | |
| 179 | deps = [ |
| 180 | ":opts_avx", |
| 181 | ":opts_sse41", |
mtklein | 4e97607 | 2016-08-08 09:06:27 -0700 | [diff] [blame] | 182 | ":opts_sse42", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 183 | ":opts_ssse3", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 184 | "//third_party/expat", |
| 185 | "//third_party/giflib", |
mtklein | 7d10b9f | 2016-07-27 11:17:18 -0700 | [diff] [blame] | 186 | "//third_party/libjpeg_turbo", |
| 187 | "//third_party/libpng", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 188 | "//third_party/libwebp", |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 189 | "//third_party/sfntly", |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 190 | "//third_party/zlib", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 191 | ] |
| 192 | |
mtklein | 7a1f45f | 2016-08-04 06:19:33 -0700 | [diff] [blame] | 193 | if (!is_win) { |
| 194 | libs = [ "pthread" ] |
| 195 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 196 | |
| 197 | sources = [] |
| 198 | sources += core_gypi.sources |
| 199 | sources += effects_gypi.sources |
| 200 | sources += gpu_gypi.skgpu_sources |
| 201 | sources += opts_gypi.sse2_sources |
| 202 | sources += pdf_gypi.sources |
| 203 | sources += utils_gypi.sources |
| 204 | sources += [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 205 | "src/android/SkBitmapRegionCodec.cpp", |
| 206 | "src/android/SkBitmapRegionDecoder.cpp", |
| 207 | "src/codec/SkAndroidCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 208 | "src/codec/SkBmpCodec.cpp", |
| 209 | "src/codec/SkBmpMaskCodec.cpp", |
| 210 | "src/codec/SkBmpRLECodec.cpp", |
| 211 | "src/codec/SkBmpStandardCodec.cpp", |
| 212 | "src/codec/SkCodec.cpp", |
| 213 | "src/codec/SkCodecImageGenerator.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 214 | "src/codec/SkGifCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 215 | "src/codec/SkIcoCodec.cpp", |
| 216 | "src/codec/SkJpegCodec.cpp", |
| 217 | "src/codec/SkJpegDecoderMgr.cpp", |
| 218 | "src/codec/SkJpegUtility.cpp", |
| 219 | "src/codec/SkMaskSwizzler.cpp", |
| 220 | "src/codec/SkMasks.cpp", |
| 221 | "src/codec/SkPngCodec.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 222 | "src/codec/SkSampledCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 223 | "src/codec/SkSampler.cpp", |
| 224 | "src/codec/SkSwizzler.cpp", |
| 225 | "src/codec/SkWbmpCodec.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 226 | "src/codec/SkWebpAdapterCodec.cpp", |
| 227 | "src/codec/SkWebpCodec.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 228 | "src/images/SkImageEncoder.cpp", |
| 229 | "src/images/SkImageEncoder_Factory.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 230 | "src/images/SkJPEGImageEncoder.cpp", |
| 231 | "src/images/SkJPEGWriteUtility.cpp", |
| 232 | "src/images/SkKTXImageEncoder.cpp", |
| 233 | "src/images/SkPNGImageEncoder.cpp", |
| 234 | "src/images/SkWEBPImageEncoder.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 235 | "src/ports/SkDiscardableMemory_none.cpp", |
| 236 | "src/ports/SkGlobalInitialization_default.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 237 | "src/ports/SkImageGenerator_skia.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 238 | "src/ports/SkMemory_malloc.cpp", |
| 239 | "src/ports/SkOSFile_stdio.cpp", |
| 240 | "src/sfnt/SkOTTable_name.cpp", |
| 241 | "src/sfnt/SkOTUtils.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 242 | "src/svg/SkSVGCanvas.cpp", |
| 243 | "src/svg/SkSVGDevice.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 244 | "src/utils/mac/SkStream_mac.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 245 | "src/xml/SkDOM.cpp", |
| 246 | "src/xml/SkXMLParser.cpp", |
| 247 | "src/xml/SkXMLWriter.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 248 | "third_party/etc1/etc1.cpp", |
| 249 | "third_party/ktx/ktx.cpp", |
| 250 | ] |
| 251 | |
| 252 | if (is_win) { |
| 253 | sources += [ |
| 254 | "src/ports/SkDebug_win.cpp", |
| 255 | "src/ports/SkFontHost_win.cpp", |
| 256 | "src/ports/SkFontMgr_win_dw.cpp", |
| 257 | "src/ports/SkFontMgr_win_dw_factory.cpp", |
| 258 | "src/ports/SkImageEncoder_WIC.cpp", |
| 259 | "src/ports/SkImageGeneratorWIC.cpp", |
| 260 | "src/ports/SkOSFile_win.cpp", |
| 261 | "src/ports/SkScalerContext_win_dw.cpp", |
| 262 | "src/ports/SkTLS_win.cpp", |
| 263 | "src/ports/SkTypeface_win_dw.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 264 | "src/xps/SkDocument_XPS.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 265 | ] |
mtklein | 7a1f45f | 2016-08-04 06:19:33 -0700 | [diff] [blame] | 266 | sources -= [ "src/utils/SkThreadUtils_pthread.cpp" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 267 | } else { |
| 268 | sources += [ |
| 269 | "src/ports/SkDebug_stdio.cpp", |
| 270 | "src/ports/SkOSFile_posix.cpp", |
| 271 | "src/ports/SkTLS_pthread.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 272 | "src/xps/SkDocument_XPS_None.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 273 | ] |
| 274 | } |
| 275 | |
| 276 | if (is_linux) { |
| 277 | deps += [ |
| 278 | "third_party:fontconfig", |
| 279 | "third_party:freetype2", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 280 | ] |
| 281 | sources += [ |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 282 | "src/ports/SkFontConfigInterface_direct.cpp", |
| 283 | "src/ports/SkFontConfigInterface_direct_factory.cpp", |
| 284 | "src/ports/SkFontHost_FreeType.cpp", |
| 285 | "src/ports/SkFontHost_FreeType_common.cpp", |
bungeman | 7d0e3bc | 2016-08-02 07:07:33 -0700 | [diff] [blame] | 286 | "src/ports/SkFontMgr_FontConfigInterface.cpp", |
mtklein | 7a34b1c | 2016-08-01 13:08:46 -0700 | [diff] [blame] | 287 | "src/ports/SkFontMgr_fontconfig.cpp", |
| 288 | "src/ports/SkFontMgr_fontconfig_factory.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 289 | ] |
| 290 | } |
| 291 | |
| 292 | if (is_mac) { |
| 293 | sources += [ |
| 294 | "src/ports/SkFontHost_mac.cpp", |
| 295 | "src/ports/SkImageEncoder_CG.cpp", |
| 296 | "src/ports/SkImageGeneratorCG.cpp", |
| 297 | ] |
| 298 | libs += [ "ApplicationServices.framework" ] |
| 299 | } |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 300 | |
| 301 | if (is_fuchsia) { |
mtklein | e817ddf | 2016-07-19 06:03:22 -0700 | [diff] [blame] | 302 | sources += [ "src/ports/SkFontMgr_empty_factory.cpp" ] |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 303 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 304 | } |
| 305 | |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 306 | skia_h_headers = exec_script("gyp/find.py", |
| 307 | [ "*.h" ] + rebase_path(skia_public_includes), |
| 308 | "list lines", |
| 309 | []) - |
| 310 | [ |
| 311 | rebase_path("include/gpu/gl/GrGLConfig_chrome.h"), |
| 312 | rebase_path("include/gpu/vk/GrVkBackendContext.h"), |
| 313 | rebase_path("include/gpu/vk/GrVkDefines.h"), |
| 314 | rebase_path("include/gpu/vk/GrVkInterface.h"), |
| 315 | rebase_path("include/gpu/vk/GrVkTypes.h"), |
| 316 | rebase_path("include/ports/SkFontMgr_fontconfig.h"), |
| 317 | ] |
| 318 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 319 | action("skia.h") { |
| 320 | script = "gn/echo_headers.py" |
| 321 | args = [ rebase_path("$target_gen_dir/skia.h", root_build_dir) ] + |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 322 | rebase_path(skia_h_headers, root_build_dir) |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 323 | outputs = [ |
| 324 | "$target_gen_dir/skia.h", |
| 325 | ] |
| 326 | } |
| 327 | |
| 328 | executable("fiddle") { |
| 329 | include_dirs = [ "$target_gen_dir" ] |
mtklein | 7d10b9f | 2016-07-27 11:17:18 -0700 | [diff] [blame] | 330 | libs = [] |
| 331 | if (is_linux) { |
| 332 | libs += [ "OSMesa" ] |
| 333 | } |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 334 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 335 | sources = [ |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 336 | "tools/fiddle/draw.cpp", |
| 337 | "tools/fiddle/fiddle_main.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 338 | ] |
| 339 | deps = [ |
| 340 | ":skia", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 341 | ":skia.h", |
mtklein | 5dbd274 | 2016-08-02 11:13:48 -0700 | [diff] [blame] | 342 | ":tool_utils", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 343 | ] |
mtklein | 5dbd274 | 2016-08-02 11:13:48 -0700 | [diff] [blame] | 344 | testonly = true |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 345 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 346 | |
| 347 | template("test_lib") { |
| 348 | config(target_name + "_config") { |
| 349 | include_dirs = invoker.public_include_dirs |
| 350 | } |
| 351 | source_set(target_name) { |
| 352 | forward_variables_from(invoker, "*", [ "public_include_dirs" ]) |
| 353 | public_configs = [ |
| 354 | ":" + target_name + "_config", |
| 355 | ":skia_private", |
| 356 | ] |
| 357 | |
| 358 | if (!defined(deps)) { |
| 359 | deps = [] |
| 360 | } |
| 361 | deps += [ ":skia" ] |
| 362 | testonly = true |
| 363 | } |
| 364 | } |
| 365 | |
| 366 | test_lib("gpu_tool_utils") { |
| 367 | public_include_dirs = [ "tools/gpu" ] |
| 368 | sources = [ |
| 369 | "tools/gpu/GrContextFactory.cpp", |
| 370 | "tools/gpu/GrTest.cpp", |
| 371 | "tools/gpu/TestContext.cpp", |
| 372 | "tools/gpu/gl/GLTestContext.cpp", |
| 373 | "tools/gpu/gl/debug/DebugGLTestContext.cpp", |
| 374 | "tools/gpu/gl/debug/GrBufferObj.cpp", |
| 375 | "tools/gpu/gl/debug/GrFrameBufferObj.cpp", |
| 376 | "tools/gpu/gl/debug/GrProgramObj.cpp", |
| 377 | "tools/gpu/gl/debug/GrShaderObj.cpp", |
| 378 | "tools/gpu/gl/debug/GrTextureObj.cpp", |
| 379 | "tools/gpu/gl/debug/GrTextureUnitObj.cpp", |
| 380 | "tools/gpu/gl/null/NullGLTestContext.cpp", |
| 381 | ] |
| 382 | libs = [] |
| 383 | |
| 384 | if (is_linux) { |
mtklein | 5259da5 | 2016-08-03 08:28:20 -0700 | [diff] [blame] | 385 | sources += [ |
mtklein | 4db3b79 | 2016-08-03 14:18:22 -0700 | [diff] [blame] | 386 | "src/gpu/gl/glx/GrGLCreateNativeInterface_glx.cpp", |
| 387 | "tools/gpu/gl/glx/CreatePlatformGLTestContext_glx.cpp", |
mtklein | 5259da5 | 2016-08-03 08:28:20 -0700 | [diff] [blame] | 388 | ] |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 389 | libs += [ |
| 390 | "GL", |
| 391 | "GLU", |
| 392 | "X11", |
| 393 | ] |
| 394 | } else if (is_mac) { |
mtklein | 5259da5 | 2016-08-03 08:28:20 -0700 | [diff] [blame] | 395 | sources += [ |
mtklein | 4db3b79 | 2016-08-03 14:18:22 -0700 | [diff] [blame] | 396 | "src/gpu/gl/mac/GrGLCreateNativeInterface_mac.cpp", |
| 397 | "tools/gpu/gl/mac/CreatePlatformGLTestContext_mac.cpp", |
mtklein | 5259da5 | 2016-08-03 08:28:20 -0700 | [diff] [blame] | 398 | ] |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 399 | libs += [ "OpenGL.framework" ] |
| 400 | } |
| 401 | } |
| 402 | |
| 403 | test_lib("flags") { |
| 404 | public_include_dirs = [ "tools/flags" ] |
| 405 | sources = [ |
| 406 | "tools/flags/SkCommandLineFlags.cpp", |
| 407 | "tools/flags/SkCommonFlags.cpp", |
| 408 | "tools/flags/SkCommonFlagsConfig.cpp", |
| 409 | ] |
| 410 | deps = [ |
| 411 | ":gpu_tool_utils", |
| 412 | ] |
| 413 | } |
| 414 | |
| 415 | test_lib("tool_utils") { |
| 416 | public_include_dirs = [ |
| 417 | "tools", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 418 | "tools/debugger", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 419 | "tools/timer", |
| 420 | ] |
| 421 | sources = [ |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 422 | "src/images/SkForceLinking.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 423 | "src/utils/SkMultiPictureDocumentReader.cpp", # TODO(halcanary): move to tools? |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 424 | "tools/CrashHandler.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 425 | "tools/ProcStats.cpp", |
| 426 | "tools/Resources.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 427 | "tools/ThermalManager.cpp", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 428 | "tools/UrlDataManager.cpp", |
| 429 | "tools/debugger/SkDebugCanvas.cpp", |
| 430 | "tools/debugger/SkDrawCommand.cpp", |
| 431 | "tools/debugger/SkJsonWriteBuffer.cpp", |
| 432 | "tools/debugger/SkObjectParser.cpp", |
| 433 | "tools/debugger/SkOverdrawMode.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 434 | "tools/picture_utils.cpp", |
| 435 | "tools/random_parse_path.cpp", |
| 436 | "tools/sk_tool_utils.cpp", |
| 437 | "tools/sk_tool_utils_font.cpp", |
| 438 | "tools/timer/Timer.cpp", |
| 439 | ] |
| 440 | deps = [ |
| 441 | ":flags", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 442 | "//third_party/libpng", |
| 443 | ] |
| 444 | public_deps = [ |
| 445 | "//third_party/jsoncpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 446 | ] |
| 447 | } |
| 448 | |
| 449 | gm_sources = exec_script("gyp/find.py", |
| 450 | [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 451 | "*.c*", |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 452 | rebase_path("gm"), |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 453 | ], |
| 454 | "list lines", |
| 455 | []) |
| 456 | test_lib("gm") { |
| 457 | public_include_dirs = [ "gm" ] |
| 458 | sources = gm_sources |
| 459 | deps = [ |
| 460 | ":gpu_tool_utils", |
| 461 | ":skia", |
| 462 | ":tool_utils", |
| 463 | ] |
| 464 | } |
| 465 | |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 466 | tests_sources = exec_script("gyp/find.py", |
| 467 | [ |
| 468 | "*.c*", |
| 469 | rebase_path("tests"), |
| 470 | ], |
| 471 | "list lines", |
| 472 | []) |
| 473 | |
| 474 | test_lib("tests") { |
| 475 | public_include_dirs = [ "tests" ] |
| 476 | sources = tests_sources - [ |
| 477 | rebase_path("tests/FontMgrAndroidParserTest.cpp"), # Android only |
| 478 | rebase_path("tests/PathOpsSkpClipTest.cpp"), # alternate main |
mtklein | 4db3b79 | 2016-08-03 14:18:22 -0700 | [diff] [blame] | 479 | rebase_path("tests/SkSLErrorTest.cpp"), # TODO: make work |
| 480 | rebase_path("tests/SkSLGLSLTest.cpp"), # TODO: make work |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 481 | rebase_path("tests/SkpSkGrTest.cpp"), # doesn't compile |
| 482 | rebase_path("tests/skia_test.cpp"), # alternate main |
| 483 | ] |
| 484 | deps = [ |
| 485 | ":flags", |
| 486 | ":gpu_tool_utils", |
| 487 | ":skia", |
| 488 | ":tool_utils", |
| 489 | "//third_party/libpng", |
| 490 | "//third_party/zlib", |
| 491 | ] |
| 492 | } |
| 493 | |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 494 | bench_sources = exec_script("gyp/find.py", |
| 495 | [ |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 496 | "*.c*", |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 497 | rebase_path("bench"), |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 498 | ], |
| 499 | "list lines", |
| 500 | []) |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 501 | |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 502 | test_lib("bench") { |
| 503 | public_include_dirs = [ "bench" ] |
| 504 | sources = bench_sources |
| 505 | sources -= [ |
| 506 | rebase_path("bench/nanobench.cpp"), |
| 507 | rebase_path("bench/nanobenchAndroid.cpp"), |
| 508 | ] |
| 509 | deps = [ |
| 510 | ":flags", |
| 511 | ":gm", |
| 512 | ":gpu_tool_utils", |
| 513 | ":skia", |
| 514 | ":tool_utils", |
| 515 | ] |
| 516 | } |
| 517 | |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 518 | test_lib("experimental_svg_model") { |
| 519 | public_include_dirs = [ "experimental/svg/model" ] |
| 520 | sources = [ |
| 521 | "experimental/svg/model/SkSVGAttribute.cpp", |
| 522 | "experimental/svg/model/SkSVGAttributeParser.cpp", |
| 523 | "experimental/svg/model/SkSVGContainer.cpp", |
| 524 | "experimental/svg/model/SkSVGDOM.cpp", |
| 525 | "experimental/svg/model/SkSVGNode.cpp", |
| 526 | "experimental/svg/model/SkSVGPath.cpp", |
fmalita | 5b31f32 | 2016-08-12 12:15:33 -0700 | [diff] [blame^] | 527 | "experimental/svg/model/SkSVGPoly.cpp", |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 528 | "experimental/svg/model/SkSVGRect.cpp", |
| 529 | "experimental/svg/model/SkSVGRenderContext.cpp", |
| 530 | "experimental/svg/model/SkSVGSVG.cpp", |
| 531 | "experimental/svg/model/SkSVGShape.cpp", |
| 532 | "experimental/svg/model/SkSVGTransformableNode.cpp", |
| 533 | "experimental/svg/model/SkSVGValue.cpp", |
| 534 | ] |
| 535 | deps = [ |
| 536 | ":skia", |
| 537 | ] |
| 538 | } |
| 539 | |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 540 | if (!is_component_build) { # Our test tools use many non-SK_API APIs... |
| 541 | executable("dm") { |
| 542 | sources = [ |
| 543 | "dm/DM.cpp", |
| 544 | "dm/DMJsonWriter.cpp", |
| 545 | "dm/DMSrcSink.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 546 | ] |
| 547 | include_dirs = [ "tests" ] |
| 548 | deps = [ |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 549 | ":experimental_svg_model", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 550 | ":flags", |
| 551 | ":gm", |
| 552 | ":gpu_tool_utils", |
| 553 | ":skia", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 554 | ":tests", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 555 | ":tool_utils", |
| 556 | "//third_party/jsoncpp", |
| 557 | "//third_party/libpng", |
| 558 | ] |
| 559 | testonly = true |
| 560 | } |
| 561 | |
| 562 | executable("monobench") { |
| 563 | sources = [ |
| 564 | "tools/monobench.cpp", |
| 565 | ] |
| 566 | deps = [ |
| 567 | ":bench", |
| 568 | ":skia", |
| 569 | ] |
| 570 | testonly = true |
| 571 | } |
| 572 | |
| 573 | executable("nanobench") { |
| 574 | sources = [ |
| 575 | "bench/nanobench.cpp", |
| 576 | ] |
| 577 | deps = [ |
| 578 | ":bench", |
| 579 | ":flags", |
| 580 | ":gm", |
| 581 | ":gpu_tool_utils", |
| 582 | ":skia", |
| 583 | ":tool_utils", |
| 584 | "//third_party/jsoncpp", |
| 585 | ] |
| 586 | testonly = true |
| 587 | } |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 588 | |
| 589 | executable("sktexttopdf") { |
| 590 | sources = [ |
| 591 | "tools/SkShaper_harfbuzz.cpp", |
| 592 | "tools/using_skia_and_harfbuzz.cpp", |
| 593 | ] |
| 594 | deps = [ |
| 595 | ":skia", |
| 596 | "//third_party/harfbuzz", |
| 597 | ] |
| 598 | testonly = true |
| 599 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 600 | } |