mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 1 | # Copyright 2016 Google Inc. |
| 2 | # |
| 3 | # Use of this source code is governed by a BSD-style license that can be |
| 4 | # found in the LICENSE file. |
| 5 | |
mikejurka | 8c24f4f | 2016-09-12 16:51:58 -0700 | [diff] [blame] | 6 | import("gn/shared_sources.gni") |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 7 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 8 | declare_args() { |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 9 | skia_use_expat = true |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 10 | skia_use_fontconfig = is_linux |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 11 | skia_use_freetype = is_android || is_fuchsia || is_linux |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 12 | skia_use_giflib = !is_fuchsia |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 13 | skia_use_libjpeg_turbo = true |
| 14 | skia_use_libpng = true |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 15 | skia_use_libwebp = !is_fuchsia |
mtklein | a627b5c | 2016-09-20 13:36:47 -0700 | [diff] [blame] | 16 | skia_use_mesa = false |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 17 | skia_use_sfntly = !is_fuchsia |
mtklein | f29180e | 2016-09-16 07:01:17 -0700 | [diff] [blame] | 18 | skia_use_vulkan = is_android && defined(ndk_api) && ndk_api >= 24 |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 19 | skia_use_zlib = true |
mtklein | 1bd72ba | 2016-09-16 07:45:52 -0700 | [diff] [blame] | 20 | |
| 21 | skia_enable_android_framework_defines = false |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 22 | skia_enable_gpu = true |
| 23 | skia_enable_tools = !is_fuchsia |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 24 | } |
| 25 | |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 26 | # Our tools require static linking (they use non-exported symbols) and GPU support (just lazy). |
| 27 | skia_enable_tools = skia_enable_tools && skia_enable_gpu && !is_component_build |
| 28 | |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 29 | fontmgr_android_enabled = skia_use_expat && skia_use_freetype |
| 30 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 31 | skia_public_includes = [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 32 | "include/android", |
mtklein | fa84d94 | 2016-07-28 09:45:14 -0700 | [diff] [blame] | 33 | "include/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 34 | "include/codec", |
| 35 | "include/config", |
| 36 | "include/core", |
| 37 | "include/effects", |
| 38 | "include/gpu", |
| 39 | "include/gpu/gl", |
| 40 | "include/images", |
| 41 | "include/pathops", |
| 42 | "include/ports", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 43 | "include/svg", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 44 | "include/utils", |
| 45 | "include/utils/mac", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 46 | "include/xml", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 47 | ] |
| 48 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 49 | # Skia public API, generally provided by :skia. |
| 50 | config("skia_public") { |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 51 | include_dirs = skia_public_includes |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 52 | defines = [ "SKIA_DLL" ] |
jcgregorio | 5561e3d | 2016-08-25 09:25:11 -0700 | [diff] [blame] | 53 | if (is_linux) { |
| 54 | defines += [ "SK_SAMPLES_FOR_X" ] |
| 55 | } |
mtklein | cae1be5 | 2016-09-20 08:24:34 -0700 | [diff] [blame] | 56 | if (skia_enable_android_framework_defines) { |
| 57 | defines += skia_android_framework_defines |
| 58 | } |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 59 | if (!skia_enable_gpu) { |
| 60 | defines += [ "SK_SUPPORT_GPU=0" ] |
| 61 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 62 | } |
| 63 | |
| 64 | # Skia internal APIs, used by Skia itself and a few test tools. |
| 65 | config("skia_private") { |
| 66 | visibility = [ ":*" ] |
| 67 | |
| 68 | include_dirs = [ |
| 69 | "include/private", |
| 70 | "src/c", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 71 | "src/codec", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 72 | "src/config", |
| 73 | "src/core", |
| 74 | "src/effects", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 75 | "src/effects/gradients", |
| 76 | "src/fonts", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 77 | "src/gpu", |
| 78 | "src/image", |
| 79 | "src/images", |
| 80 | "src/lazy", |
| 81 | "src/opts", |
| 82 | "src/pathops", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 83 | "src/pdf", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 84 | "src/ports", |
| 85 | "src/sfnt", |
mtklein | 9e0d9dd | 2016-08-30 10:37:19 -0700 | [diff] [blame] | 86 | "src/sksl", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 87 | "src/utils", |
mtklein | 7a1f45f | 2016-08-04 06:19:33 -0700 | [diff] [blame] | 88 | "src/utils/win", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 89 | "third_party/etc1", |
| 90 | "third_party/ktx", |
| 91 | ] |
mtklein | 150d113 | 2016-08-01 06:56:40 -0700 | [diff] [blame] | 92 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 93 | defines = [ "SK_GAMMA_APPLY_TO_A8" ] |
mtklein | b37c034 | 2016-09-09 11:07:45 -0700 | [diff] [blame] | 94 | if (is_android) { |
| 95 | defines += [ |
| 96 | "SK_GAMMA_EXPONENT=1.4", |
| 97 | "SK_GAMMA_CONTRAST=0.0", |
| 98 | ] |
| 99 | } |
mtklein | 88a7ac0 | 2016-09-14 11:16:49 -0700 | [diff] [blame] | 100 | if (is_official_build || is_android) { |
| 101 | # TODO(bsalomon): it'd be nice to make Android normal. |
| 102 | defines += [ "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0" ] |
| 103 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 104 | } |
| 105 | |
| 106 | # Any code that's linked into Skia-the-library should use this config via += skia_library_configs. |
| 107 | config("skia_library") { |
| 108 | visibility = [ ":*" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 109 | defines = [ "SKIA_IMPLEMENTATION=1" ] |
| 110 | } |
| 111 | |
| 112 | skia_library_configs = [ |
| 113 | ":skia_public", |
| 114 | ":skia_private", |
| 115 | ":skia_library", |
| 116 | ] |
| 117 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 118 | # Use for CPU-specific Skia code that needs particular compiler flags. |
| 119 | template("opts") { |
| 120 | if (invoker.enabled) { |
| 121 | source_set(target_name) { |
| 122 | forward_variables_from(invoker, "*") |
| 123 | configs += skia_library_configs |
| 124 | } |
| 125 | } else { |
| 126 | # If not enabled, a phony empty target that swallows all otherwise unused variables. |
| 127 | source_set(target_name) { |
| 128 | forward_variables_from(invoker, |
| 129 | "*", |
| 130 | [ |
| 131 | "sources", |
| 132 | "cflags", |
| 133 | ]) |
| 134 | } |
| 135 | } |
anmittal | a7eaf2e | 2016-08-17 13:57:26 -0700 | [diff] [blame] | 136 | } |
| 137 | |
mtklein | 422310d | 2016-08-16 18:28:43 -0700 | [diff] [blame] | 138 | is_x86 = current_cpu == "x64" || current_cpu == "x86" |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 139 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 140 | opts("none") { |
| 141 | enabled = !is_x86 && current_cpu != "arm" && current_cpu != "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 142 | sources = skia_opts.none_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 143 | cflags = [] |
| 144 | } |
| 145 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 146 | opts("armv7") { |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 147 | enabled = current_cpu == "arm" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 148 | sources = skia_opts.armv7_sources + skia_opts.neon_sources |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 149 | cflags = [] |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 150 | } |
| 151 | |
| 152 | opts("arm64") { |
| 153 | enabled = current_cpu == "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 154 | sources = skia_opts.arm64_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 155 | cflags = [] |
| 156 | } |
| 157 | |
| 158 | opts("crc32") { |
| 159 | enabled = current_cpu == "arm64" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 160 | sources = skia_opts.crc32_sources |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 161 | cflags = [ "-march=armv8-a+crc" ] |
| 162 | } |
| 163 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 164 | opts("sse2") { |
| 165 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 166 | sources = skia_opts.sse2_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 167 | cflags = [ "-msse2" ] |
| 168 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 169 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 170 | opts("ssse3") { |
| 171 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 172 | sources = skia_opts.ssse3_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 173 | cflags = [ "-mssse3" ] |
| 174 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 175 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 176 | opts("sse41") { |
| 177 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 178 | sources = skia_opts.sse41_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 179 | cflags = [ "-msse4.1" ] |
| 180 | } |
mtklein | 4e97607 | 2016-08-08 09:06:27 -0700 | [diff] [blame] | 181 | |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 182 | opts("sse42") { |
| 183 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 184 | sources = skia_opts.sse42_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 185 | cflags = [ "-msse4.2" ] |
| 186 | } |
| 187 | |
| 188 | opts("avx") { |
| 189 | enabled = is_x86 |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 190 | sources = skia_opts.avx_sources |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 191 | cflags = [ "-mavx" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 192 | } |
| 193 | |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 194 | opts("dsp") { |
| 195 | enabled = current_cpu == "mipsel" |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 196 | sources = skia_opts.mips_dsp_sources |
mtklein | b6064ef | 2016-08-30 11:49:24 -0700 | [diff] [blame] | 197 | cflags = [] |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 198 | } |
| 199 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 200 | # Any feature of Skia that requires third-party code should be optional and use this template. |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 201 | template("optional") { |
| 202 | if (invoker.enabled) { |
| 203 | config(target_name + "_public") { |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 204 | if (defined(invoker.public_defines)) { |
| 205 | defines = invoker.public_defines |
| 206 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 207 | } |
| 208 | source_set(target_name) { |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 209 | forward_variables_from(invoker, |
| 210 | "*", |
| 211 | [ |
| 212 | "public_defines", |
| 213 | "sources_when_disabled", |
| 214 | ]) |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 215 | all_dependent_configs = [ ":" + target_name + "_public" ] |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 216 | configs += skia_library_configs |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 217 | } |
| 218 | } else { |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 219 | source_set(target_name) { |
| 220 | forward_variables_from(invoker, |
| 221 | "*", |
| 222 | [ |
| 223 | "public_defines", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 224 | "deps", |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 225 | "libs", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 226 | "sources", |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 227 | "sources_when_disabled", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 228 | ]) |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 229 | if (defined(invoker.sources_when_disabled)) { |
| 230 | sources = invoker.sources_when_disabled |
| 231 | } |
| 232 | configs += skia_library_configs |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 233 | } |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 234 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 235 | } |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 236 | |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 237 | optional("fontmgr_android") { |
| 238 | enabled = fontmgr_android_enabled |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 239 | |
| 240 | deps = [ |
| 241 | "//third_party/expat", |
| 242 | "//third_party/freetype2", |
| 243 | ] |
| 244 | sources = [ |
| 245 | "src/ports/SkFontMgr_android.cpp", |
| 246 | "src/ports/SkFontMgr_android_factory.cpp", |
| 247 | "src/ports/SkFontMgr_android_parser.cpp", |
| 248 | ] |
| 249 | } |
| 250 | |
mtklein | d2e39db | 2016-09-07 07:52:55 -0700 | [diff] [blame] | 251 | optional("fontmgr_custom") { |
| 252 | enabled = is_linux && skia_use_freetype && !skia_use_fontconfig |
| 253 | |
| 254 | deps = [ |
| 255 | "//third_party/freetype2", |
| 256 | ] |
| 257 | sources = [ |
| 258 | "src/ports/SkFontMgr_custom.cpp", |
| 259 | "src/ports/SkFontMgr_custom_directory_factory.cpp", |
| 260 | ] |
| 261 | } |
| 262 | |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 263 | optional("fontmgr_fontconfig") { |
| 264 | enabled = skia_use_freetype && skia_use_fontconfig |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 265 | |
| 266 | deps = [ |
| 267 | "//third_party:fontconfig", |
| 268 | "//third_party/freetype2", |
| 269 | ] |
| 270 | sources = [ |
bungeman | 1ae0e01 | 2016-09-19 12:13:16 -0700 | [diff] [blame] | 271 | "src/ports/SkFontConfigInterface.cpp", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 272 | "src/ports/SkFontConfigInterface_direct.cpp", |
| 273 | "src/ports/SkFontConfigInterface_direct_factory.cpp", |
| 274 | "src/ports/SkFontMgr_FontConfigInterface.cpp", |
| 275 | "src/ports/SkFontMgr_fontconfig.cpp", |
| 276 | "src/ports/SkFontMgr_fontconfig_factory.cpp", |
| 277 | ] |
| 278 | } |
| 279 | |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 280 | optional("fontmgr_fuchsia") { |
| 281 | enabled = is_fuchsia && skia_use_freetype |
| 282 | |
| 283 | deps = [ |
| 284 | "//third_party/freetype2", |
| 285 | ] |
| 286 | sources = [ |
| 287 | "src/ports/SkFontMgr_custom.cpp", |
| 288 | "src/ports/SkFontMgr_custom_empty_factory.cpp", |
| 289 | ] |
| 290 | } |
| 291 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 292 | optional("gif") { |
| 293 | enabled = skia_use_giflib |
| 294 | public_defines = [ "SK_HAS_GIF_LIBRARY" ] |
| 295 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 296 | deps = [ |
| 297 | "//third_party/giflib", |
| 298 | ] |
| 299 | sources = [ |
| 300 | "src/codec/SkGifCodec.cpp", |
| 301 | ] |
| 302 | } |
| 303 | |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 304 | optional("gpu") { |
| 305 | enabled = skia_enable_gpu |
mtklein | e9fb3d5 | 2016-09-20 15:11:46 -0700 | [diff] [blame^] | 306 | public_defines = [] |
| 307 | |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 308 | sources = skia_gpu_sources + [ "src/gpu/gl/GrGLDefaultInterface_native.cpp" ] |
| 309 | |
| 310 | # These paths need to be absolute to match the ones produced by shared_sources.gni. |
| 311 | sources -= get_path_info([ |
| 312 | "src/gpu/gl/GrGLCreateNativeInterface_none.cpp", |
| 313 | "src/gpu/gl/GrGLDefaultInterface_none.cpp", |
| 314 | ], |
| 315 | "abspath") |
| 316 | if (is_android) { |
| 317 | sources += [ "src/gpu/gl/android/GrGLCreateNativeInterface_android.cpp" ] |
| 318 | } else if (is_linux) { |
| 319 | sources += [ "src/gpu/gl/glx/GrGLCreateNativeInterface_glx.cpp" ] |
| 320 | } else if (is_mac) { |
| 321 | sources += [ "src/gpu/gl/mac/GrGLCreateNativeInterface_mac.cpp" ] |
| 322 | } else { |
| 323 | sources += [ "src/gpu/gl/GrGLCreateNativeInterface_none.cpp" ] |
| 324 | } |
mtklein | e9fb3d5 | 2016-09-20 15:11:46 -0700 | [diff] [blame^] | 325 | libs = [] |
| 326 | |
| 327 | if (skia_use_vulkan) { |
| 328 | public_defines += [ "SK_VULKAN" ] |
| 329 | sources += skia_vk_sources |
| 330 | libs += [ "vulkan" ] |
| 331 | } |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 332 | } |
| 333 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 334 | optional("jpeg") { |
| 335 | enabled = skia_use_libjpeg_turbo |
| 336 | public_defines = [ "SK_HAS_JPEG_LIBRARY" ] |
| 337 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 338 | deps = [ |
| 339 | "//third_party/libjpeg-turbo:libjpeg", |
| 340 | ] |
| 341 | sources = [ |
| 342 | "src/codec/SkJpegCodec.cpp", |
| 343 | "src/codec/SkJpegDecoderMgr.cpp", |
| 344 | "src/codec/SkJpegUtility.cpp", |
| 345 | "src/images/SkJPEGImageEncoder.cpp", |
| 346 | "src/images/SkJPEGWriteUtility.cpp", |
| 347 | ] |
| 348 | } |
| 349 | |
| 350 | optional("pdf") { |
| 351 | enabled = skia_use_zlib |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 352 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 353 | deps = [ |
| 354 | "//third_party/zlib", |
| 355 | ] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 356 | sources = skia_pdf_sources |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 357 | sources_when_disabled = [ "src/pdf/SkDocument_PDF_None.cpp" ] |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 358 | |
| 359 | if (skia_use_sfntly) { |
| 360 | deps += [ "//third_party/sfntly" ] |
mtklein | cd01b03 | 2016-08-31 04:58:19 -0700 | [diff] [blame] | 361 | public_defines = [ "SK_PDF_USE_SFNTLY" ] |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 362 | } |
| 363 | } |
| 364 | |
| 365 | optional("png") { |
| 366 | enabled = skia_use_libpng |
| 367 | public_defines = [ "SK_HAS_PNG_LIBRARY" ] |
| 368 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 369 | deps = [ |
| 370 | "//third_party/libpng", |
| 371 | ] |
| 372 | sources = [ |
| 373 | "src/codec/SkIcoCodec.cpp", |
| 374 | "src/codec/SkPngCodec.cpp", |
| 375 | "src/images/SkPNGImageEncoder.cpp", |
| 376 | ] |
| 377 | } |
| 378 | |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 379 | optional("typeface_freetype") { |
| 380 | enabled = skia_use_freetype |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 381 | |
| 382 | deps = [ |
| 383 | "//third_party/freetype2", |
| 384 | ] |
| 385 | sources = [ |
| 386 | "src/ports/SkFontHost_FreeType.cpp", |
| 387 | "src/ports/SkFontHost_FreeType_common.cpp", |
| 388 | ] |
| 389 | } |
| 390 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 391 | optional("webp") { |
| 392 | enabled = skia_use_libwebp |
| 393 | public_defines = [ "SK_HAS_WEBP_LIBRARY" ] |
| 394 | |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 395 | deps = [ |
| 396 | "//third_party/libwebp", |
| 397 | ] |
| 398 | sources = [ |
| 399 | "src/codec/SkWebpAdapterCodec.cpp", |
| 400 | "src/codec/SkWebpCodec.cpp", |
| 401 | "src/images/SkWEBPImageEncoder.cpp", |
| 402 | ] |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 403 | } |
| 404 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 405 | optional("xml") { |
| 406 | enabled = skia_use_expat |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 407 | |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 408 | deps = [ |
| 409 | "//third_party/expat", |
| 410 | ] |
| 411 | sources = [ |
| 412 | "src/xml/SkDOM.cpp", |
| 413 | "src/xml/SkXMLParser.cpp", |
| 414 | "src/xml/SkXMLWriter.cpp", |
| 415 | ] |
| 416 | } |
| 417 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 418 | component("skia") { |
| 419 | public_configs = [ ":skia_public" ] |
| 420 | configs += skia_library_configs |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 421 | |
| 422 | deps = [ |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 423 | ":arm64", |
| 424 | ":armv7", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 425 | ":avx", |
anmittal | b8b3f71 | 2016-08-25 04:55:19 -0700 | [diff] [blame] | 426 | ":crc32", |
mtklein | 349cece | 2016-08-26 08:13:04 -0700 | [diff] [blame] | 427 | ":dsp", |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 428 | ":fontmgr_android", |
mtklein | d2e39db | 2016-09-07 07:52:55 -0700 | [diff] [blame] | 429 | ":fontmgr_custom", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 430 | ":fontmgr_fontconfig", |
mtklein | cdedd0e | 2016-09-12 15:15:44 -0700 | [diff] [blame] | 431 | ":fontmgr_fuchsia", |
mtklein | 457b42a | 2016-08-23 13:56:37 -0700 | [diff] [blame] | 432 | ":gif", |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 433 | ":gpu", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 434 | ":jpeg", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 435 | ":none", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 436 | ":pdf", |
| 437 | ":png", |
mtklein | 9b8583d | 2016-08-24 17:32:30 -0700 | [diff] [blame] | 438 | ":sse2", |
| 439 | ":sse41", |
| 440 | ":sse42", |
| 441 | ":ssse3", |
mtklein | 3cc2218 | 2016-08-29 13:26:14 -0700 | [diff] [blame] | 442 | ":typeface_freetype", |
mtklein | eb3c425 | 2016-08-23 07:38:09 -0700 | [diff] [blame] | 443 | ":webp", |
mtklein | 6321381 | 2016-08-24 09:55:56 -0700 | [diff] [blame] | 444 | ":xml", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 445 | ] |
| 446 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 447 | sources = [] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 448 | sources += skia_core_sources |
| 449 | sources += skia_effects_sources |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 450 | sources += skia_sksl_sources |
| 451 | sources += skia_utils_sources |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 452 | sources += [ |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 453 | "src/android/SkBitmapRegionCodec.cpp", |
| 454 | "src/android/SkBitmapRegionDecoder.cpp", |
| 455 | "src/codec/SkAndroidCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 456 | "src/codec/SkBmpCodec.cpp", |
| 457 | "src/codec/SkBmpMaskCodec.cpp", |
| 458 | "src/codec/SkBmpRLECodec.cpp", |
| 459 | "src/codec/SkBmpStandardCodec.cpp", |
| 460 | "src/codec/SkCodec.cpp", |
| 461 | "src/codec/SkCodecImageGenerator.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 462 | "src/codec/SkMaskSwizzler.cpp", |
| 463 | "src/codec/SkMasks.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 464 | "src/codec/SkSampledCodec.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 465 | "src/codec/SkSampler.cpp", |
| 466 | "src/codec/SkSwizzler.cpp", |
| 467 | "src/codec/SkWbmpCodec.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 468 | "src/images/SkImageEncoder.cpp", |
| 469 | "src/images/SkImageEncoder_Factory.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 470 | "src/images/SkKTXImageEncoder.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 471 | "src/ports/SkDiscardableMemory_none.cpp", |
| 472 | "src/ports/SkGlobalInitialization_default.cpp", |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 473 | "src/ports/SkImageGenerator_skia.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 474 | "src/ports/SkMemory_malloc.cpp", |
| 475 | "src/ports/SkOSFile_stdio.cpp", |
| 476 | "src/sfnt/SkOTTable_name.cpp", |
| 477 | "src/sfnt/SkOTUtils.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 478 | "src/svg/SkSVGCanvas.cpp", |
| 479 | "src/svg/SkSVGDevice.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 480 | "src/utils/mac/SkStream_mac.cpp", |
| 481 | "third_party/etc1/etc1.cpp", |
| 482 | "third_party/ktx/ktx.cpp", |
| 483 | ] |
brettw | b944728 | 2016-09-01 14:24:39 -0700 | [diff] [blame] | 484 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 485 | libs = [] |
| 486 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 487 | if (is_win) { |
| 488 | sources += [ |
| 489 | "src/ports/SkDebug_win.cpp", |
| 490 | "src/ports/SkFontHost_win.cpp", |
| 491 | "src/ports/SkFontMgr_win_dw.cpp", |
| 492 | "src/ports/SkFontMgr_win_dw_factory.cpp", |
| 493 | "src/ports/SkImageEncoder_WIC.cpp", |
| 494 | "src/ports/SkImageGeneratorWIC.cpp", |
| 495 | "src/ports/SkOSFile_win.cpp", |
| 496 | "src/ports/SkScalerContext_win_dw.cpp", |
| 497 | "src/ports/SkTLS_win.cpp", |
| 498 | "src/ports/SkTypeface_win_dw.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 499 | "src/xps/SkDocument_XPS.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 500 | ] |
mtklein | b9be979 | 2016-09-16 14:44:18 -0700 | [diff] [blame] | 501 | sources -= |
| 502 | [ get_path_info("src/utils/SkThreadUtils_pthread.cpp", "abspath") ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 503 | } else { |
| 504 | sources += [ |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 505 | "src/ports/SkOSFile_posix.cpp", |
| 506 | "src/ports/SkTLS_pthread.cpp", |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 507 | "src/xps/SkDocument_XPS_None.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 508 | ] |
| 509 | } |
| 510 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 511 | if (is_android) { |
| 512 | deps += [ |
| 513 | "//third_party/cpu-features", |
| 514 | "//third_party/expat", |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 515 | ] |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 516 | sources += [ "src/ports/SkDebug_android.cpp" ] |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 517 | libs += [ |
| 518 | "EGL", |
| 519 | "GLESv2", |
| 520 | "log", |
| 521 | ] |
| 522 | } |
| 523 | |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 524 | if (is_linux) { |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 525 | libs += [ |
| 526 | "GL", |
| 527 | "GLU", |
| 528 | "X11", |
| 529 | ] |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 530 | sources += [ "src/ports/SkDebug_stdio.cpp" ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 531 | } |
| 532 | |
| 533 | if (is_mac) { |
| 534 | sources += [ |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 535 | "src/ports/SkDebug_stdio.cpp", |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 536 | "src/ports/SkFontHost_mac.cpp", |
| 537 | "src/ports/SkImageEncoder_CG.cpp", |
| 538 | "src/ports/SkImageGeneratorCG.cpp", |
| 539 | ] |
mtklein | 09e61f7 | 2016-08-23 13:35:28 -0700 | [diff] [blame] | 540 | libs += [ |
| 541 | "ApplicationServices.framework", |
| 542 | "OpenGL.framework", |
| 543 | ] |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 544 | } |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 545 | |
| 546 | if (is_fuchsia) { |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 547 | sources += [ "src/ports/SkDebug_stdio.cpp" ] |
abarth | 6fc8ff0 | 2016-07-15 15:15:15 -0700 | [diff] [blame] | 548 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 549 | } |
| 550 | |
mtklein | ada5a44 | 2016-08-02 14:28:26 -0700 | [diff] [blame] | 551 | skia_h_headers = exec_script("gyp/find.py", |
| 552 | [ "*.h" ] + rebase_path(skia_public_includes), |
| 553 | "list lines", |
| 554 | []) - |
| 555 | [ |
| 556 | rebase_path("include/gpu/gl/GrGLConfig_chrome.h"), |
| 557 | rebase_path("include/gpu/vk/GrVkBackendContext.h"), |
| 558 | rebase_path("include/gpu/vk/GrVkDefines.h"), |
| 559 | rebase_path("include/gpu/vk/GrVkInterface.h"), |
| 560 | rebase_path("include/gpu/vk/GrVkTypes.h"), |
| 561 | rebase_path("include/ports/SkFontMgr_fontconfig.h"), |
| 562 | ] |
| 563 | |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 564 | action("skia.h") { |
| 565 | script = "gn/echo_headers.py" |
| 566 | args = [ rebase_path("$target_gen_dir/skia.h", root_build_dir) ] + |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 567 | rebase_path(skia_h_headers, target_gen_dir) |
mtklein | 1211e0c | 2016-07-26 13:55:45 -0700 | [diff] [blame] | 568 | outputs = [ |
| 569 | "$target_gen_dir/skia.h", |
| 570 | ] |
| 571 | } |
| 572 | |
mtklein | 06c35c0 | 2016-09-20 12:28:12 -0700 | [diff] [blame] | 573 | if (skia_enable_gpu && target_cpu == "x64") { |
mtklein | 1fbdf98 | 2016-09-15 12:07:48 -0700 | [diff] [blame] | 574 | # Our bots only have 64-bit libOSMesa installed. |
| 575 | # TODO: worth fixing? |
| 576 | executable("fiddle") { |
| 577 | include_dirs = [ "$target_gen_dir" ] |
| 578 | libs = [] |
| 579 | if (is_linux) { |
| 580 | libs += [ "OSMesa" ] |
| 581 | } |
mtklein | 56d5669 | 2016-09-15 11:18:55 -0700 | [diff] [blame] | 582 | |
mtklein | 1fbdf98 | 2016-09-15 12:07:48 -0700 | [diff] [blame] | 583 | sources = [ |
| 584 | "src/images/SkForceLinking.cpp", |
| 585 | "tools/fiddle/draw.cpp", |
| 586 | "tools/fiddle/fiddle_main.cpp", |
| 587 | ] |
| 588 | deps = [ |
| 589 | ":skia", |
| 590 | ":skia.h", |
| 591 | ] |
| 592 | } |
mtklein | c04ff47 | 2016-06-23 10:29:30 -0700 | [diff] [blame] | 593 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 594 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 595 | # Targets guarded by skia_enable_tools may use //third_party freely. |
| 596 | if (skia_enable_tools) { |
| 597 | template("test_lib") { |
| 598 | config(target_name + "_config") { |
| 599 | include_dirs = invoker.public_include_dirs |
mtklein | a627b5c | 2016-09-20 13:36:47 -0700 | [diff] [blame] | 600 | if (defined(invoker.public_defines)) { |
| 601 | defines = invoker.public_defines |
| 602 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 603 | } |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 604 | source_set(target_name) { |
| 605 | forward_variables_from(invoker, "*", [ "public_include_dirs" ]) |
| 606 | public_configs = [ |
| 607 | ":" + target_name + "_config", |
| 608 | ":skia_private", |
| 609 | ] |
| 610 | |
| 611 | if (!defined(deps)) { |
| 612 | deps = [] |
| 613 | } |
| 614 | deps += [ ":skia" ] |
| 615 | testonly = true |
| 616 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 617 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 618 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 619 | test_lib("gpu_tool_utils") { |
mtklein | a627b5c | 2016-09-20 13:36:47 -0700 | [diff] [blame] | 620 | public_defines = [] |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 621 | public_include_dirs = [ "tools/gpu" ] |
| 622 | sources = [ |
| 623 | "tools/gpu/GrContextFactory.cpp", |
| 624 | "tools/gpu/GrTest.cpp", |
| 625 | "tools/gpu/TestContext.cpp", |
| 626 | "tools/gpu/gl/GLTestContext.cpp", |
| 627 | "tools/gpu/gl/debug/DebugGLTestContext.cpp", |
| 628 | "tools/gpu/gl/debug/GrBufferObj.cpp", |
| 629 | "tools/gpu/gl/debug/GrFrameBufferObj.cpp", |
| 630 | "tools/gpu/gl/debug/GrProgramObj.cpp", |
| 631 | "tools/gpu/gl/debug/GrShaderObj.cpp", |
| 632 | "tools/gpu/gl/debug/GrTextureObj.cpp", |
| 633 | "tools/gpu/gl/debug/GrTextureUnitObj.cpp", |
| 634 | "tools/gpu/gl/null/NullGLTestContext.cpp", |
| 635 | ] |
| 636 | libs = [] |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 637 | |
mtklein | 7d6fb2c | 2016-08-25 14:50:44 -0700 | [diff] [blame] | 638 | if (is_android) { |
| 639 | sources += [ "tools/gpu/gl/egl/CreatePlatformGLTestContext_egl.cpp" ] |
| 640 | } else if (is_linux) { |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 641 | sources += [ "tools/gpu/gl/glx/CreatePlatformGLTestContext_glx.cpp" ] |
| 642 | } else if (is_mac) { |
| 643 | sources += [ "tools/gpu/gl/mac/CreatePlatformGLTestContext_mac.cpp" ] |
| 644 | } |
mtklein | 6ef6999 | 2016-09-14 06:12:09 -0700 | [diff] [blame] | 645 | |
| 646 | if (skia_use_vulkan) { |
| 647 | sources += [ "tools/gpu/vk/VkTestContext.cpp" ] |
| 648 | } |
mtklein | a627b5c | 2016-09-20 13:36:47 -0700 | [diff] [blame] | 649 | if (skia_use_mesa) { |
| 650 | public_defines += [ "SK_MESA" ] |
| 651 | sources += [ "tools/gpu/gl/mesa/GLTestContext_mesa.cpp" ] |
| 652 | libs += [ "OSMesa" ] |
| 653 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 654 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 655 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 656 | test_lib("flags") { |
| 657 | public_include_dirs = [ "tools/flags" ] |
| 658 | sources = [ |
| 659 | "tools/flags/SkCommandLineFlags.cpp", |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 660 | ] |
| 661 | } |
| 662 | test_lib("common_flags") { |
| 663 | public_include_dirs = [ "tools/flags" ] |
| 664 | sources = [ |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 665 | "tools/flags/SkCommonFlags.cpp", |
| 666 | "tools/flags/SkCommonFlagsConfig.cpp", |
| 667 | ] |
| 668 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 669 | ":flags", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 670 | ":gpu_tool_utils", |
| 671 | ] |
| 672 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 673 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 674 | test_lib("tool_utils") { |
| 675 | public_include_dirs = [ |
| 676 | "tools", |
| 677 | "tools/debugger", |
| 678 | "tools/timer", |
| 679 | ] |
| 680 | sources = [ |
| 681 | "src/images/SkForceLinking.cpp", |
| 682 | "src/utils/SkMultiPictureDocumentReader.cpp", # TODO(halcanary): move to tools? |
mtklein | b37c034 | 2016-09-09 11:07:45 -0700 | [diff] [blame] | 683 | "tools/AndroidSkDebugToStdOut.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 684 | "tools/CrashHandler.cpp", |
mtklein | 0590fa5 | 2016-09-01 07:06:54 -0700 | [diff] [blame] | 685 | "tools/LsanSuppressions.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 686 | "tools/ProcStats.cpp", |
| 687 | "tools/Resources.cpp", |
| 688 | "tools/ThermalManager.cpp", |
| 689 | "tools/UrlDataManager.cpp", |
| 690 | "tools/debugger/SkDebugCanvas.cpp", |
| 691 | "tools/debugger/SkDrawCommand.cpp", |
| 692 | "tools/debugger/SkJsonWriteBuffer.cpp", |
| 693 | "tools/debugger/SkObjectParser.cpp", |
| 694 | "tools/debugger/SkOverdrawMode.cpp", |
| 695 | "tools/picture_utils.cpp", |
| 696 | "tools/random_parse_path.cpp", |
| 697 | "tools/sk_tool_utils.cpp", |
| 698 | "tools/sk_tool_utils_font.cpp", |
| 699 | "tools/timer/Timer.cpp", |
| 700 | ] |
| 701 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 702 | ":common_flags", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 703 | ":flags", |
| 704 | "//third_party/libpng", |
| 705 | ] |
| 706 | public_deps = [ |
| 707 | "//third_party/jsoncpp", |
| 708 | ] |
| 709 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 710 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 711 | gm_sources = exec_script("gyp/find.py", |
| 712 | [ |
| 713 | "*.c*", |
| 714 | rebase_path("gm"), |
| 715 | ], |
| 716 | "list lines", |
| 717 | []) |
| 718 | test_lib("gm") { |
| 719 | public_include_dirs = [ "gm" ] |
| 720 | sources = gm_sources |
| 721 | deps = [ |
| 722 | ":gpu_tool_utils", |
| 723 | ":skia", |
| 724 | ":tool_utils", |
| 725 | ] |
| 726 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 727 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 728 | tests_sources = exec_script("gyp/find.py", |
| 729 | [ |
| 730 | "*.c*", |
| 731 | rebase_path("tests"), |
| 732 | ], |
| 733 | "list lines", |
| 734 | []) |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 735 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 736 | test_lib("tests") { |
| 737 | public_include_dirs = [ "tests" ] |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 738 | sources = tests_sources - [ |
| 739 | rebase_path("tests/PathOpsSkpClipTest.cpp"), # alternate main |
mtklein | a45be61 | 2016-08-29 15:22:10 -0700 | [diff] [blame] | 740 | rebase_path("tests/SkpSkGrTest.cpp"), # doesn't compile |
| 741 | rebase_path("tests/skia_test.cpp"), # alternate main |
| 742 | ] |
| 743 | if (!fontmgr_android_enabled) { |
| 744 | sources -= [ rebase_path("tests/FontMgrAndroidParserTest.cpp") ] |
| 745 | } |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 746 | deps = [ |
fmalita | 6cf896d | 2016-08-25 08:44:35 -0700 | [diff] [blame] | 747 | ":experimental_svg_model", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 748 | ":flags", |
| 749 | ":gpu_tool_utils", |
| 750 | ":skia", |
| 751 | ":tool_utils", |
| 752 | "//third_party/libpng", |
| 753 | "//third_party/zlib", |
| 754 | ] |
| 755 | } |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 756 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 757 | bench_sources = exec_script("gyp/find.py", |
| 758 | [ |
| 759 | "*.c*", |
| 760 | rebase_path("bench"), |
| 761 | ], |
| 762 | "list lines", |
| 763 | []) |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 764 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 765 | test_lib("bench") { |
| 766 | public_include_dirs = [ "bench" ] |
| 767 | sources = bench_sources |
| 768 | sources -= [ |
| 769 | rebase_path("bench/nanobench.cpp"), |
| 770 | rebase_path("bench/nanobenchAndroid.cpp"), |
| 771 | ] |
| 772 | deps = [ |
| 773 | ":flags", |
| 774 | ":gm", |
| 775 | ":gpu_tool_utils", |
| 776 | ":skia", |
| 777 | ":tool_utils", |
| 778 | ] |
| 779 | } |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 780 | |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 781 | test_lib("experimental_svg_model") { |
| 782 | public_include_dirs = [ "experimental/svg/model" ] |
| 783 | sources = [ |
| 784 | "experimental/svg/model/SkSVGAttribute.cpp", |
| 785 | "experimental/svg/model/SkSVGAttributeParser.cpp", |
| 786 | "experimental/svg/model/SkSVGCircle.cpp", |
| 787 | "experimental/svg/model/SkSVGContainer.cpp", |
| 788 | "experimental/svg/model/SkSVGDOM.cpp", |
| 789 | "experimental/svg/model/SkSVGEllipse.cpp", |
| 790 | "experimental/svg/model/SkSVGLine.cpp", |
fmalita | 28d5b72 | 2016-09-12 17:06:47 -0700 | [diff] [blame] | 791 | "experimental/svg/model/SkSVGLinearGradient.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 792 | "experimental/svg/model/SkSVGNode.cpp", |
| 793 | "experimental/svg/model/SkSVGPath.cpp", |
| 794 | "experimental/svg/model/SkSVGPoly.cpp", |
| 795 | "experimental/svg/model/SkSVGRect.cpp", |
| 796 | "experimental/svg/model/SkSVGRenderContext.cpp", |
| 797 | "experimental/svg/model/SkSVGSVG.cpp", |
| 798 | "experimental/svg/model/SkSVGShape.cpp", |
fmalita | 28d5b72 | 2016-09-12 17:06:47 -0700 | [diff] [blame] | 799 | "experimental/svg/model/SkSVGStop.cpp", |
mtklein | c095df5 | 2016-08-24 12:23:52 -0700 | [diff] [blame] | 800 | "experimental/svg/model/SkSVGTransformableNode.cpp", |
| 801 | "experimental/svg/model/SkSVGValue.cpp", |
| 802 | ] |
| 803 | deps = [ |
| 804 | ":skia", |
| 805 | ] |
| 806 | } |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 807 | |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 808 | executable("dm") { |
| 809 | sources = [ |
| 810 | "dm/DM.cpp", |
| 811 | "dm/DMJsonWriter.cpp", |
| 812 | "dm/DMSrcSink.cpp", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 813 | ] |
| 814 | include_dirs = [ "tests" ] |
| 815 | deps = [ |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 816 | ":common_flags", |
fmalita | a2b9fdf | 2016-08-03 19:53:36 -0700 | [diff] [blame] | 817 | ":experimental_svg_model", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 818 | ":flags", |
| 819 | ":gm", |
| 820 | ":gpu_tool_utils", |
| 821 | ":skia", |
mtklein | 2f3416d | 2016-08-02 16:02:05 -0700 | [diff] [blame] | 822 | ":tests", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 823 | ":tool_utils", |
| 824 | "//third_party/jsoncpp", |
| 825 | "//third_party/libpng", |
| 826 | ] |
| 827 | testonly = true |
| 828 | } |
| 829 | |
| 830 | executable("monobench") { |
| 831 | sources = [ |
| 832 | "tools/monobench.cpp", |
| 833 | ] |
| 834 | deps = [ |
| 835 | ":bench", |
| 836 | ":skia", |
| 837 | ] |
| 838 | testonly = true |
| 839 | } |
| 840 | |
| 841 | executable("nanobench") { |
| 842 | sources = [ |
| 843 | "bench/nanobench.cpp", |
| 844 | ] |
| 845 | deps = [ |
| 846 | ":bench", |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 847 | ":common_flags", |
fmalita | 6519c21 | 2016-09-14 08:05:17 -0700 | [diff] [blame] | 848 | ":experimental_svg_model", |
mtklein | 2b6870c | 2016-07-28 14:17:33 -0700 | [diff] [blame] | 849 | ":flags", |
| 850 | ":gm", |
| 851 | ":gpu_tool_utils", |
| 852 | ":skia", |
| 853 | ":tool_utils", |
| 854 | "//third_party/jsoncpp", |
| 855 | ] |
| 856 | testonly = true |
| 857 | } |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 858 | |
csmartdalton | 4b5179b | 2016-09-19 11:03:58 -0700 | [diff] [blame] | 859 | executable("skpbench") { |
| 860 | sources = [ |
| 861 | "tools/skpbench/skpbench.cpp", |
| 862 | ] |
| 863 | deps = [ |
| 864 | ":flags", |
| 865 | ":gpu_tool_utils", |
| 866 | ":skia", |
| 867 | ":tool_utils", |
| 868 | ] |
| 869 | testonly = true |
| 870 | } |
| 871 | |
mtklein | 6f5df6a | 2016-08-29 16:01:10 -0700 | [diff] [blame] | 872 | if (current_cpu != "mipsel") { # Clang 3.8 crashes while compiling hb-icu.cc for mipsel. |
halcanary | 3eee9d9 | 2016-09-10 07:01:53 -0700 | [diff] [blame] | 873 | executable("sktexttopdf-hb") { |
mtklein | 6f5df6a | 2016-08-29 16:01:10 -0700 | [diff] [blame] | 874 | sources = [ |
| 875 | "tools/SkShaper_harfbuzz.cpp", |
| 876 | "tools/using_skia_and_harfbuzz.cpp", |
| 877 | ] |
| 878 | deps = [ |
| 879 | ":skia", |
| 880 | "//third_party/harfbuzz", |
| 881 | ] |
| 882 | testonly = true |
| 883 | } |
halcanary | 19a9720 | 2016-08-03 15:08:04 -0700 | [diff] [blame] | 884 | } |
halcanary | 3eee9d9 | 2016-09-10 07:01:53 -0700 | [diff] [blame] | 885 | executable("sktexttopdf") { |
| 886 | sources = [ |
| 887 | "tools/SkShaper_primitive.cpp", |
| 888 | "tools/using_skia_and_harfbuzz.cpp", |
| 889 | ] |
| 890 | deps = [ |
| 891 | ":skia", |
| 892 | ] |
| 893 | testonly = true |
| 894 | } |
mtklein | 046cb56 | 2016-09-16 10:23:12 -0700 | [diff] [blame] | 895 | |
| 896 | executable("get_images_from_skps") { |
| 897 | sources = [ |
| 898 | "tools/get_images_from_skps.cpp", |
| 899 | ] |
| 900 | deps = [ |
| 901 | ":flags", |
| 902 | ":skia", |
| 903 | "//third_party/jsoncpp", |
| 904 | ] |
| 905 | testonly = true |
| 906 | } |
mtklein | 25c81d4 | 2016-07-27 13:55:26 -0700 | [diff] [blame] | 907 | } |